get data from attribute needs help

[pmxcad]

Hello.
I made my first lisp. It`s a simple one and looks like script. It works ok (i have to copy and paste bij myself)but i want it to do automatic.

Sure there is better way to do it, but it is a start.
I want the lisp to do:

-Select a attribute from a block (VIEWP, rectangle)
-copie the value
-starts the view command to create named view
-W from window
-Autocad asked for a name
-Paste the attribute value
-Enter
-And selecting a window for the named-view..by me

Done


It looks simple but i don`t think it is.
The copie and paste things are difficult for me.
I used PAUSE for user input. It works, but it can be better.


Thanks,

PmxCAD

[David Bethel]

Assuming:

The tagname of the attribute is always "NAMEDVW"
The ATTRIB string value is a valid symbol name



Maybe something like this:

(defun c:nvw (/ ss en an ad nv p1 p2)
  (and (setq ss (ssget '((0 . "INSERT")(66 . 1))))
       (= (sslength ss) 1)
       (setq en (ssname ss 0)
             an (entnext en)
             ad (entget an))
       (while (= "ATTRIB" (cdr (assoc 0 ad)))
              (and (= "NAMEDVW" (cdr (assoc 2 ad)))
                   (setq nv (cdr (assoc 1 ad))))
              (setq an (entnext an)
                    ad (entget an))))
  (if nv
    (progn
       (initget 1)
       (setq p1 (getpoint (strcat "\nSelect 1 Corner Of " nv " View Window:  ")))
       (initget 1)
       (setq p2 (getcorner p1 "\nSelect Opposite Corner Of View Window:   "))
       (command "_.VIEW" "_Window" nv p1 p2))
    (alert "No View Names Found"))
  (prin1 nv)
  (prin1))

-David

[pmxcad]

Thanks David.
It is not working. Wel it does something, It opens the view dialog. What i like to have, Is running the lisp, select an attribute from a block, and after that, selecting/pick-points for the view..........done.
The value/text from the selected attribute becomes the name of the named view.

Thanks,

PmxCAD

[David Bethel]

It must be a setting in filedia or some dialog setting. It works on my systems R12 r13 2004 2012

-David

[pBe]

Thanks David.
It is not working. Wel it does something, It opens the view dialog. What i like to have, Is running the lisp, select an attribute from a block, and after that, selecting/pick-points for the view..........done.
The value/text from the selected attribute becomes the name of the named view.

Thanks,

PmxCAD

Works here as well (2009)

I suggest you change the c:newview to something else like c:NW

[David Bethel]

Works here as well (2009)

I suggest you change the c:newview to something else like c:NW

Looks like pBe is correct . NEWVIEW is a internal ACAD commend now. -David

[pmxcad]

Yep.change it to nv.............works fine, thanks fooks.

PmxCAD