Something wrong with CLAYER

[Tharwat]

Hello
Something wrong with making layer current and CLAYER,

(defun c:ww (/ curlay width)
  (prompt "This is Duct Design program . ...")
  (setq curlay (getvar "clayer"))
    (if (/= (cdr(setq ser(tblsearch "layer" "acduct")))"acduct")
       (progn
	(command "_-layer" "_make" "ACDUCT" "_ltype" "continuous" "" "_color" "142" "" "")
        (command "_-layer" "_set" "ACDUCT" "" ""))
  (setvar "clayer" "ACDUCT"))
  (setq width (getint"\nSpecify width of Duct:"))
  (command "_mline" "_J" "_z" "_scale" width )
  (setvar "clayer" curlay)
  (princ)
  )

Regards
Tharwat

[profcad]

I think this is what you are looking for...

I removed the code
(command "_-layer" "_set" "ACDUCT" "" ""))

(defun c:ww2 (/ curlay width)
  (prompt "This is Duct Design program . ...")
  (setq curlay (getvar "clayer"))
    (if (/= (cdr(setq ser(tblsearch "layer" "acduct")))"acduct")
       (progn
         (command "_-layer" "_make" "ACDUCT" "_ltype" "continuous" "" "_color" "142" "" "")
         (setvar "clayer" "ACDUCT")
       );progn
      );if
  (setq width (getint"\nSpecify width of Duct:"))
  (command "_mline" "_J" "_z" "_scale" width )
  (setvar "clayer" curlay)
  (princ)
  )

[Tharwat]

I think this is what you are looking for...

I removed the code
(command "_-layer" "_set" "ACDUCT" "" ""))

(defun c:ww2 (/ curlay width)
  (prompt "This is Duct Design program . ...")
  (setq curlay (getvar "clayer"))
    (if (/= (cdr(setq ser(tblsearch "layer" "acduct")))"acduct")
       (progn
         (command "_-layer" "_make" "ACDUCT" "_ltype" "continuous" "" "_color" "142" "" "")
         (setvar "clayer" "ACDUCT")
       );progn
      );if
  (setvar "layer" "ACDUCT")
  (setq width (getint"\nSpecify width of Duct:"))
  (command "_mline" "_J" "_z" "_scale" width )
  (setvar "clayer" curlay)
  (princ)
  )

Thanks for your reply , But the Clayer is still not responding by putting the current layer "ACDUCT" on, and to implement the following mline works through that layer.

Any other solution would be highly apprecaited.
Best Regards.

Tharwat

[David Bethel]

Using (setvar "CLAYER" ) isn't the best way to create a layer

It takes a bit more error trapping etc:

(defun SetLayer (name / ldef flag)
  (command "_.LAYER")
  (if (not (tblsearch "LAYER" name))
      (command "_Make" name)
      (progn
        (setq ldef (tblsearch "LAYER" name)
              flag (cdr (assoc 70 ldef)))
        (and (= (logand flag  1)  1)
             (command "_Thaw" name))
        (and (minusp (cdr (assoc 62 ldef)))
             (command "_On" name))
        (and (= (logand flag  4)  4)
             (command "_Unlock" name))
        (and (= (logand flag 16) 16)
             (princ "\nCannot Set To XRef Dependent Layer")
             (quit))
        (command "_Set" name)))
  (command "")
  name)

(and (/= (strcase (getvar "CLAYER")) "ACDUCT")
     (SetLayer "ACDUCT")
     (command "_.LAYER" "_LT" "Continuous" "ACDUCT" ......  ""))

Checking for (snvalid) is also a good thing.

-David

[Tharwat]

Thanks David
But SetLayer is not function definition in my system. And the way you making a layer is not familiar to me .


I do not know ...... anyway thank you.

[profcad]

tharwat313,

The problem is with the mline command itself. You need a way to input multiple pauses for the ponits that you pick. The original program is running the last line (setvar "clayer" currlay) before the completes the mline command.

I simplified the if statement, added a while loop to catch all the points for the mline command and a default duct width.

(defun c:ww3 (/ curlay width)
  (prompt "This is Duct Design program . ...")
  (setq curlay (getvar "clayer"))
    (if (tblsearch "layer" "acduct")  ;if layer exist, set it current, if not create it.
         (command "_-layer" "_set" "ACDUCT" "")
         (command "_-layer" "_make" "ACDUCT" "_ltype" "continuous" "" "_color" "142" "" "")
      );if
  (setq width (getint"\nSpecify width of Duct <10>: "))
  (if (null width) (setq width 10))
  (command "_mline" "_J" "_z" "_scale" width )
  (while 
      (= (logand (getvar "cmdactive") 1) 1)
      (command pause)
    );while
  (setvar "clayer" curlay)
  (princ)
  )

[Tharwat]

Mr. Profcad

Really wonderful that's what I have been looking for.

So you pause the command mline by the use of (command pause) and during that period, the Layer created or set current according to the situations and reinvoked the command of Mline .... Am I right ... ?


Thank you soooo much
Best Regards
Tharwat