generate layers based on color?

[arqi]

hey guys i have a file with 2 dozen layers each with objects in 12 different colors and i need to sort them out into layers depending on the objects color. e.g. all the objects with color "yellow" in one layer, all the objects with color "magenta" in another layer etc. can this be done with a lisp? can anyone help me i now nothing about writing lisp's

[BlackBox]

This should get you started:

((lambda (i / ss e c)
  (setq ss (ssget))
  (while (setq e (ssname ss (setq i (1+ i))))
    (cond 
      ((= 1 (setq c (cdr (assoc 62 (entget e)))))
        ;; <- Code for red objects
        )
      ((= 2 c)
        ;; <- Code for yellow objects
        )
      ((= 3 c)
        ;; <- Code for green objects
        )
      ((= 4 c)
        ;; <- Code for cyan objects
        )
      ;; <- Additional colors here
    ))
  (princ))
-1)

[arqi]

thanks RenderMan i will try it out, all dough i have no experience with writing lisp, if you could fill in some of the blancks foor me that would be great!

[Tharwat]

This may help you and the main idea of the routine is inspired by RenderMan .

(defun c:test (/ ss)
(if (setq ss (ssget "_:L" ))
 (
  (lambda (i / ss1 e col)
   (while
     (setq ss1 (ssname ss (setq i (1+ i))))
       (setq e (entget ss1))
         (setq col (cdr (assoc 62 e)))
         (cond ((eq 1 col)
            (entupd (cdr (assoc -1 (entmod (subst (cons 8 "Layer1")(assoc 8 e) e))))))
           ((eq 2 col)
                (entupd (cdr (assoc -1 (entmod (subst (cons 8 "Layer2")(assoc 8 e) e))))))
           ((eq 3 col)
                   (entupd (cdr (assoc -1 (entmod (subst (cons 8 "Layer3")(assoc 8 e) e))))))
            )
          )
        )
     -1
    )
   (princ)
    )
  (princ)
  )

Tharwat

[Smirnoff]

This will distribute all entities with non 'By Layer' color to layers named 'Color N'. Entities which have 'By Layer' color or on locked or frozen layers will be passed.

(defun c:colay(/ aSet lCol cLay)
  
  (vl-load-com)
  
  (if(setq aSet(ssget "_X"))
    (progn
      (setq lCol(vla-get-Layers
		  (vla-get-ActiveDocument
		    (vlax-get-acad-object))))
    (foreach e(vl-remove-if 'listp(mapcar 'cadr(ssnamex aSet)))
      (if(setq cCol(cdr(assoc 62(entget e))))
	   (setq cLay(strcat "Color " (itoa cCol))
		 cFlg T)
	   (setq cFlg nil)
	); end if
     (if cFlg
       (progn
        (if(vl-catch-all-error-p
	    (vl-catch-all-apply
	     'vla-Item (list lCol cLay)))
	  (vla-Add lCol cLay)
	); and if
	(vl-catch-all-error-p
	    (vl-catch-all-apply
	     'vla-put-Layer (list e cLay)))
       ); end progn
       ); end if
      ); end foreach
     ); end progn
    ); end if
  (princ)
  ); end of c:colay

[David Bethel]

Or something fairly simple should work as well:

(defun c:enc (/ ss en ed clr)
  (and (setq ss (ssget))
       (while (setq en (ssname ss 0))
              (setq ed (entget en))
              (if (setq clr (cdr (assoc 62 ed)))
                  (entmod (subst (cons 8 (strcat "C" (itoa clr)))
                                 (assoc 8 ed) ed)))
             (ssdel en ss)))
  (prin1))

Bylayer entities are not affected. New layer name is "C" and the color number. -David

[Smirnoff]

(entmod (subst (cons 8 (strcat "C" (itoa clr)))(assoc 8 ed) ed))

Here is very good solution. Entmod entity and create layer at once.

[fixo]

Are you back, friend???
Knock my door

Oleg

[Smirnoff]

Are you back, friend??

Hi Oleg. Yes I'm back working in AutoCAD and will sometimes coming here.

Alexander.

[Lee Mac]

ASMI, is that you? Good to see you back if so