Center Text in a Circle

[Bill Tillman]

I did a search and didn't seem to find anything on this. I draw architectual floor plans and create column lines with a circle on the end of the line. I then insert text in the circle. usually a single digit or alpha character. The trouble is I often spend too much time trying to get the text to fit nicely in the center of the circle. Can anyone help me with this?

[lpseifert]

Middle (Middle center) justify the text and use the center osnap of the circle as the insert point for the text.

[alanjt]

How about a Dynamic Attributed block with a scale parameter?

[Tankman]

Or, try this lisp?

[alanjt]

One more, just for fun...

(defun c:TIC (/ label pt dist)
  ;; MText label witin circle
  ;; Alan J. Thompson, 05.22.10

  (vl-load-com)
  (if (and (/= "" (setq label (getstring t "\nSpecify label: ")))
           (setq pt (getpoint "\nSpecify center point: "))
           (setq dist (getdist pt "\nSpecify radius of circle: "))
      )
    ((lambda (p)
       (entmakex (list '(0 . "CIRCLE") (cons 10 p) (cons 40 dist)))
       ((lambda (text)
          (vla-put-AttachmentPoint text 5)
          (vla-put-InsertionPoint text (vlax-3d-point p))
        )
         (vla-addMText
           (if (or (eq acmodelspace
                       (vla-get-activespace
                         (cond (*AcadDoc*)
                               ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
                         )
                       )
                   )
                   (eq :vlax-true (vla-get-mspace *AcadDoc*))
               )
             (vla-get-modelspace *AcadDoc*)
             (vla-get-paperspace *AcadDoc*)
           )
           (vlax-3d-point p)
           0.
           label
         )
       )
     )
      (trans pt 0 1)
    )
  )
  (princ)
)

[alanjt]

(defun c:TCL (/ obj label)
  ;; Label selected circle with MText
  ;; Alan J. Thompson, 05.22.10

  (vl-load-com)
  (if (and (setq obj (car (entsel "\nSelect circle: ")))
           (or (eq "AcDbCircle" (vla-get-objectname (setq obj (vlax-ename->vla-object obj))))
               (alert "Invalid object!")
           )
           (/= "" (setq label (getstring t "\nSpecify label: ")))
      )
    ((lambda (p)
       ((lambda (text)
          (vla-put-AttachmentPoint text 5)
          (vla-put-InsertionPoint text p)
        )
         (vla-addMText
           (if (or (eq acmodelspace
                       (vla-get-activespace
                         (cond (*AcadDoc*)
                               ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
                         )
                       )
                   )
                   (eq :vlax-true (vla-get-mspace *AcadDoc*))
               )
             (vla-get-modelspace *AcadDoc*)
             (vla-get-paperspace *AcadDoc*)
           )
           p
           0.
           label
         )
       )
     )
      (vla-get-center obj)
    )
  )
  (princ)
)

[Lee Mac]

May help.

[ReMark]

Bill:

It was right there under your nose the entire time. You just had to look on your Tool Palettes on the Annotation tab. The very first entry at the top called Tag - Imperial is a number within a circle. The number is an attribute.

Seek and ye shall find.

I'm running 2010 too.

[gsksun4]

Bill:

It was right there under your nose the entire time. You just had to look on your Tool Palettes on the Annotation tab. The very first entry at the top called Tag - Imperial is a number within a circle. The number is an attribute.

Seek and ye shall find.

I'm running 2010 too.

ReMark, another good find. Would like to know why the text in the circle doesn't take on the font set in the drawing? Or how can I set it to? It doesn't list out a font, and I don't want to explode it, but just to see what font lists out I did. No font listed, but style lists out as Tohoma.
Glenn
2009LT

[ReMark]

It's an attribute. The font can be reset.