Help with Sample code to Entmake a Hatch

**TuFoFi** · 8th Mar 2006 10:54 pm

I am trying to do a solid hatch on a simple polygon with ENTMAKE.

Any idea why the following sequence does not work?

Code:

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(setq layername "0" x1 0.0 y1 0.0 z1 0.0 x2 120.0 y2 0.0 z2 0.0
      x3 120.0 y3 120.0 z3 0.0 x4 0.0 y4 120.0 z4 0.0)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(setq dummyhatch
	 (list (cons 0 "HATCH")	       
	       (cons 2 "SOLID")
	       (cons 8 layername)
	       (cons 62 256)
	       (cons 10 (list 0.0 0.0 0.0))
	       (cons 210 (list 0.0 0.0 0.0))
	       (cons 70 1)
	       (cons 71 0)
	       (cons 91 1)
	       (cons 92 1)
	       (cons 93 4)
	       (cons 72 1)
	       (cons 10 (list x1 y1 z1))
	       (cons 11 (list x2 y2 z2))
	       (cons 72 1)
	       (cons 10 (list x2 y2 z2))
	       (cons 11 (list x3 y3 z3))
	       (cons 72 1)
	       (cons 10 (list x3 y3 z3))
	       (cons 11 (list x4 y4 z4))
	       (cons 72 1)
	       (cons 10 (list x4 y4 z4))
	       (cons 11 (list x1 y1 z1))
	       (cons 97 0)
	       (cons 75 2)
	       (cons 76 1)
	       (cons 98 1)
	       (cons 10 (list 0.0 0.0 0.0))
	       (cons 470 "LINEAR")))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(entmake dummyhatch)

**CarlB** · 9th Mar 2006 02:21 am

I played with your code and got it to work. It appears you need the 100 group codes for hatch. Plus the 210 code should have been '0 0 1'. The following works, don't know if the re-order has any effect:

Code:

(setq layername "0" x1 0.0 y1 0.0 z1 0.0 x2 120.0 y2 0.0 z2 0.0 
x3 120.0 y3 120.0 z3 0.0 x4 0.0 y4 120.0 z4 0.0) 
(setq dummyhatch 
(list (cons 0 "HATCH")
'(100 . "AcDbEntity")
(cons 8 layername)
'(100 . "AcDbHatch")
(cons 62 256) 
(cons 10 (list 0.0 0.0 0.0)) 
(cons 210 (list 0.0 0.0 1.0)) ;;changed z
(cons 2 "SOLID")
(cons 70 1) 
(cons 71 0) 
(cons 91 1) 
(cons 92 1) 
(cons 93 4) 
(cons 72 1) 
(cons 10 (list x1 y1 z1)) 
(cons 11 (list x2 y2 z2)) 
(cons 72 1) 
(cons 10 (list x2 y2 z2)) 
(cons 11 (list x3 y3 z3)) 
(cons 72 1) 
(cons 10 (list x3 y3 z3)) 
(cons 11 (list x4 y4 z4)) 
(cons 72 1) 
(cons 10 (list x4 y4 z4)) 
(cons 11 (list x1 y1 z1)) 
(cons 97 0) 
(cons 75 2) 
(cons 76 1) 
(cons 98 1) 
(cons 10 (list 0.0 0.0 0.0)) 
(cons 470 "LINEAR"))) 
(entmake dummyhatch)

**TuFoFi** · 9th Mar 2006 06:40 pm

Code:

