Do not explode the dimensions! [Archive]

fuccaro

19th Nov 2003, 03:21 pm

Sometime I have to work on drawings created by my colleagues. I hate working with exploded dimensions, so I wrote a short Lisp routine and I placed a copy of it on every computer in our office. The routines are in the startup suit so are loaded at startup. I am the only one around here working with Lisp, so I suppose that my routine will remain on place for long time from now. If some of you wish to try, here is the code:
(command "undefine" "explode")
(defun c:explode()
(setvar "cmdecho" 0)
(command "undo" "begin")
(setq q (ssget)
i 0
dim nil
message (strcat " You are going to explode one or more dimension(s)!"
"\nYou exploded until now more than 100 dimension entyes."
"\nPress F1 for help and read about dimensioning in AutoCAD")
)
(repeat (sslength q)
(setq ed (entget (ssname q i))
i (1+ i)
dim (= "DIMENSION" (cdr (assoc 0 ed))))
)
(if dim (alert message))
(command "._explode" q)
(command "undo" "end")
(princ)
)
Probable in the next step I will add the hatches to the �protected list�. Did you ewer try to edit an exploded dot hatch? -I did!

Mr T

20th Nov 2003, 12:38 pm

I see you have non associated the dimensions ?

Flores

18th Dec 2003, 08:25 pm

Here is another routine to prevent dimensions from being exploded, but also adds mtext and blocks to the list. It is really easy to add an entity to be "filtered" whenever you select an object to explode.

;; Created by: Lee Ambrosius
;; Date created : 12/05/03
;; Error Handler added : 12/09/03
;; Corrected looping issue : 12/10/03

;; Filter out Blocks (Inserts), Mtext and Dimensions from the
;; Explode command.

;; Load COM Library for Visual LISP
(vl-load-com)

;; Remove standard Explode Command
;; Standard Explode can still be accessed via the . (period) in front of the command name

;; Save current value of CMDECHO into a local variable
(defun undefine-cmd ( / SAV-CMDECHO)
(setq SAV-CMDECHO (getvar "CMDECHO"))
(setvar "CMDECHO" 0)
(command ".undefine" "explode")
(if (/= SAV-CMDECHO nil)
(setvar "CMDECHO" SAV-CMDECHO)
)
(princ)
)

(undefine-cmd)

;; Custom Explode Command Override
(defun c:explode ( / SS SS-FILTER SAV-CMDECHO SAV-NOMUTT SS-CNT CNT-LOOP
UNDOFLAG EXPLODE-ERROR OLDERR)

;; Save current value of CMDECHO into a local variable
(setq SAV-CMDECHO (getvar "CMDECHO"))
;; Save current value of CMDECHO into a local variable
;; Check for AutuCAD version and if 2000 - 2004 then run additional code
(if (< (atoi (substr (getvar "ACADVER") 1 2)) 15)
(setq SAV-NOMUTT (getvar "NOMUTT"))
)

;; Custom error handler
(defun EXPLODE-ERROR (S)
(if (/= S "\nFunction cancelled")
(princ "\n")
)
(if (= UNDOFLAG T)
(progn
(command "._undo" "end")
(command ".u")
)
)
(if (/= SAV-CMDECHO nil)(setvar "CMDECHO" SAV-CMDECHO))

(if (< (atoi (substr (getvar "ACADVER") 1 2)) 15)
(if (/= SAV-NOMUTT nil)(setvar "NOMUTT" SAV-NOMUTT))
)
(setq *ERROR* OLDERR)
(princ)
)

(setq OLDERR *ERROR*
*ERROR* EXPLODE-ERROR
)

;; Build entity exclusion filter
;; Use the expression to find out the DXF 0 value that needs
;; to be placed in the filter. (entget (car (entsel)))
(setq SS-FILTER
(list
(cons -4 "<NOT")
(cons -4 "<OR")
(cons 0 "INSERT")
(cons 0 "MTEXT")
(cons 0 "DIMENSION")

;; By filtering out Lines, Circles and Arcs it helps to reduce unnecessary prompts
;; at the command line
(cons 0 "LINE")
(cons 0 "CIRCLE")
(cons 0 "ARC")
(cons 0 "TEXT")
(cons 0 "SOLID")
(cons -4 "OR>")
(cons -4 "NOT>")
)
)

;; Ask the user to select some objects with our filter in place
(setq SS (ssget SS-FILTER))

;; Check to see if Selection Set is empty
(if (/= SS nil)
(progn
;; Change current value of CMDECHO to 0, then no additional prompts will be displayed
(setvar "CMDECHO" 0)

;; Start our undo stack call
(command ".undo" "begin")

(if (< (atoi (substr (getvar "ACADVER") 1 2)) 15)
(setvar "NOMUTT" 1)
)

(setq UNDOFLAG T)

;; Set up counters
(setq SS-CNT (sslength SS)
CNT-LOOP 0
)

;; Loop through all objects in the Selection Set
(while (< CNT-LOOP SS-CNT)
;; Explode the object
(command ".explode" (ssname SS CNT-LOOP))

(if (= 1 (boole 1 (getvar "cmdactive") 1 ))
(command "")
)

;; Add one to the counter
(setq CNT-LOOP (1+ CNT-LOOP))
)

;; Restore original value to th variable NOMUTT
(if (< (atoi (substr (getvar "ACADVER") 1 2)) 15)
(setvar "NOMUTT" SAV-NOMUTT)
)

;; End out undo stack call
(command ".undo" "end")

;; Restore original value to th variable CMDECHO
(setvar "CMDECHO" SAV-CMDECHO)
)
(progn
;; Echo None found like the core Explode command does.
(prompt "\nNone found.")
)
)
(setq *ERROR* OLDERR)
(princ)
)

;; Don't send echoes to screen
(princ)

Flores