Find Nearest Text/Mtext from Specified point

Hi all,

How can we find nearest specified Text/Mtext object from specified point?

For example: I want to find nearest TB2A from point A.

Thank you.

mardi

Quickly written:

(defun NearestTextFromPoint ( pt str / d e i l m r s )
   (if
       (setq s
           (ssget "_X"
               (list
                  '(0 . "TEXT,MTEXT")
                   (cons 1 str)
                   (cons 410 (if (= 1 (getvar 'CVPORT)) (getvar 'CTAB) "Model"))
               )
           )
       )
       (repeat (setq i (sslength s))
           (setq e (ssname s (setq i (1- i)))
                 l (entget e)
           )
           (if
               (<
                   (setq d
                       (distance pt
                           (if
                               (or (eq "MTEXT" (cdr (assoc 0 l)))
                                   (and
                                       (zerop (cdr (assoc 72 l)))
                                       (zerop (cdr (assoc 73 l)))
                                   )
                               )
                               (cdr (assoc 10 l))
                               (cdr (assoc 11 l))
                           )
                       )
                   )
                   (cond (m) ((1+ d)))
               )
               (setq m d r e) r
           )
       )
   )
)

(defun c:test ( / s p )
   (setq s (getstring t "\nString: "))
   (if (setq p (getpoint "\nPoint: "))
       (sssetfirst nil (ssadd (NearestTextFromPoint (trans p 1 0) s)))
   )
   (princ)
)

Quickly written:

 

 

I test it and working nicely

Good to hear wimal

I test it and working nicely

Faint praise for the code-meister.

Perhaps a thank you might be in order?

Thank you Lee, It works for my quick tests. I am stilll studying your routine....

mardi

sorry for replying to an old thread. I need this too, but after selecting a point, got this error: "Point: ; error: bad argument type: lentityp nil"

sorry for replying to an old thread. I need this too, but after selecting a point, got this error: "Point: ; error: bad argument type: lentityp nil"

Change:

(defun c:test ( / s p )
   (setq s (getstring t "\nString: "))
   (if (setq p (getpoint "\nPoint: "))
       (sssetfirst nil (ssadd (NearestTextFromPoint (trans p 1 0) s)))
   )
   (princ)
)

to:

(defun c:test ( / e s p )
   (setq s (getstring t "\nString: "))
   (if (setq p (getpoint "\nPoint: "))
       (if (setq e (NearestTextFromPoint (trans p 1 0) s))
           (sssetfirst nil (ssadd e))
           (princ (strcat "\nNo text/mtext with content \"" s "\" found in the current layout."))
       )
   )
   (princ)
)

thanks Lee, that works great! um, could you please modify it so that it finds any nearest text? edit: never mind, it works with wildcard.

You're welcome.