Text alignment

[VisDak]

Hi Good day to all, is there any body have a route that will arrange and aligned the text/mtext/attribute on any place where i want to pick on sides or middle (as shown on image)

By selecting all the text i need to align it on the left or middle or right side so that we will not be able to eye ball it by text alignment. please

Thanks to all

[Lee Mac]

This should do MTEXT and TEXT:

(defun c:talign  (/ ss pt tmp elst)
  (vl-load-com)
  (or tal:def (setq tal:def "Left"))
  (if (and (setq ss (ssget '((0 . "*TEXT"))))
           (setq pt (getpoint "\nSelect Alignment Point: ")))
    (progn
      (initget "Left Middle Right")
      (setq tmp (getkword (strcat "\nAlignment? [L/M/R] <" tal:def ">: ")))
      (or (not tmp) (setq tal:def tmp))
      (foreach elst  (mapcar 'entget
                       (vl-remove-if 'listp
                         (mapcar 'cadr (ssnamex ss))))
        (cond ((eq "TEXT" (cdr (assoc 0 elst)))
               (setq elst (mod 10 (list (car pt)
                                        (caddr (assoc 10 elst))
                                        (cadddr (assoc 10 elst))) elst))
               (mod 72 (cond ((eq tal:def "Left") 0)
                             ((eq tal:def "Middle") 1)
                             ((eq tal:def "Right") 2))
                    (mod 11 (cdr (assoc 10 elst)) elst)))
              ((eq "MTEXT" (cdr (assoc 0 elst)))
               (setq elst (mod 10 (list (car pt)
                                        (caddr (assoc 10 elst))
                                        (cadddr (assoc 10 elst))) elst))
               (mod 71 (cond ((eq tal:def "Left") 1)
                             ((eq tal:def "Middle") 2)
                             ((eq tal:def "Right") 3)) elst)))))
    (princ "\n<!> No Text Selected <!>"))
  (princ))

(defun mod (code val elst)
  (entmod
    (subst
      (cons code val)
        (assoc code elst) elst)))

[VisDak]

Thank Lee, function is great only i cannot used on UCS rotated plan, its jump aways the text, can be fix it, Thanks again

[Lee Mac]

Give this a shot, should work with UCS (hopefully!):

(defun c:talign  (/ ss pt tmp elst)
  (vl-load-com)
  (or tal:def (setq tal:def "Left"))
  (if (and (setq ss (ssget '((0 . "*TEXT"))))
           (setq pt (getpoint "\nSelect Alignment Point: ")))
    (progn
      (setq pt (trans pt 1 0))
      (initget "Left Middle Right")
      (setq tmp (getkword (strcat "\nAlignment? [L/M/R] <" tal:def ">: ")))
      (or (not tmp) (setq tal:def tmp))
      (foreach elst  (mapcar 'entget
                       (vl-remove-if 'listp
                         (mapcar 'cadr (ssnamex ss))))
        (cond ((eq "TEXT" (cdr (assoc 0 elst)))
               (setq elst (mod 10 (list (car pt)
                                        (caddr (assoc 10 elst))
                                        (cadddr (assoc 10 elst))) elst))
               (mod 72 (cond ((eq tal:def "Left") 0)
                             ((eq tal:def "Middle") 1)
                             ((eq tal:def "Right") 2))
                    (mod 11 (cdr (assoc 10 elst)) elst)))
              ((eq "MTEXT" (cdr (assoc 0 elst)))
               (setq elst (mod 10 (list (car pt)
                                        (caddr (assoc 10 elst))
                                        (cadddr (assoc 10 elst))) elst))
               (mod 71 (cond ((eq tal:def "Left") 1)
                             ((eq tal:def "Middle") 2)
                             ((eq tal:def "Right") 3)) elst)))))
    (princ "\n<!> No Text Selected <!>"))
  (princ))

(defun mod (code val elst)
  (entmod
    (subst
      (cons code val)
        (assoc code elst) elst)))

[VisDak]

Hi Lee little bit more, the text is not now thrown around only it will not align vertical its just aligning according to Y axis inclined to UCS, see image thanks for your hard work on it Lee,

[Lee Mac]

Are you sure you are trying the new version? - it works fine for me

Try closing and re-opening your drawing, and reload the routine and test it again.

[VisDak]

Yes its ok LEE, i have an idea how i will us with out using the UCS, i will set to work the text on layout tabs not in the model tabs i will used only the model tabs for working drawings (plans and layouts),

If the TEXT are completed on the layout tabs, i will use the "talign.Lsp" to align the text and then command "CHSPACE" and select all text and leaders and presto!! the text are transfer to model that not affects the text alingment..

Thanks LEE for the Lisp..

[Lee Mac]

No probs dude