select last "n" entities drawn inside a lisp

[flopo]

Hello guys,
Using a lisp, i draw few entities; how can i select them? I mean, last "n" entities drawn inside a lisp. Thanks!

[Tharwat]

Here are two examples .

  (setq line1 (entmakex (list (cons 0 "LINE")(cons 10 p1) (cons 11 p2))))

Or..

(entmakex (list (cons 0 "LINE")(cons 10 p1) (cons 11 p2)))
(setq line1 (entlast))

Tharwat

[LibertyOne]

how about something like this?

 
;;--------------------------------------------------------------;;
;; SINCE
;; Creates a selection set of all objects created SINCE the
;; selected one.
(defun since (/ ss en)
 (setq ss (ssadd))
 (setq en (car (entsel "\nSelect first object: ")))
 (setq ss (ssadd en ss))
 (while (setq en (entnext en))
  (setq ss (ssadd en ss))
 )
 ss
)

[irneb]

Another way could be to save the value of entlast just before creating the entities. Then use entnext to step through all that have been made thereafter. E.g.:

(defun c:MyFunc (/ lastEnt ss)
  ;; Save the last entity
  (setq lastEnt (entlast))
  ;; Do some stuff
  ;; ....
  ;; Select all entities created in this function
  (setq ss (ssadd))
  (while (setq lastEnt (entnext lastEnt))
    (ssadd lastEnt ss)
  )
  (sssetfirst nil ss) ;Grip select the set
  (princ) ;Exit cleanly
)

[LibertyOne]

Another way could be to save the value of entlast just before creating the entities. Then use entnext to step through all that have been made thereafter. E.g.:

(defun c:MyFunc (/ lastEnt ss)
;; Save the last entity
(setq lastEnt (entlast))
;; Do some stuff
;; ....
;; Select all entities created in this function
(setq ss (ssadd))
(while (setq lastEnt (entnext lastEnt))
(ssadd lastEnt ss)
)
(sssetfirst nil ss) ;Grip select the set
(princ) ;Exit cleanly
)

This is also a good idea, but I would make a function to set a marker, and another to then retrieve the entities that were made after the marker.

(defun set-bookmark ()
   (setq ent-mark (entlast))
)

once this function is defined, you can go about placing it in your code where ever you see fit.

;; ...your code...
(set-bookmark)
;; ...your code...

once a bookmark is set, there are endless possibilities of what you can do with the selection sets.

You can even set multiple markers and use them to create selection sets "in between" and not just from a certain entity to the end.

[irneb]

Exactly! It's how I created my Select Result routine.