ACADDOC.lsp Help

Is there a command I can use to load template.dwt files so te user has access to them on start up? Or maybe a command in the ACAD.lsp file?

Is there a command I can use to load template.dwt files so te user has access to them on start up? Or maybe a command in the ACAD.lsp file?

You can set the Template and QNew template in Options.

I want this to apply to every computer in my network that share the ACADDOC.lsp file so that I can stay away from going to each one and setting this up.

I want this to apply to every computer in my network that share the ACADDOC.lsp file so that I can stay away from going to each one and setting this up.

Just set the Path in the Options > Files template directory. Just make sure it's networked, obviously.

can I do that with a line in the ACADDOC.lsp file?

can I do that with a line in the ACADDOC.lsp file?

Yes, but you only need to do it once and it's set forever. This is a setup routine I wrote to set everything properly. You are more than welcome to modify and use. It has what you need to setup template paths.

(defun c:CES-Setup (/ #Files #Layout #Flag)
 (vl-load-com)
 (and
   (not
     (vl-catch-all-error-p
       (vl-catch-all-apply
         '(lambda ()
            (setq #Files  (vla-get-files
                            (vla-get-preferences (vlax-get-acad-object))
                          ) ;_ vla-get-files
                  #Layout (vla-get-activelayout
                            (vla-get-activedocument (vlax-get-acad-object))
                          ) ;_ vla-get-activelayout
            ) ;_ setq
            ;; *********************
            ;; **  AutoSave Path  **
            ;; *********************
            (mapcar 'vl-mkdir (list "c:\\TEMP" "c:\\TEMP\\ACAD"))
            (vla-put-autosavepath #Files "c:\\TEMP\\ACAD")
            ;; ***************************
            ;; **  Printer Config Path  **
            ;; ***************************
            (vla-put-PrinterConfigPath
              #Files
              "s:\\cadd standards\\Plotters"
            ) ;_ vla-put-PrinterConfigPath
            (vla-refreshplotdeviceinfo #Layout)
            ;; ***********************
            ;; **  Plotstyles Path  **
            ;; ***********************
            (vla-put-printerstylesheetpath
              #Files
              "s:\\cadd standards\\Plotstyles"
            ) ;_ vla-put-printerstylesheetpath
            (vla-refreshplotdeviceinfo #Layout)
            ;; *********************
            ;; **  Template Path  **
            ;; *********************
            (vla-put-TemplateDwgPath
              #Files
              "s:\\cadd standards\\Template"
            ) ;_ vla-put-TemplateDwgPath
            ;; *********************
            ;; **  QNew Template  **
            ;; *********************
            (vla-put-QNewTemplateFile
              #Files
              "s:\\cadd standards\\Template\\CES_Template.dwt"
            ) ;_ vla-put-QNewTemplateFile
            ;; *********************
            ;; **  Support Paths  **
            ;; *********************
            (vla-put-supportpath
              #Files
              (strcat ";s:\\cadd standards\\startup"
                      ";s:\\cadd standards\\lisp"
                      ";s:\\cadd standards\\linetypes"
                      ";s:\\cadd standards\\fonts"
                      ";s:\\cadd standards\\ces layers"
                      ";"
                      (vla-get-supportpath #Files)
              ) ;_ strcat
            ) ;_ vla-put-supportpath
            ;; ***************************
            ;; **  Tool Palettes Paths  **
            ;; ***************************
            (vla-put-ToolPalettePath
              #Files
              (strcat "S:\\CADD Standards\\Toolpalette\\Palettes;"
                      (vla-get-ToolPalettePath #Files)
              ) ;_ strcat
            ) ;_ vla-put-ToolPalettePath
          ) ;_ lambda
       ) ;_ vl-catch-all-apply
     ) ;_ vl-catch-all-error-p
   ) ;_ not
   (alert
     (strcat
       "AutoCAD has been setup for Capital Engineering & Surveying, Inc. Standards.\n\n"
       "                      Please restart AutoCAD."
     ) ;_ strcat
   ) ;_ alert
 ) ;_ and
 (princ)
) ;_ defun
(alert "Type: \"CES-SETUP\" to run setup.")
(princ)

Wow... Nice... I will see what I can do with this... Thanks!

Wow... Nice... I will see what I can do with this... Thanks!

No problem, I got a nice little bonus for it when I introduced it for our 06 to 08 switch.