Lisp Command For Setting The Auto File Save Location

[ReinierMeyer]

Does anybody know what the command is to set the Auto save file location using a lisp routine

like the following sets the Template path,

(vla-put-TemplateDwgPath *files* "\\\\Server\\Data\\Cad_Programs\\Autocad\\Draw ing Templates")

I need to set the Autosave file location.

Please Help!!!!

[MarcoW]

Do you happen to be dutch?

 
; MarcoW 09-11-2009
;
; first create the function
; and localise the variables used
 (defun c:asf ( / asfloc oldloc)
; then set some variables that will be used
 (setq asfloc (getstring T "\nPlease enter the automatic Save File Location as desired:  ")
  oldloc (getvar "savefilepath")
 ); end of setq
; put the new path into the systemvariable
 (setvar "savefilepath" asfloc)
; show the old location once more, you might want to write down its location for you never know if you want it back
 (alert (strcat "The old path was: " oldloc))
; clean exit
  (princ)
; end of defun
)

Just wrote it but I guess it works.

Someone might help you along getting the right folder by selecting it in a dialog box.

[ReinierMeyer]

Thanks .

Nope not Dutch, Afrikaans from South Africa simlilar to Dutch.

[Tekenmeester]

Is this not what you are looking for?

It is in options under the files tab.

[alanjt]

I wrote this a while back to run on new machines for complete setup.
Obviously, you will have to make changes to the specifics, but it will have what you are looking for.

(defun c:CES-Setup (/ #Files #Layout #Flag)
  (vl-load-com)
  (and
    (not
      (vl-catch-all-error-p
        (vl-catch-all-apply
          '(lambda ()
             (setq #Files  (vla-get-files
                             (vla-get-preferences (vlax-get-acad-object))
                           ) ;_ vla-get-files
                   #Layout (vla-get-activelayout
                             (vla-get-activedocument (vlax-get-acad-object))
                           ) ;_ vla-get-activelayout
             ) ;_ setq
             ;; *********************
             ;; **  AutoSave Path  **
             ;; *********************
             (mapcar 'vl-mkdir (list "c:\\TEMP" "c:\\TEMP\\ACAD"))
             (vla-put-autosavepath #Files "c:\\TEMP\\ACAD")
             ;; ***************************
             ;; **  Printer Config Path  **
             ;; ***************************
             (vla-put-PrinterConfigPath
               #Files
               "s:\\cadd standards\\Plotters"
             ) ;_ vla-put-PrinterConfigPath
             (vla-refreshplotdeviceinfo #Layout)
             ;; ***********************
             ;; **  Plotstyles Path  **
             ;; ***********************
             (vla-put-printerstylesheetpath
               #Files
               "s:\\cadd standards\\Plotstyles"
             ) ;_ vla-put-printerstylesheetpath
             (vla-refreshplotdeviceinfo #Layout)
             ;; *********************
             ;; **  Template Path  **
             ;; *********************
             (vla-put-TemplateDwgPath
               #Files
               "s:\\cadd standards\\Template"
             ) ;_ vla-put-TemplateDwgPath
             ;; *********************
             ;; **  QNew Template  **
             ;; *********************
             (vla-put-QNewTemplateFile
               #Files
               "s:\\cadd standards\\Template\\CES_Template.dwt"
             ) ;_ vla-put-QNewTemplateFile
             ;; *********************
             ;; **  Support Paths  **
             ;; *********************
             (vla-put-supportpath
               #Files
               (strcat ";s:\\cadd standards\\startup"
                       ";s:\\cadd standards\\lisp"
                       ";s:\\cadd standards\\linetypes"
                       ";s:\\cadd standards\\fonts"
                       ";s:\\cadd standards\\ces layers"
                       ";"
                       (vla-get-supportpath #Files)
               ) ;_ strcat
             ) ;_ vla-put-supportpath
             ;; ***************************
             ;; **  Tool Palettes Paths  **
             ;; ***************************
             (vla-put-ToolPalettePath
               #Files
               (strcat "S:\\CADD Standards\\Toolpalette\\Palettes;"
                       (vla-get-ToolPalettePath #Files)
               ) ;_ strcat
             ) ;_ vla-put-ToolPalettePath
           ) ;_ lambda
        ) ;_ vl-catch-all-apply
      ) ;_ vl-catch-all-error-p
    ) ;_ not
    (alert
      (strcat
        "AutoCAD has been setup for Capital Engineering & Surveying, Inc. Standards.\n\n"
        "                      Please restart AutoCAD."
      ) ;_ strcat
    ) ;_ alert
  ) ;_ and
  (princ)
) ;_ defun
(alert "Type: \"CES-SETUP\" to run setup.")
(princ)