Set Z Position of all Blocks to Zero

[harilalmn]

What is wrong in the code? I am trying to set the Z position value to zero for all the blocks in the drawing;

(defun c:B0()
  (setq myFilter(list (cons 0 "INSERT")))
  (setq ss (ssget "_X" myFilter))
  (setq l (sslength ss))
  (setq i 0)
  (Repeat l
    (setq blk (ssname ss i))
    (setq DXF (entget (car blk)))
    (setq IP (cadr (assoc 0 dxf)))
    (setq NewIP (subst "0" (caddr  IP) IP))
    (setq NewDXF (subst NewIP IP DXF))
    (entmod NewDXF)
  )
)

[pBe]

(defun c:B0  ()
    (setq myFilter (list (cons 0 "INSERT")))
    (setq ss (ssget "_X" myFilter))
    (setq l (sslength ss))
    (setq i 0)
    (Repeat l
          (setq blk (ssname ss i))
          (setq DXF (entget blk))
          (setq IP (cdr (assoc 10 dxf)))
          (setq NewIP (subst 0.00 (caddr IP) IP))
          (setq NewDXF (subst (cons 10 NewIP) (assoc 10 dxf) DXF))
          (entmod NewDXF)
(setq i (1+ i))
          )
    )

variable i remains at 0.... "0" as string not real number...
Among other things....

[Tharwat]

Try this ...

(defun c:Test (/ ss i sset lst)
  (vl-load-com)
  (if (setq ss (ssget "_x" '((0 . "INSERT") (410 . "model"))))
    (repeat (setq i (sslength ss))
      (setq sset (ssname ss (setq i (1- i))))
      (setq lst (cons (vlax-ename->vla-object sset) lst))
    )
    (alert " << No Blocks existed in this drawing >>  ")
  )
  (foreach ml '(1e99 -1e99)
    (mapcar (function (lambda (x)
                        (vla-move x
                                  (vlax-3d-point (list 0 0 0))
                                  (vlax-3d-point (list 0 0 ml))
                        )
                      )
            )
            lst
    )
  )
  (princ)
)

Tharwat

[harilalmn]

pBe Thanks for your comment.. I now understand I should have added a (setq i (1+ i)) in the repeat loop...!!

Thanks for the code Tharwat...!! That was much professional a solution compared to my code...!!

Happy Happy....

[pBe]

....
(1e99 -1e99).....

Interesting

[Lee Mac]

I would approach it this way:

(defun c:B0 ( / e i p s )
    (if (setq s (ssget "_X" '((0 . "INSERT") (-4 . "*,*,<>") (10 0.0 0.0 0.0))))
        (repeat (setq i (sslength s))
            (setq e (entget (ssname s (setq i (1- i))))
                  p (assoc 10 e)
            )
            (entmod (subst (list 10 (cadr p) (caddr p) 0.0) p e))
        )
    )
    (princ)
)

I don't see the need to move everything to 1e99 elevation and back just to set the elevation to zero

[David Bethel]

Using (subst) on a point value is very dangerous

(setq ip '(10 10 10 10))
(subst 0 (caddr ip) ip)

Returns -> '(0 0 0 0)

(defun c:iz0 (/ ss en ed in)

  (and (setq ss (ssget "X" '((0 . "INSERT"))))
       (while (setq en (ssname ss 0))
              (setq ed (entget en)
                    in (cdr (assoc 10 ed)))
              (entmod (subst (list 10 (car in) (cadr in) 0.0)
                             (assoc 10 ed) ed))
              (entupd en)
              (ssdel en ss)))

  (prin1))

I would think a lot more filtering would be advisable. Maybe groups 67 210 at the very least should be added.

Also this will not move the attributes the elevation 0.

-David

[pBe]

or Ctrl+1
Quick Select
Position Z

[Tharwat]

....
(1e99 -1e99).....

Interesting

Thanks pBe .

I don't see the need to move everything to 1e99 elevation and back just to set the elevation to zero

Why not ?

Would that harm or incorrect in away or another ?

Tharwat

[Tharwat]

[B]

Thanks for the code Tharwat...!! That was much professional a solution compared to my code...!!

Happy Happy....

You're welcome harilalmn .

Enjoy it buddy

Tharwat