Lisp for attribute extract from block

[sadhu]

I got most of the code below from here
What I am trying to do is read the attribute value and tag from a block (the block has multiple attributes). When I (princ) it, it returns nil. What am I doing wrong ?

thanks

(defun c:sk (/)
(if (setq ent(entsel "\n Select a Block: "))  ;- Let the user select a block
(progn                                                   
  (setq en(car ent))                                                        ;- Get the entity name of the block
  (setq enlist(entget en))                                          ;- Get the DXF group codes
  (setq blkType(cdr(assoc 0 enlist)))                 ;- Save the type of entity
  (if (= blkType "INSERT")                                          ;- If the entity type is an Insert entity
   (progn
    (if(= (cdr(assoc 66 enlist)) 1)    ;- See if the attribute flag equals one (if so, attributes follow)
    (progn
      (setq en2(entnext en))                                    ;- Get the next sub-entity
      (setq enlist2(entget en2))                           ;- Get the DXF group codes
      (while (/= (cdr(assoc 0 enlist2)) "SEQEND")  ;- Start the while loop and keep   
        (princ "\n ")                                                 ;-Print a new line
        (princ enlist2)                                               ;- Print the attribute DXF group codes
        (setq en2(entnext en2))                             ;- Get the next sub-entity
        (setq enlist2(entget en2))                      ;- Get the DXF group codes
      )
     )
    )  ;- Close the if group code 66 = 1 statement
   )
  )   ;- Close the if block type = "ATTRIB" statement
)
)   ;- Close the if an Entity is selected statement
  (setq att_value (cdr (assoc 1 enlist2)))
  (princ "\nAtt_value  :  ")
  (princ att_value)
  (setq att_tag (cdr (assoc 2 enlist2)))
  (princ "\nAtt_tag  :  ")
  (princ att_tag)
 
)

[Lee Mac]

Perhaps:

(defun c:sk (/ dxf ent)

  (defun dxf (code ent) (cdr (assoc code (entget ent))))

  (if (and (setq ent (car (entsel "\nSelect an Attributed Block: ")))
           (eq "INSERT" (dxf 0 ent))
           (= 1 (dxf 66 ent)))

    (while (not (eq "SEQEND" (dxf 0 (setq ent (entnext ent)))))
      (princ (strcat "\n\nAtt_Tag:" (dxf 2 ent) "\nAtt_Value: " (dxf 1 ent)))))

  (princ))

[alanjt]

What a strange thing to list. This information can be seen by double-clicking on the attributed block and looking at that editor.

[Lee Mac]

What a strange thing to list. This information can be seen by double-clicking on the attributed block and looking at that editor.

I think it's more of a learning exercise

[alanjt]

I think it's more of a learning exercise

Perhaps, it just seemed odd.

[sadhu]

I just read the posts. Thanks Lee for your code. It is what I wanted to do. Now I have to study all of your code because what I have to do to is even more complex. All the posts I have made serve for the same project.

Anyway I have started.

Now I need to transfer these att_value to another block (the block isn't on the drawing yet). So I have to call this block "RH" change its att_value (replace them with the ones just read and place it on the drawing.

So you see, it is learning and exercise though it may seem odd. Maybe what I ask is so simple to you guys that it seems odd.

Both of you are of great help.

[sadhu]

Can you add another feature to your code that can read and extract sub-entity ( I mean blocks inside blocks - one level) tags, values and prints them.

sub-entity-1 name : xxx
sub-entity-1 tag: xxx
sub-entity-1 value : xxx

....

(defun c:sk (/ dxf ent)

  (defun dxf (code ent) (cdr (assoc code (entget ent))))

  (if (and (setq ent (car (entsel "\nSelect an Attributed Block: ")))
           (eq "INSERT" (dxf 0 ent))
           (= 1 (dxf 66 ent)))

    (while (not (eq "SEQEND" (dxf 0 (setq ent (entnext ent)))))
      (princ (strcat "\n\nAtt_Tag:" (dxf 2 ent) "\nAtt_Value: " (dxf 1 ent)))))

  (princ))

Thanks

[Lee Mac]

Not a simple addition, you would have to dig into the block definition for that.

[Lee Mac]

Check this by CAB

[BIGAL]

You can definately change the values of one block but pick another block to get the values. You just need to know the name of each block your working with.

We do something like your asking pick a block on the layout (model space) it then updates another block with information from the model the other block can be anywhere in the total Autocad dwg usually in a layout tab.

It reads the displayed attributes as a common ID link