;;;;;; begin entmake_insert----format&#58; &#40;entmake_insert "testme" "0" 0.0 0.0 0.0 45 1.0 1.0 1.0 0 1 1 0.0 0.0 0.0 0.0 1.0&#41;
&#40;defun entmake_insert  &#40;blockname layername xcoord ycoord zcoord ang xscale yscale zscale attribflag colmncnt rowcnt
			colmnspcng rowspcng xvectr yvectr zvectr / dummy&#41;
  &#40;setq	dummy &#40;list &#40;cons 0 "INSERT"&#41;
		    &#40;cons 2 blockname&#41;
		    &#40;cons 100 "AcDbEntity"&#41;
		    &#40;cons 8 layername&#41;
		    &#40;cons 100 "AcDbBlockReference"&#41;
		    &#40;cons 10 &#40;list xcoord ycoord zcoord&#41;&#41;
		    &#40;cons 50 &#40;* pi &#40;/ ang 180.0&#41;&#41;&#41;
		    &#40;cons 41 xscale&#41;
		    &#40;cons 42 yscale&#41;
		    &#40;cons 43 zscale&#41;
		    &#40;cons 66 attribflag&#41;
		    ;&#40;cons 70 colmncnt&#41;
		    ;&#40;cons 71 rowcnt&#41;
		    ;&#40;cons 44 colmnspcng&#41;
		    ;&#40;cons 45 rowspcng&#41;
		    &#40;cons 210 &#40;list xvectr yvectr zvectr&#41;&#41;&#41;&#41;
  &#40;entmake dummy&#41;&#41;
;;;;;;;;;end entmake_insert

**rkmcswain** · 14th Dec 2009 06:11 pm

Thanks for the examples guys. I was able to take this and modify it slightly so that I can set the scale also. Carl's code works fine, but there are changes necessary when switching to a pattern (as opposed to solid) and when you want to set the scale.

Example:

Code:

;;; this setq is only needed to populate variables used below.
(setq pt7 (list 0.0 0.0 0.0)
      pt3 (list 15.0 0.0 0.0)
      pt4 (list 15.0 18.5 0.0)
      pt8 (list 0.0 18.5 0.0)     ) 

(setq dummyhatch
       (list (cons 0 "HATCH")
	     (cons 100 "AcDbEntity")
	     (cons 8 "0")
	     (cons 100 "AcDbHatch")	     
	     (cons 10 (list 0.0 0.0 0.0))
	     (cons 210 (list 0.0 0.0 1.0))	     
	     (cons 2 "ANSI31")
	     (cons 70 0)
	     (cons 71 0)
	     (cons 91 1)
	     (cons 92 1)
	     (cons 93 4)
        
	     (cons 72 1)
	     (cons 10 pt7)
	     (cons 11 pt3)
	     (cons 72 1)
	     (cons 10 pt3)
	     (cons 11 pt4)
	     (cons 72 1)
	     (cons 10 pt4)
	     (cons 11 pt8)
	     (cons 72 1)
	     (cons 10 pt8)
	     (cons 11 pt7)	     

	     (cons 97 0)
	     (cons 75 0)
	     (cons 76 1)
	     
	     (cons 52 0.0)         ;angle
	     (cons 41 20.0)        ;scale
	     (cons 77 0)           ;double flag
	     (cons 78 1)           ;# of pat def lines
	     (cons 53 (* 0.25 pi)) ;pat line angle (45° in this case)
	     (cons 43 0.0)         ; x pat base pt
	     (cons 44 0.0)         ; y pat base pt
	     (cons 45 -1.0)        ; x pat line offset ***
	     (cons 46 1.0)         ; y pat line offset ***
	     (cons 79 0)           ; # of dash length items
	     
	     (cons 98 1)
	     (cons 10 (list 0.0 0.0 0.0))	     
       )
)
(entmake dummyhatch)
(redraw)

;*** = I have found it doesn't matter what you set these to.
The values appear to be generated automatically, but you 
cannot omit these lines

**fixo** · 14th Dec 2009 11:24 pm

Originally Posted by rkmcswain

Thanks for the examples guys. I was able to take this and modify it slightly so that I can set the scale also. Carl's code works fine, but there are changes necessary when switching to a pattern (as opposed to solid) and when you want to set the scale.

Example:

Code:

;;; this setq is only needed to populate variables used below.
(setq pt7 (list 0.0 0.0 0.0)
      pt3 (list 15.0 0.0 0.0)
      pt4 (list 15.0 18.5 0.0)
      pt8 (list 0.0 18.5 0.0)     ) 

