Text 2 Attribute

[Srinivas.Vinjamuri]

Hi All,
Is anybody having lisp programme to change text to attributes?
Thanks,
Srinivas Vinjamuri

[ReMark]

You might try over at The Swamp. www.theswamp.org

You'll have to join the forum though. Once you do that conduct a search using as the criteria "text to attribute". Include the quotation marks. It should bring up a post by DanB, Bull Frog containing Carl Rockstrom's Text to Attribute lisp routine. The thread is dated March 02, 2005.

[flowerrobot]

Or Command "burst"
(sorry For Bringing This Alive, Couldnt Help My Self)

[Tiger]

Or Command "burst"
(sorry For Bringing This Alive, Couldnt Help My Self)

It's ok, but BURST changes Attributes to Text - not the other way around, which is what the OP was asking

[flowerrobot]

dnt i feel like a fool.
I thought i finnaly knew an answer

[Lee Mac]

dnt i feel like a fool.
I thought i finnaly knew an answer

Haha, no worries FlowerRobot, When I saw the OP, Burst immediatley sprang to mind...

[David Bethel]

This should do the trick

(defun txt2attd (/ ss ct en ed)
  (while (or (not ss)
             (> (sslength ss) 1))
         (princ "\nSelect A TEXT to Convert to ATTDEF:   ")
         (setq ss (ssget (list (cons 0 "TEXT")
                               (if (setq ct (getvar "CTAB"))
                                   (cons 410 ct)
                                   (cons 67 (- 1 (getvar "TILEMODE")))))))
          (setq en (ssname ss 0)
                ed (entget en))
          (and (wcmatch (cdr (assoc 1 ed)) "* *")
               (getstring "\nString Contains Spaces - Try Again...")
               (setq ss nil)))
  (entmake (list (cons 0 "ATTDEF")
                 (assoc 8 ed)
                 (assoc 10 ed)
                 (assoc 11 ed)
                 (assoc 7 ed)
                 (assoc 40 ed)
                 (assoc 41 ed)
                 (assoc 50 ed)
                 (assoc 51 ed)
                 (cons 70 0)
                 (assoc 71 ed)
                 (assoc 72 ed)
                 (cons 74 (cdr (assoc 73 ed)))
                 (assoc 210 ed)
                 (cons 1 "")
                 (cons 2 (cdr (assoc 1 ed)))
                 (cons 3 (cdr (assoc 1 ed)))
                 (if (assoc 6 ed) (assoc 6 ed)'(6 . "BYLAYER"))
                 (if (assoc 39 ed) (assoc 39 ed)'(39 . 0))
                 (if (assoc 62 ed) (assoc 62 ed)'(62 . 256))))
  (entdel en)
  (redraw)
  (prin1))

-David

[Lee Mac]

David, why not use:

(defun c:txt2attd (/ ss ct en ed)
  (while (not ss)
         (princ "\nSelect A TEXT to Convert to ATTDEF:   ")
         (setq ss (ssget "_:S" (list (cons 0 "TEXT")
                               (if (setq ct (getvar "CTAB"))
                                   (cons 410 ct)
                                   (cons 67 (- 1 (getvar "TILEMODE")))))))
          (setq en (ssname ss 0)
                ed (entget en))
          (and (wcmatch (cdr (assoc 1 ed)) "* *")
               (getstring "\nString Contains Spaces - Try Again...")
               (setq ss nil)))
  (entmake (list (cons 0 "ATTDEF")
                 (assoc 8 ed)
                 (assoc 10 ed)
                 (assoc 11 ed)
                 (assoc 7 ed)
                 (assoc 40 ed)
                 (assoc 41 ed)
                 (assoc 50 ed)
                 (assoc 51 ed)
                 (cons 70 0)
                 (assoc 71 ed)
                 (assoc 72 ed)
                 (cons 74 (cdr (assoc 73 ed)))
                 (assoc 210 ed)
                 (cons 1 "")
                 (cons 2 (cdr (assoc 1 ed)))
                 (cons 3 (cdr (assoc 1 ed)))
                 (if (assoc 6 ed) (assoc 6 ed)'(6 . "BYLAYER"))
                 (if (assoc 39 ed) (assoc 39 ed)'(39 . 0))
                 (if (assoc 62 ed) (assoc 62 ed)'(62 . 256))))
  (entdel en)
  (redraw)
  (prin1))

Instead of

  (while (or (not ss)
             (> (sslength ss) 1))

Just curious

Nice code by the way

[David Bethel]

Those parameters for ssget didn't come around until R14 or R15 and there were only 1 or 2 then. They have added more over the years.

I think that they pretty cryptic looking where as AutoLISP is a fairly human readable language. 1 Reason I don't like vl and vla stuff. Way too long names for functions and not real readable. IMO. -David

PS I just tried it 2000 and it didn't work as advertised

[Tiger]

Just so you know guys, this is an old thread...

but it's sould come in handy in future searches anyway