Lisp for calculating the sum of blocks

[sophie]

Does anyone know of a lisp for calculating the sum of blocks? So if I was to create a block to represent trees in plan for example, I could automatically tally the number of trees.

With thanks,

Sophie

[ASMI]

(defun c:blc(/ blSet filLst nameLst curLen)

  (defun namesExtract(selSet)
    (mapcar '(lambda(x)(assoc 2 x))
     (mapcar 'entget(vl-remove-if 'listp
      (mapcar 'cadr(ssnamex selSet)))))
    ); end of namesExtract
  
  (princ "\n<<< Select sample blocks to count >>> ")
  (if(setq blSet(ssget '((0 . "INSERT"))))
    (progn
      (setq filLst(append(list '(0 . "INSERT"))(list '(-4 . "<OR"))
		     (namesExtract blSet)(list '(-4 . "OR>"))))
      (princ "\n<<< Specify area(s) to count >>> ")
       (if(setq blSet(ssget filLst))
	 (progn
	   (setq nameLst(namesExtract blSet))
	   (princ "\n========== COUNT REPORT ==========")
	   (while nameLst
	     (setq curLen(length nameLst))
	     (princ(strcat "\n" (cdar nameLst) " "
			  (itoa(- curLen(length(setq nameLst
			    (vl-remove(car nameLst)nameLst)))))))
	     ); end while
	   (princ "\n=========== END REPORT ===========\n")
	   (textscr)
	   ); end progn
	 ); end if
      ); end progn
    ); end if
  (princ)
  ); end of c:blc

[LElkins]

Do you really need a lisp, or could you use the BCOUNT command which was recently mentioned?

[khama]

Do you really need a lisp, or could you use the BCOUNT command which was recently mentioned?

yes bcount is the go.. and you don't need a lisp for that command..

[ASMI]

sophie
Forum Newbie

Using: AutoCAD 2004

Join Date: Jan 2008
Posts: 3

[NBC]

Bcount became available in AutoCAD 2000 though, according to this - http://www.hyperpics.com/commands/

[ASMI]

Yes, with Express Tools.

[LElkins]

yes, and AutoCAD 2004 had express tools. no?

[khama]

sophie
Forum Newbie

Using: AutoCAD 2004

Join Date: Jan 2008
Posts: 3

Hey good point.. Don't know if it works in autocad 2004... maybe you do need a lisp then to make it happen.. my apologies...

[ASMI]

yes, and AutoCAD 2004 had express tools. no?

Yes. But it not always good tool. For example I want to count certain blocks inside some area. Therefore I consider use of this (or another) LISP quite justified.