(setq dummyhatch
       (list (cons 0 "HATCH")
	     (cons 100 "AcDbEntity")
	     (cons 8 "0")
	     (cons 100 "AcDbHatch")	     
	     (cons 10 (list 0.0 0.0 0.0))
	     (cons 210 (list 0.0 0.0 1.0))	     
	     (cons 2 "ANSI31")
	     (cons 70 0)
	     (cons 71 0)
	     (cons 91 1)
	     (cons 92 1)
	     (cons 93 4)
        
	     (cons 72 1)
	     (cons 10 pt7)
	     (cons 11 pt3)
	     (cons 72 1)
	     (cons 10 pt3)
	     (cons 11 pt4)
	     (cons 72 1)
	     (cons 10 pt4)
	     (cons 11 pt8)
	     (cons 72 1)
	     (cons 10 pt8)
	     (cons 11 pt7)	     

	     (cons 97 0)
	     (cons 75 0)
	     (cons 76 1)
	     
	     (cons 52 0.0)         ;angle
	     (cons 41 20.0)        ;scale
	     (cons 77 0)           ;double flag
	     (cons 78 1)           ;# of pat def lines
	     (cons 53 (* 0.25 pi)) ;pat line angle (45° in this case)
	     (cons 43 0.0)         ; x pat base pt
	     (cons 44 0.0)         ; y pat base pt
	     (cons 45 -1.0)        ; x pat line offset ***
	     (cons 46 1.0)         ; y pat line offset ***
	     (cons 79 0)           ; # of dash length items
	     
	     (cons 98 1)
	     (cons 10 (list 0.0 0.0 0.0))	     
       )
)
(entmake dummyhatch)
(redraw)

;*** = I have found it doesn't matter what you set these to.
The values appear to be generated automatically, but you 
cannot omit these lines

This one is written by Eugeny Elpanov
perhaps it will be interesting for you too

Code:

(defun entmakex-hatch (L)
 ;; By ElpanovEvgeniy
 ;; 03.04.2007 10:03:51:
 (entmakex
  (apply
   'append
   (list
    (list '(0 . "HATCH")
          '(100 . "AcDbEntity")
          '(410 . "Model")
          '(100 . "AcDbHatch")
          '(10 0.0 0.0 0.0)
          '(210 0.0 0.0 1.0)
          '(2 . "ANSI31")
          '(70 . 1)
          '(71 . 0)
          (cons 91 (length l))
    ) ;_  list
    (apply 'append
    (mapcar '(lambda (a)
             (apply 'append
                    (list (list '(92 . 7) '(72 . 0) '(73 . 1) (cons 93 (length a)))
                          (mapcar '(lambda (b) (cons 10 b)) a)
                          '((97 . 0))
                    ) ;_  list
             ) ;_  apply
            ) ;_  lambda
            l
    ) ;_  mapcar
           )
    '((75 . 0)
      (76 . 1)
      (47 . 1.)
      (98 . 2)
      (10 0. 0. 0.0)
      (10 0. 0. 0.0)
      (451 . 0)
      (460 . 0.0)
      (461 . 0.0)
      (452 . 1)
      (462 . 1.0)
      (453 . 2)
      (463 . 0.0)
      (463 . 1.0)
      (470 . "LINEAR")
     )
   ) ;_  list
  ) ;_  apply
 ) ;_  entmakex
); _
;;Call:
(setq h (entmakex-hatch
         '(((538.794 584.563) (895.629 584.563) (895.629 997.377) (538.794 997.377))
           ((386.809 345.13) (670.955 345.13) (670.955 855.369) (386.809 855.369))
          )
        ) ;_  entmakex-hatch
) ;_  setq

~'J'~

**rkmcswain** · 15th Dec 2009 03:45 am

Yes, my next adventure was going to be making it more of an scalable function that can accept a variable length list of entities. Thanks.

Thread: Help with Sample code to Entmake a Hatch

Thread Tools

Help with Sample code to Entmake a Hatch

Thank you... and here is the Entmake_insert buggy too.

rkmcswain's Computer Details

fixo's Computer Details

rkmcswain's Computer Details

Bookmarks

Bookmarks

Posting Permissions