Jump to content

Security


j_spawn_h

Recommended Posts

Is there any thing I can put in my lisp to keep someone from using it if they copied from my computer to theirs?

 

Hard-code your AutoCAD serial number (_PKSER) (or some other unique identifier to your computer) into the LISP, then compile the LISP to a VLX to make it uneditable.

Link to comment
Share on other sites

Oh.. Somewhere all people use a crac* version, so their _PKSER always is "000-00000000" or "999-99999999", or has same Serial.....(might be OP ^^)

Hi, just a joke ^^ I think we should use HDD Serial or sth similar

Link to comment
Share on other sites

Hi, just a joke ^^ I think we should use HDD Serial or sth similar

 

Maybe (virtual serial):

 

(defun HDSerial ( drive / fso drv ser )
 (vl-catch-all-apply
   (function
     (lambda nil
       (setq fso (vlax-create-object "Scripting.FileSystemObject")
             drv (vlax-invoke-method fso 'getdrive drive)
             ser (vlax-get-property drv 'serialnumber)
       )
     )
   )
 )
 (if drv (vlax-release-object drv))
 (if fso (vlax-release-object fso))
 ser
)

Or, for the manufacturer's Serial number (only works in Vista or 7):

 

(defun HDSerial ( / wmi srv drv ser )
 (vl-catch-all-apply
   (function
     (lambda ( )
       (if
         (setq wmi (vlax-create-object "WbemScripting.SWbemLocator")
               srv (vlax-invoke wmi 'connectserver nil nil nil nil nil nil nil nil)
               drv (vlax-invoke srv 'execquery "Select SerialNumber from Win32_DiskDrive")
         )
         (vlax-for item drv
           (vlax-for prop (vlax-get item 'Properties_)
             (if (eq "SERIALNUMBER" (strcase (vlax-get prop 'name)))
               (setq ser (vl-string-trim " " (vlax-get prop 'value)))
             )
           )
         )
       )
     )
   )
 )
 (if drv (vlax-release-object drv))
 (if srv (vlax-release-object srv))
 (if wmi (vlax-release-object wmi))
 ser
)

  • Like 1
Link to comment
Share on other sites

I thought that most people write lisp routines because they DO want to share them. Now share can mean 1) free or 2) at a cost but don't you want the world beating a path to your door demanding the perfect lisp routine you went through all the trouble to create? Have you ever "borrowed" someone else's lisp routine?

Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.
Note: Your post will require moderator approval before it will be visible.

Guest
Unfortunately, your content contains terms that we do not allow. Please edit your content to remove the highlighted words below.
Reply to this topic...

×   Pasted as rich text.   Restore formatting

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
×
  • Create New...