error

In vba , we have on error resume next

in lisp what is the option?

on error , it is exited.

regards

Kalai

(if(vlax-safearray->list(vlax-variant-value(vla-intersectwith obj1 obj2 
acExtendNone)))(prompt"nothing")(prompt"ok"))  

the above code doesnot work.

i need to continue with the code if there is no intersection.

It is going to the error function.

try this:

(defun c:TEST (/ A B)
 (if
   (and
     (setq A (car (entsel "\nSelect first object: ")))
     (setq B (car (entsel "\nSelect first object: ")))
   )
   (if
     (vlax-invoke
       (vlax-Ename->vla-Object A)
       'IntersectWith
       (vlax-Ename->vla-Object B)
       acExtendNone
     )
     (princ "ok")
     (princ "bad")
   )
 )
 (princ)
)

k.

thanks

It works .

I would also be inclined to use the method utilising vlax-invoke as Kruuger has demonstrated, but if you wanted to follow your original method, here is how it could be accomplished:

(defun c:test ( / e1 e2 arr )
 (if
   (and
     (setq e1 (car (entsel "\nFirst Object: ")))
     (setq e2 (car (entsel "\nSecond Object: ")))
   )
   (if
     (minusp
       (vlax-safearray-get-u-bound
         (setq arr
           (vlax-variant-value
             (vla-intersectwith
               (vlax-ename->vla-object e1)
               (vlax-ename->vla-object e2) acextendnone
             )
           )
         )
         1
       )
     )
     (princ "\nDont Intersect.")
     (princ (vlax-safearray->list arr))
   )
 )
 (princ)
)