Copy Blocks

[ImaJayhawk]

I'm trying to write a simple routine that copies all blocks of a entered name or selected. I'm getting an Invalid Selection error when I enter in the name, and when I select I'm getting a never ending loop. Thanks.

(defun C:bs ( / blocker continue selecty selecter selecterset)
(setvar "cmdecho" 0)
(setq continue T)
(if (= (strcase (getstring "\nDo you want to enter block name? y/<n>")) "Y")
(progn
(setq blocker (getstring "\nEnter Block Name: "))

(While continue
(progn
(setq selecty (ssget "X" (list (cons 0 "Insert") (cons 2 blocker))))
(command "_copybase" pause selecty)
)
)
)
(While continue
(if (setq enty (car (entsel "\nSelect Block: ")))
(progn
(setq e (entget enty))
(setq selecter (cdr (assoc 2 e)))
(setq selecterset (ssget "X" (list (cons 0 "Insert") (cons 2 selecter))))
(command "_copybase" pause selecterset)
(setq continue F)
) (progn (princ "Please select a block") (setq continue T))

)))
(Setvar "cmdecho" 1)
(princ)
)

[fuccaro]

ImaJayhawk
Your error:
....
(setq continue T)
...
(while continue
...
(setq continue F)
)
This is an endless loop. The opposite of TRUE (T) is NIL. F is not NIL, so the test (while continue...) will return T even if continue is set to F.
Here is my attempt to solve your problem. But (again) I think that is not safe to accept the block name to be typed by the user. Not without a verification!

; Blocks to Clippboard
; copy all occurences of a block to the clipboard
;  mfuccaro@hotmail.com
;  January 2004
(defun c:b2c( / answer name blocks)
  (setvar "cmdecho" 0)
  (initget "N")
  (setq answer (entsel "\nselect block\\enter [N]ame "))
  (setq name (if (listp answer)
	       (cdr (assoc 2 (entget (car answer))))
	       (getstring "\nenter block name ")
	       )
	blocks (ssget "X" (list (cons 0 "insert") (cons 2 name))))
  (princ "\nbase point ")
  (command "_copybase" pause blocks "")
  (princ "\nOK")
  (princ)
  )

[David Bethel]

(ssget) accepts wildcards as well

So maybe:

(while (or (not bn)
(not (or (snvalid bn)
(wcmatch bn "*[#@`,.*?~]*"))))
(setq bn (getstring "\nBlock Name <Pattern>: ")))

;And then

(and
(setq ss (ssget "X" (list (cons 0 "INSERT")(cons 2 bn))))
(command ........)
)


or:

(setq i (sslength ss))
(while (not (minusp (setq i (1- i))))
(setq en (ssname ss i)
ed (entget en))))

For picks:

(while (not ss)
(setq ss (ssget (list (cons 0 "INSERT"))))
(command .....)
)

[ImaJayhawk]

Thanks for the help!