Adding number to a text string

[Storm2002]

I would like to create a routine to add the current dimscale variable to the end of text string.

Thanks
Derek

[wannabe]

Would the dimscale need to be concurrent with the live dimscale? i.e will you need the text string to be updated to reflect changes to the dimscale value, automatically?

If you don't need it to be automatically updated you could just add a field that is assigned the value of the dimscale system variable.

[Lee Mac]

Quick fix:

(defun c:AddDim  (/ ss)
  (vl-load-com)
  (if (setq ss (ssget (list (cons 0 "*TEXT")
                            (if (getvar "CTAB")
                              (cons 410 (getvar "CTAB"))
                              (cons 67 (- 1 (getvar "TILEMODE")))))))
    (progn
      (foreach x  (mapcar 'entget
                    (vl-remove-if 'listp
                      (mapcar 'cadr (ssnamex ss))))
        (entmod (subst (cons 1 (strcat (cdr (assoc 1 x)) (chr 32)
                                       (rtos (getvar "DIMSCALE"))))
                       (assoc 1 x) x))))
    (princ "\<!> No Text Selected <!>"))
  (princ))

[Storm2002]

I will better describe my intent:

I am trying to automate the process of inserting a block and have it inserted on the correct layer, grab the correct scale factor (based on the current dimscale). Our layers are standard with a suffix for a particular scale.

The layer the block is inserted on is static, except for the scale suffix, (i.e. Layer-25, Layer-50) from drawing to drawing.

Ideally, if the layer does not exist I would like it to be created. Most likely the layer will exist in the drawing the block is being inserted into.

I was thinking that I could read the current dimscale and place it at the end of the layer name and make that layer current prior to inserting the block.

Thanks
Derek

[Lee Mac]

Ok, I think I understand your intents, will see what I can do

[Lee Mac]

Perhaps:

(defun c:Blklay (/ lDim)
  (vl-load-com)
  (setq lDim (strcat "Layer-" (rtos (getvar "DIMSCALE"))))
  (or (tblsearch "LAYER" lDim)
      (vla-add (vla-get-Layers
                 (vla-get-ActiveDocument
                   (vlax-get-acad-object))) lDim))
  (setvar "CLAYER" lDim)
  (princ))

[David Bethel]

This assumes that your DIMSCALE is a whole number

(defun SetLayer (name / ldef flag)
  (cond ((or (not name)
             (not (snvalid name)))
         (princ "\nBad Aurgment Passed To SetLayer - ")
         (prin1 name)
         (exit)))
  (command "_.LAYER")
  (if (not (tblsearch "LAYER" name))
      (command "_Make" name)
      (progn
        (setq ldef (tblsearch "LAYER" name)
              flag (cdr (assoc 70 ldef)))
        (and (= (logand flag  1)  1)
             (command "_Thaw" name))
        (and (minusp (cdr (assoc 62 ldef)))
             (command "_On" name))
        (and (= (logand flag  4)  4)
             (command "_Unlock" name))
        (and (= (logand flag 16) 16)
             (princ "\nCannot Set To XRef Dependent Layer")
             (quit))
        (command "_Set" name)))
  (command "")
  name)

(SetLayer (strcat "LAYER-" (rtos (getvar "DIMSCALE") 2 0)))

-David

[Storm2002]

That was perfect...thanks a whole bunch!!!!

Derek

[Lee Mac]

I suppose a reactor could be used also - hasn't got the error trapping standard of Davids though

(defun c:Ron  ()
  (vl-load-com)
  (if (not blk:react)
    (setq blk:react
           (vlr-command-reactor nil
             '((:vlr-commandWillStart . Blklay)
               (:vlr-commandEnded . Blkend)
               (:vlr-commandCancelled . Blkcan)))))
  (princ "\n<<--  Block Reactor ON  -->>")
  (princ))

(defun c:Roff  ()
  (if blk:react
    (progn
      (vlr-remove blk:react)
      (setq blk:react nil)
      (princ "\n<<--  Block Reactor OFF  -->>")))
  (princ))

(defun Blklay  (Reac Args / lDim)
  (vl-load-com)
  (and (eq "INSERT" (car Args))
       (setq oLay (getvar "CLAYER")
             lDim (strcat "Layer-" (rtos (getvar "DIMSCALE"))))
       (or (tblsearch "LAYER" lDim)
           (vla-add (vla-get-Layers
                      (vla-get-ActiveDocument
                        (vlax-get-acad-object))) lDim))
       (setvar "CLAYER" lDim))
  (princ))

(defun Blkend  (Reac Args)
  (if oLay
    (setvar "CLAYER" oLay))
  (princ))

(defun Blkcan  (Reac Args)
  (if oLay
    (setvar "CLAYER" oLay))
  (princ))

Type "Ron" to turn on and "Roff" to turn off

[Storm2002]

Is there an advantage of error trapping?