Old extend line button not working

[mdbdesign]

This is my old code from line extend button(version 10) is any way to bring it to life

ID_EXT [EXT_LINE]^C^C(SETQ EN (ENTSEL "SELECT LINE: "));\+
(SETQ EAL (ENTGET (CAR EN)));+
(SETQ PT1 (LIST (CADR (ASSOC 10 EAL)) (CADDR (ASSOC 10 EAL))));+
(SETQ PT2 (LIST (CADR (ASSOC 11 EAL)) (CADDR (ASSOC 11 EAL))));+
(SETQ L1 (GETREAL "ENTER EXTENTION LENGTH: "));\+
(SETQ PT3 (POLAR PT1 (ANGLE PT2 PT1) L1));+
(SETQ PT4 (POLAR PT2 (ANGLE PT1 PT2) L1));+
(SETQ EAL (SUBST (LIST 10 (CAR PT3) (CADR PT3)) (ASSOC 10 EAL) EAL));+
(ENTMOD EAL);+
(SETQ EAL (SUBST (LIST 11 (CAR PT4) (CADR PT4)) (ASSOC 11 EAL) EAL));+
(ENTMOD EAL)

[fixo]

Hi friend, I think problem is on in your
macros more then 256 letters as I read
in one book about mastering buttons,
there is the cause of instabily work
You can store this file in your Support
File Search Path and add this macros
on button : ^C^C_XX
Not tested but may help I hope
[code]
(defun C:XX (/ EAL EN L1 PT1 PT2 PT3 PT4)
(setvar "cmdecho" 0)
(SETQ EN (ENTSEL "\nSELECT LINE: "));\+
(SETQ EAL (ENTGET (CAR EN)));+
(SETQ PT1 (LIST (CADR (ASSOC 10 EAL)) (CADDR (ASSOC 10 EAL))));+
(SETQ PT2 (LIST (CADR (ASSOC 11 EAL)) (CADDR (ASSOC 11 EAL))));+
(SETQ L1 (GETDIST "\nENTER EXTENTION LENGTH: "));\+
(SETQ PT3 (POLAR PT1 (ANGLE PT2 PT1) L1));+
(SETQ PT4 (POLAR PT2 (ANGLE PT1 PT2) L1));+
(SETQ EAL (SUBST (LIST 10 (CAR PT3) (CADR PT3)) (ASSOC 10 EAL) EAL));+
(ENTMOD EAL);+
(SETQ EAL (SUBST (LIST 11 (CAR PT4) (CADR PT4)) (ASSOC 11 EAL) EAL));+
(ENTMOD EAL)
(setvar "cmdecho" 1)
(princ)
)
(prompt "\n\t\t***\tLine extention routine loaded. Type XX to execute\t**")
(princ)
[code]

[mdbdesign]

Works like always
thanks O

[mdbdesign]

BTW I never wite any macro longer than maybe 50 letters so thanks for your info. Learn something new again.
Tell me if I want to open more than one dwg at a time how do I got to separate name? With any of , \ / : ; ?

[CAB]

Isn't it time to update that lisp?

;;  Extend both ends of a LINE
;;  Revised version by CAB  01/23/2007
(defun c:ext2 (/ usrecho lst tmp)
  (setq usrecho (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (command "_undo" "_begin")
  (or *len (setq *len 2.0))
  (initget (+ 2 4))
  (and (setq tmp (getdist (strcat "\nExtend Lines, Enter Extention *length: <"
                             (rtos *len)"> ")))
       (setq *len tmp))
  (prompt "\nSelect Lines to extend: ")
  (and
    (setq ss (ssget '((0 . "LINE"))))
    (setq lst (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))))
    (mapcar
      '(lambda (x / elst p1 p2)
         (setq elst (entget x)
               p1   (cdr (assoc 10 elst))
               p2   (cdr (assoc 11 elst))
               ang  (angle p1 p2)
               elst (subst (cons 10 (polar p1 ang (- *len))) (assoc 10 elst) elst)
               elst (subst (cons 11 (polar p2 ang *len)) (assoc 11 elst) elst)
         )
         (entmod elst)
       )
      lst
    )
  )
  (command "_undo" "_end")
  (setvar "cmdecho" usrecho)
  (princ)
)
(prompt "\n***  Line extention routine loaded. Type ext2 to execute  ***")
(princ)

[mdbdesign]

Thanks, but some company still use Autocad version 10 and Mastercam10 to do job and they doing very well believe me.
I be happy to put it on my 2002.
Btw is here any lisp that extract single attribute from about 70 blocks(bill of material) in one drawing and write all of it to text in one line, spaced only with coma?