Search and replace inside string variable?

[ajs]

Dos anyone know if it is possible to run a find and replace within a string variable?

I have a string variable that holds a string that concantenates a room name, letter and material: Example: Master Bath--A--Eos Acadia.

I am able to remove the spaces from the variable via the "trim" function:

(setq PRINT_CNC_TEXT(trim PRINT_CNC_TEXT "BMA" ))

What I would also like to do is replace the two dashes with a single dash. I tried the following but it didn't work:

(subst '"--" '"-" '("PRINT_CNC_TEXT"))

Is there a way to do this inside the variable as opposed to running a search and replace inside the drawing?

Thank you.

AJS

[Lee Mac]

Try running this on your drawing:

(defun c:repDash  (/ ss tStr pos)
  (vl-load-com)
  (if (setq ss (ssget "X"
                      (list (cons 0 "TEXT,MTEXT")
                            (cons 1 "*--*")
                            (if (getvar "CTAB")
                              (cons 410 (getvar "CTAB"))
                              (cons 67 (- 1 (getvar "TILEMODE")))))))
    (foreach x  (mapcar 'vlax-ename->vla-object
                  (mapcar 'cadr
                    (ssnamex ss)))
      (setq tStr (vla-get-TextString x))
      (while (setq pos (vl-string-search "--" tStr))
        (setq tStr (strcat
                     (substr tStr 1 pos) (chr 45)
                       (substr tStr (+ pos 3)))))
      (vla-put-TextString x tStr))
    (princ "\n<!> No Text Found <!>"))
  (princ))

[Freerefill]

(if (getvar "CTAB") ... shouldn't that always return true? Is there any way for "CTAB" to be nil?

Also, couldn't you use (vl-string-subst) instead of (strcat)?

Sorry if I'm asking too many questions, I only just started getting into VLA like.. last week.. it's very new to me and I'm learning a lot, and quickly.

[Lee Mac]

Great idea about using vl-string-subst, with so many VL functions, you sometimes forget a few

(defun c:repDash  (/ ss tStr)
  (vl-load-com)
  (if (setq ss (ssget "X"
                      (list (cons 0 "TEXT,MTEXT")
                            (cons 1 "*--*")
                            (if (getvar "CTAB")
                              (cons 410 (getvar "CTAB"))
                              (cons 67 (- 1 (getvar "TILEMODE")))))))
    (foreach x  (mapcar 'vlax-ename->vla-object
                  (mapcar 'cadr
                    (ssnamex ss)))
      (setq tStr (vla-get-TextString x))
      (while (vl-string-search "--" tStr)
        (setq tStr (vl-string-subst "-" "--" tStr)))
      (vla-put-TextString x tStr))
    (princ "\n<!> No Text Found <!>"))
  (princ))

As for the CTAB, R14 didn't have it.

[Freerefill]

Ah, I see I see.. wow, that's a job itself, trying to make it all backwards compatible. I never did use R14.. just how different is it from, say, 2004, or 2008? I'd imagine it must at least have VL, but that it wouldn't have "ctab"...

[Lee Mac]

Ah, I see I see.. wow, that's a job itself, trying to make it all backwards compatible. I never did use R14.. just how different is it from, say, 2004, or 2008? I'd imagine it must at least have VL, but that it wouldn't have "ctab"...

Good point, I suppose the IF statement isn't required here as R14 didn't have VL either - I just keep the ssget code as a set block of code and copy it when I need it... need to look over it more in the future.

[ajs]

Thank you very much!

[Lee Mac]

No probs, happy to help