+ Reply to Thread
Page 2 of 4 FirstFirst 1 2 3 4 LastLast
Results 11 to 20 of 35
  1. #11
    Forum Deity David Bethel's Avatar
    Discipline
    Multi-disciplinary
    David Bethel's Discipline Details
    Discipline
    Multi-disciplinary
    Details
    Commercial Food Service
    Using
    AutoCAD pre 2000
    Join Date
    Dec 2003
    Location
    Newport News, Virginia
    Posts
    2,075

    Default

    Registered forum members do not see this ad.

    Quote Originally Posted by kruuger View Post
    that's very clever David. i like it.
    replace command with vla and will be perfect
    Thanks. I don't have access to vl* calls in most of the versions I run so I get to stick with (command....

    -David
    R12 (Dos) - A2K

  2. #12
    Senior Member lamensterms's Avatar
    Computer Details
    lamensterms's Computer Details
    Operating System:
    Windows 7 - 64bit
    Discipline
    Manufacture
    lamensterms's Discipline Details
    Occupation
    Steel Detailer
    Discipline
    Manufacture
    Details
    3D Modelling - Mechanical & Structural 2D Detailing - Shop Drawings
    Using
    AutoCAD 2014
    Join Date
    May 2011
    Location
    Berwick, VIC, Australia
    Posts
    415

    Default

    Thanks so much for all your replies guys.

    David

    That routine does work well on ordinary AutoCAD entitiest (lines, solids, etc)… but im afraid it wont run on ProSteel objects. Im thinking it must have something to do with assigning the XDATA.

    ProSteel has a proprietary object type that is uses to contain all necessary data. These are 3D objects, but not ACIS solids.

    Thanks for your efforts though.


    Thanks a lot to everyone else for the pointers… looks like ill have to do some reading on VLA functions and VLISP.

    I shall let you all know how I go.

  3. #13
    Forum Deity David Bethel's Avatar
    Discipline
    Multi-disciplinary
    David Bethel's Discipline Details
    Discipline
    Multi-disciplinary
    Details
    Commercial Food Service
    Using
    AutoCAD pre 2000
    Join Date
    Dec 2003
    Location
    Newport News, Virginia
    Posts
    2,075

    Default

    Hmmmmm That's strange. I've used this scenario for 10+ years and never ran across anything that it couldn't handle ( excluding VIEWPORT entities ). Can you post a sample dwg? -David
    R12 (Dos) - A2K

  4. #14
    Senior Member lamensterms's Avatar
    Computer Details
    lamensterms's Computer Details
    Operating System:
    Windows 7 - 64bit
    Discipline
    Manufacture
    lamensterms's Discipline Details
    Occupation
    Steel Detailer
    Discipline
    Manufacture
    Details
    3D Modelling - Mechanical & Structural 2D Detailing - Shop Drawings
    Using
    AutoCAD 2014
    Join Date
    May 2011
    Location
    Berwick, VIC, Australia
    Posts
    415

    Default

    Hi again David,

    I have attached a .DWG (2000) containing some ProSteel objects. Though i have noticed that if the program ProSteel is not running - AutoCAD can only recognise these objects as "ACAD_PROXY_ENTITY" - rather than the true ProSteel shape.

    Though it should still demonstrate how the routine wont run on these object types.

    Thanks again mate.

    Sample_ProSteel_Objects.dwg

    ps:... i think i may have increased the reliability of my original routine... simply by making sure the UCS is not in 'world' while the routine is running. Still experimenting - its seems that ProSteels show/hide function is not completely stable - hence my routine also being unstable.

  5. #15
    Senior Member
    Computer Details
    VVA's Computer Details
    Operating System:
    Windows 7
    CPU:
    Intel Core i5-2400
    RAM:
    8 Gb
    Graphics:
    Nvidia Quadro 600
    Primary Storage:
    Seagate 500 GB + WD 750 GB
    Monitor:
    Philips 27"
    Using
    AutoCAD 2013
    Join Date
    Dec 2006
    Location
    Minsk, Belarus
    Posts
    427

    Default

    How about ASMITOOLS?
    ;; ================================================== ================== ;;
    ;; ;;
    ;; INVIS.LSP - Makes objects temporarily invisible and ;;
    ;; returns visibility. ;;
    ;; ;;
    ;; ================================================== ================== ;;
    ;; ;;
    ;; Command(s) to call: INVIS ;;
    ;; ;;
    ;; ================================================== ================== ;;
    ;; ;;
    ;; THIS PROGRAM AND PARTS OF IT MAY REPRODUCED BY ANY METHOD ON ANY ;;
    ;; MEDIUM FOR ANY REASON. YOU CAN USE OR MODIFY THIS PROGRAM OR ;;
    ;; PARTS OF IT ABSOLUTELY FREE. ;;
    ;; ;;
    ;; THIS PROGRAM PROVIDES 'AS IS' WITH ALL FAULTS AND SPECIFICALLY ;;
    ;; DISCLAIMS ANY IMPLIED WARRANTY OF MERCHANTABILITY OR FITNESS ;;
    ;; FOR A PARTICULAR USE. ;;
    ;; ;;
    ;; ================================================== ================== ;;
    ;; ;;
    ;; V1.1, 11th Apr 2005, Riga, Latvia ;;
    ;; © Aleksandr Smirnov (ASMI) ;;
    ;; For AutoCAD 2000 - 2008 (isn't tested in a next versions) ;;
    ;; ;;
    ;; http://www.asmitools.com ;;
    ;; ================================================== ================== ;;
    ;
    AsmiTools

  6. #16
    Senior Member lamensterms's Avatar
    Computer Details
    lamensterms's Computer Details
    Operating System:
    Windows 7 - 64bit
    Discipline
    Manufacture
    lamensterms's Discipline Details
    Occupation
    Steel Detailer
    Discipline
    Manufacture
    Details
    3D Modelling - Mechanical & Structural 2D Detailing - Shop Drawings
    Using
    AutoCAD 2014
    Join Date
    May 2011
    Location
    Berwick, VIC, Australia
    Posts
    415

    Default

    Hi VVA,

    I have tried the INVIS LISP - im afraid it offers no greater functionality than ProSteel's existing hide/show command.

    INVIS will let me select objects i wish to hide - but it will not let me select which objects to reveal - it will only reveal ALL hidden objects. So you can hide 50% of your model - but then you cannot reveal a small percent of that 50% which is hidden.

    If you know what i mean.

    Thanks anyway mate.

  7. #17
    Senior Member
    Computer Details
    VVA's Computer Details
    Operating System:
    Windows 7
    CPU:
    Intel Core i5-2400
    RAM:
    8 Gb
    Graphics:
    Nvidia Quadro 600
    Primary Storage:
    Seagate 500 GB + WD 750 GB
    Monitor:
    Philips 27"
    Using
    AutoCAD 2013
    Join Date
    Dec 2006
    Location
    Minsk, Belarus
    Posts
    427

    Default

    a few more links
    HideShow - hide selected objects from AutoCAD drawing (VLX for AutoCAD)
    Easily hide and isolate objects in AutoCAD 2011
    Freeze Object(s)
    Quick and dirty
    Code:
    (defun c:invis (/ errCount wMode objSet showset actDoc *error*)
      ;; ==================================================================== ;;
      ;;                                                                      ;;
      ;;  INVIS.LSP - Makes objects temporarily invisible and                 ;;
      ;;              visible return of all or some                           ;;
      ;;                                                                      ;;
      ;; ==================================================================== ;;
      ;;                                                                      ;;
      ;;  Command(s) to call: INVIS                                           ;;
      ;;                                                                      ;;
      ;; ==================================================================== ;;
      ;;                                                                      ;;
      ;;  THIS PROGRAM AND PARTS OF IT MAY REPRODUCED BY ANY METHOD ON ANY    ;;
      ;;  MEDIUM FOR ANY REASON. YOU CAN USE OR MODIFY THIS PROGRAM OR        ;;
      ;;  PARTS OF IT ABSOLUTELY FREE.                                        ;;
      ;;                                                                      ;;
      ;;  THIS PROGRAM PROVIDES 'AS IS' WITH ALL FAULTS AND SPECIFICALLY      ;;
      ;;  DISCLAIMS ANY IMPLIED WARRANTY OF MERCHANTABILITY OR FITNESS        ;;
      ;;  FOR A PARTICULAR USE.                                               ;;
      ;;                                                                      ;;
      ;; ==================================================================== ;;
      ;;                                                                      ;;
      ;;  V1.1, 11th Apr 2005, Riga, Latvia                                   ;;
      ;;  © Aleksandr Smirnov (ASMI)                                          ;;
      ;;  For AutoCAD 2000 - 2008 (isn't tested in a next versions)           ;;
      ;;                                                                      ;;
      ;;http://www.cadtutor.net/forum/showthread.php?43876-AsmiTools          ;;
      ;; ==================================================================== ;;
      ;;                                                                      ;;
      ;;  V1.2, 02 June 2011, Minsk, Belarus                                  ;;
      ;;  © Vladimir Azarko (VVA)                                             ;;
      ;;  For AutoCAD 2000 - 2011 (isn't tested in a next versions)           ;;
      ;; Add mode "Show some object"                                          ;;
      ;;  V1.3, 04 may 2013, Minsk, Belarus                                   ;;
      ;;  © Vladimir Azarko (VVA)                                             ;;
      ;;  For AutoCAD 2000 - 2011 (isn't tested in a next versions)           ;;
      ;; Add mode "Show selected Only"                                        ;;
      ;;                                                                      ;;
      ;;http://www.cadtutor.net/forum/showthread.php?59655                    ;;
      ;; ==================================================================== ;;
      ;;                                                                      ;;
    
      (vl-load-com)
      (defun put_Visible_Prop (Object Flag)
        (if
          (vl-catch-all-error-p
    	(vl-catch-all-apply
    	  'vla-put-visible
    	  (list Object Flag)
    	)
          )
           (setq errCount (1+ errCount))
        );_ end if
        (princ)
      );_ end of put_Visible_Prop
      (defun Set_to_List (SelSet)
        (mapcar 'vlax-ename->vla-object
    	    (vl-remove-if
    	      'listp
    	      (mapcar 'cadr (ssnamex SelSet))
    	    )
        )
      );_ end of Set_to_List
      (defun errMsg	()
        (if	(/= 0 errCount)
          (princ (strcat ", "
    		     (itoa errCount)
    		     " were on locked layer."
    	     )
          )
          "."
        );_ end if
      );_ end of errMsg
      (setq	actDoc	 (vla-get-ActiveDocument
    		   (vlax-get-Acad-object)
    		 )
    	errCount 0
      );_ end setq
      (vla-StartUndoMark actDoc)
      (initget "Visible Invisible Show Only" 1)
      (setq	wMode
    	 (getkword
    	   "\nMake objects [Visible all/Invisible/Show some invisible objects/show selected Only]: "
    	 )
      )
      (cond
        ((and
           (= wMode "Visible")
           (setq objSet (ssget "_X" '((60 . 1))))
         );_ end and
         (setq objSet (Set_to_List objSet))
         (mapcar
           '(lambda (x) (put_Visible_Prop x :vlax-true))
           objSet
         )
         (princ
           (strcat "\n<< "
    	       (itoa (- (length objSet) errCount))
    	       " now visible"
    	       (errMsg)
    	       " >>"
           )
         )
        ) ;_ # condition
        ((and
           (= wMode "Show")
           (setq objSet (ssget "_X" '((60 . 1))))
         );_ end and
         (setq objSet (Set_to_List objSet))
         (mapcar
           '(lambda (x) (put_Visible_Prop x :vlax-true))
           objSet
         )
         (princ
           (strcat "\n<< "
    	       (itoa (- (length objSet) errCount))
    	       " now visible"
    	       (errMsg)
    	       " >>"
           )
         )
         (princ "\nSelect objects to show")
         (if (setq showset (ssget "_:L"))
           (progn
    	 (setq showset (Set_to_List showset))
    	 (foreach item showset
    	   (setq objSet (vl-remove item objSet))
    	 )
    	 (mapcar
    	   '(lambda (x) (put_Visible_Prop x :vlax-false))
    	   objSet
    	 )
           )
         )
        ) ;_ # condition
        ((= wMode "Only")
         (if (not (setq objSet (ssget "_I")))
           (setq objSet (ssget))
         ) ;_ end if
         (if (and objset (setq objSet (Set_to_List objSet)))
           (progn
    	 (setq showset (ssget "_X" (list (cons 410 (getvar 'Ctab))))
    	       showset (Set_to_List showset)
    	 )
    	 (foreach item objSet
    	   (setq showset (vl-remove item showset))
    	 )
    	 (mapcar
    	   '(lambda (x) (put_Visible_Prop x :vlax-false))
    	   showset
    	 )
    	 (princ
    	   (strcat "\n<< "
    		   (itoa (- (length showset) errCount))
    		   " now invisible"
    		   (errMsg)
    		   " >>"
    	   )
    	 )
           )
         )
        ) ;_ # condition
        (t
         (if (not (setq objSet (ssget "_I")))
           (setq objSet (ssget))
         );_ end if
         (if objSet
           (progn
    	 (setq objSet (Set_to_List objSet))
    	 (mapcar
    	   '(lambda (x) (put_Visible_Prop x :vlax-false))
    	   objSet
    	 )
    	 (princ
    	   (strcat "\n<< "
    		   (itoa (- (length objSet) errCount))
    		   " now invisible"
    		   (errMsg)
    		   " >>"
    	   )
    	 )
           );_ end progn
         );_ end if
        )
      );_ end cond
      (vla-EndUndoMark actDoc)
      (princ)
    );_ end of c:invis
    (mapcar 'princ
    (list
      "\n[Info] http://www.cadtutor.net/forum/showthread.php?59655 [Info]"
      "\nType INVIS to make objects invisible or visible."
     )
    )	
    (princ)
    Last edited by VVA; 4th May 2013 at 11:22 am. Reason: add option "Show selected only" see #18

  8. #18
    Super Member mdbdesign's Avatar
    Computer Details
    mdbdesign's Computer Details
    Operating System:
    WIN7 U 32 BIT
    Computer:
    Homemade
    Motherboard:
    GIGABYTE G31M-ES2L
    CPU:
    INTEL CORE 2-QUAD-Q6600@2.4GHz
    RAM:
    4 GB
    Graphics:
    NVIDIA GeForce 9800 gt 1gb
    Primary Storage:
    WESTERN DIGITAL 500GB
    Secondary Storage:
    TBA
    Monitor:
    2 - 22" HP
    Discipline
    Manufacture
    mdbdesign's Discipline Details
    Occupation
    Designing Engineer in Engineering Department
    Discipline
    Manufacture
    Details
    Pressure tanks Oil processing & storage equip. Steel mill equip. Telecom towers & equip. Wind turbine towers Power plant structures etc.
    Using
    AutoCAD 2013
    Join Date
    Jan 2007
    Location
    Courtice, Ontario, Canada
    Posts
    850

    Default

    This is the thing I was looking for. Perfect. Thank you.
    Only one question: Is possible to extend it to another option as "Show selected only"
    Similar to AutoCAD's "Isolate Object".
    I know it is older post but will waiting for answer.
    Thank you again.
    Marek

  9. #19
    Senior Member kruuger's Avatar
    Computer Details
    kruuger's Computer Details
    Operating System:
    Xp 64bit
    Using
    AutoCAD 2010
    Join Date
    Dec 2007
    Location
    Poland
    Posts
    193

    Default

    Quote Originally Posted by mdbdesign View Post
    This is the thing I was looking for. Perfect. Thank you.
    Only one question: Is possible to extend it to another option as "Show selected only"
    Similar to AutoCAD's "Isolate Object".
    I know it is older post but will waiting for answer.
    Thank you again.
    try this. CadPack required
    http://forum.cad.pl/cadpl-pack-v1-lsp-t78161.html
    kruuger
    Attached Files

  10. #20
    Super Member mdbdesign's Avatar
    Computer Details
    mdbdesign's Computer Details
    Operating System:
    WIN7 U 32 BIT
    Computer:
    Homemade
    Motherboard:
    GIGABYTE G31M-ES2L
    CPU:
    INTEL CORE 2-QUAD-Q6600@2.4GHz
    RAM:
    4 GB
    Graphics:
    NVIDIA GeForce 9800 gt 1gb
    Primary Storage:
    WESTERN DIGITAL 500GB
    Secondary Storage:
    TBA
    Monitor:
    2 - 22" HP
    Discipline
    Manufacture
    mdbdesign's Discipline Details
    Occupation
    Designing Engineer in Engineering Department
    Discipline
    Manufacture
    Details
    Pressure tanks Oil processing & storage equip. Steel mill equip. Telecom towers & equip. Wind turbine towers Power plant structures etc.
    Using
    AutoCAD 2013
    Join Date
    Jan 2007
    Location
    Courtice, Ontario, Canada
    Posts
    850

    Default

    Registered forum members do not see this ad.

    Great tool as well. Added to toolbar, but I need extension to VVA program, something works exactly like "Isolate Objects" in AutoCAD, but only extension to VVA program.
    Let say I need to isolate two items from entire dwg, I select them and only this item stay visible and rest of them disappear.
    Maybe header "Show selected only" is misleading. It s/b "Isolate selected only from entire dwg"
    Sorry for confusion.
    Last edited by mdbdesign; 1st May 2013 at 08:21 pm.
    Marek

Similar Threads

  1. All objects in drawing not hiding?
    By Mason Dixon in forum AutoCAD 3D Modelling & Rendering
    Replies: 11
    Last Post: 12th May 2011, 11:30 pm
  2. Hiding 3d objects when plotting
    By noxit in forum AutoCAD 3D Modelling & Rendering
    Replies: 4
    Last Post: 11th Feb 2011, 10:00 pm
  3. Showing and Hiding AutoCAD Toolbars
    By CAD Panacea in forum AutoCAD RSS Feeds
    Replies: 0
    Last Post: 6th Jan 2010, 06:20 pm
  4. Hiding some objects
    By alijahed in forum AutoCAD General
    Replies: 9
    Last Post: 25th Jun 2008, 05:51 am
  5. Hiding objects in viewport
    By f700es in forum AutoCAD Drawing Management & Output
    Replies: 11
    Last Post: 24th Jun 2003, 01:05 pm

Tags for this Thread

Bookmarks

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts