how trim many line inside multi circle on one step

[Tharwat]

irneb , that would disable the visibility of the selection set for all open drawings .

e.g , try to move any entity in any opened drawing and you will find out that the high lighting objects would be disabled when you try to select any object.

Regards.

[irneb]

Yes, it's one of the painful aspects of only using portions of the Express tools. You could always allow for such things by saving the value of Highlight and the restoring it at the end of the function.

I.e. something like this:

(defun c:MExTrim  (/ highlight *error* ss n en ed enA minpt maxpt dx dy pt dxx dyy)
  (vl-load-com)
  (setq highlight (getvar "HighLight"))
  (defun *error* (msg)
    (if highlight (setvar "HighLight" highlight))
    (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*") (princ (strcat "\n** Error: " msg " **")))
    (princ))
  (prompt "\nSelect closed entities: ")
  (if (setq ss (ssget (append (list '(-4 . "<or")        '(0 . "CIRCLE")      '(-4 . "<and")       '(0 . "*POLYLINE")
                                    '(70 . 1)            '(-4 . "and>")       '(-4 . "<and")       '(0 . "SPLINE")
                                    '(70 . 11)           '(-4 . "and>")       '(-4 . "<and")       '(0 . "ELLIPSE")
                                    '(41 . 0.0))
                              (list (cons 42 (* 2 pi)))
                              (list '(-4 . "and>") '(-4 . "or>")))))
    (progn (setq n (sslength ss))
           (while (>= (setq n (1- n)) 0)
             (setq en  (ssname ss n)
                   ed  (entget en)
                   enA (vlax-ename->vla-object en))
             (vla-getboundingbox enA 'minpoint 'maxpoint)
             (setq minpt (vlax-safearray->list minpoint)
                   maxpt (vlax-safearray->list maxpoint))
             (setq dx (- (car maxpt) (car minpt)))
             (setq dy (- (cadr maxpt) (cadr minpt)))
             (setq pt '(0.0 0.0 0.0))
             (while (not (ptinsideent pt en))
               (setq dxx (* dx (rnd)))
               (setq dyy (* dy (rnd)))
               (setq pt (list (+ (car minpt) dxx) (+ (cadr minpt) dyy) 0.0)))
             (etrim en pt))))
  (*error* nil))

Edit: Oh and BTW, thanks marko - that works great even on polylines!

[Tharwat]

Looks interesting indeed .

sub-function ptinsideent is missing

[irneb]

Looks interesting indeed .

sub-function ptinsideent is missing

Yes, that function is part of marko's code. I've taken marko's code and only shown the defun where I've modified it to include for the highlight reset.

[KCorby]

This routine is resulting in everything outside of my circles being trimmed, leaving the portion of line inside as per #3 in ReMark's sketch above. Is there a setting that I could change for it to result in #2 in ReMark's sketch?

[mmsmurugan1]

Hi,

Really its very useful ...........

thank you,

[ctdlc888]

Hi Irneb,
I'm not well versed in lisp where to put. Please give the full lisp.thanks

[irneb]

Copy marko_ribar's code from post #10, then replace the last portion starting with

(defun c:MExTrim ...

with my code from post #12. Save all into a LSP file (normal text file just with a LSP extension instead of TXT). Then load that file into ACad - several ways. Then after that any defun in that file with a name starting with C: becomes a new command with the rest of the name (in this case MExTrim).

[marko_ribar]

I've modified my code according to BIGAL's discovery that on older Acad versions (etrim ent pt) won't work correctly without (acet-error-init) function and at the end followed by (acet-error-restore)... Look here for details...

So here is complete code :

(defun rnd (/ modulus multiplier increment rand)
  (if (not seed)
    (setq seed (getvar "DATE"))
  )
  (setq modulus    65536
        multiplier 25173
        increment  13849
        seed  (rem (+ (* multiplier seed) increment) modulus)
        rand     (/ seed modulus)
  )
)

(defun GroupByNum ( l n / f )
  (defun f ( a b )
    (if (and a (< 0 b))
      (cons (car a) (f (setq l (cdr a)) (1- b)))
    )
  )
  (if l (cons (f l n) (GroupByNum l n)))
)

(defun ptonline ( pt pt1 pt2 / vec12 vec1p d result )
  (setq vec12 (mapcar '- pt2 pt1))
  (setq vec12 (reverse (cdr (reverse vec12))))
  (setq vec1p (mapcar '- pt pt1))
  (setq vec1p (reverse (cdr (reverse vec1p))))
  (setq vec2p (mapcar '- pt2 pt))
  (setq vec2p (reverse (cdr (reverse vec2p))))
  (setq d (distance '(0.0 0.0) vec12) d1 (distance '(0.0 0.0) vec1p) d2 (distance '(0.0 0.0) vec2p))
  (if (equal d (+ d1 d2) 1e-8) (setq result T) (setq result nil))
  result
)

(defun ptinsideent ( pt ent / msp ptt xlin int k kk tst result )
  (vl-load-com)
  (setq msp (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object))))
  (setq ptt (vlax-curve-getclosestpointto ent pt))
  (setq xlin (vla-addxline msp (vlax-3d-point pt) (vlax-3d-point ptt)))
  (setq int (GroupByNum (vlax-invoke (if (eq (type ent) 'ENAME) (vlax-ename->vla-object ent)) 'intersectwith xlin acExtendBoth) 3))
  (setq int (vl-sort int '(lambda (a b) (< (vlax-curve-getparamatpoint xlin a) (vlax-curve-getparamatpoint xlin b)))))
  (setq k 0)
  (while (< (setq k (1+ k)) (length int))
    (if (and (eq (rem k 2) 1) (ptonline pt (nth (- k 1) int) (nth k int))) (setq tst (cons T tst)) (setq tst (cons nil tst)))
  )
  (setq tst (reverse tst))
  (setq k 0)
  (mapcar '(lambda (x) (setq k (1+ k)) (if (eq x T) (setq kk k))) tst)
  (vla-delete xlin)
  (if kk
    (if (eq (rem kk 2) 1) (setq result T) (setq result nil))
    (setq result nil)
  )
  result
)

(load "extrim.lsp")
(defun c:MExTrim ( / highlight *error* ss n en ed enA minpt maxpt dx dy pt dxx dyy ) (vl-load-com)
  (setq highlight (getvar "HighLight"))
  (acet-error-init (list
                     (list   "cmdecho" 0
                           "highlight" highlight
                           "regenmode" 1
                              "osmode" 0
                             "ucsicon" 0
                          "offsetdist" 0
                              "attreq" 0
                            "plinewid" 0
                           "plinetype" 1
                            "gridmode" 0
                             "celtype" "CONTINUOUS"
                           "ucsfollow" 0
                            "limcheck" 0
                     )
                     T     ;flag. True means use undo for error clean up.
                     '(if redraw_it (redraw na 4))
                    );list
  );acet-error-init

  (prompt "\nSelect closed entities: ")
  (defun *error* (msg)
    (if highlight (setvar "highLight" highlight))
    (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*") (princ (strcat "\n** Error: " msg " **")))
    (princ))
  (if (setq ss (ssget (append (list '(-4 . "<or") '(0 . "CIRCLE") '(-4 . "<and") '(0 . "*POLYLINE") '(70 . 1) '(-4 . "and>") '(-4 . "<and") '(0 . "SPLINE") '(70 . 11) '(-4 . "and>") '(-4 . "<and") '(0 . "ELLIPSE") '(41 . 0.0)) (list (cons 42 (* 2 pi))) (list '(-4 . "and>") '(-4 . "or>")))))
    (progn
      (setq n (sslength ss))
      (while (>= (setq n (1- n)) 0)
        (setq en (ssname ss n) ed (entget en) enA (vlax-ename->vla-object en))
          (vla-getboundingbox enA 'minpoint 'maxpoint)
        (setq
         minpt (vlax-safearray->list minpoint)
         maxpt (vlax-safearray->list maxpoint)
        )
        (setq dx (- (car maxpt) (car minpt)))
        (setq dy (- (cadr maxpt) (cadr minpt)))
        (setq pt '(0.0 0.0 0.0))
        (while (not (ptinsideent pt en))
          (setq dxx (* dx (rnd)))
          (setq dyy (* dy (rnd)))
          (setq pt (list (+ (car minpt) dxx) (+ (cadr minpt) dyy) 0.0))
        )
        (etrim en pt)
      )
    )
  )
  (acet-error-restore)
  (setvar 'highlight highlight)
  (princ)
)

Regards, M.R.