add small circles to start and end of arcs

[MSasu]

Use this line to add the new layer:

(if (not (tblsearch "LAYER" "arcmark"))
 (entmakex '((0 . "LAYER") (100 . "AcDbSymbolTableRecord") (100 . "AcDbLayerTableRecord")
             (2 . "arcmark") (70 . 0) (62 . 3) (6 . "Continuous")))
)

To get the circles/blocks in desired layer just adjut:

(entmake (list '(0 . "CIRCLE") (cons 10 p) (cons 40 r) '(8 . "arcmark")))
...
(entmake (list '(0 . "INSERT") (cons 10 p) (cons 2 b) '(8 . "arcmark")))

[Tharwat]

@motee-z: Just add the line below to Tharwat's code:

(vl-load-com)

Thank you Mircea .

it works tharwat after adding (vl-load-com)
but polylines arcs not considered

thank you very much

You're welcome .

Polylines are not included because you did not ask about them into your first post .

[Lee Mac]

Polylines are not included because you did not ask about them into your first post .

hello tharwat
any diameter(optional)any block in the drawing
command line:
select arcs: all arcs selected even polyline if contain circles
enter radius of circle or name of block:

..........

[Tharwat]

I considered the first post , and I was writing the code when the OP replied to my first post .

Anyway , You did a very good routine that I learned how to include Polyline 's arc within the selection set filtration system.

[Tharwat]

i tried to add these lines in all possible places to create layer named(markarc) to lay circles on but i failed
(command "layer" "make" "arcmark" "")
(command "layer" "c" "3" "arcmark" "")
(command "color" "bylayer")
any suggestion

Try it now ....

(defun c:Test (/ ss i sn ins d bname)
;;; Tharwat 10. June. 2012  ;;;
  (vl-load-com)
  (if
    (and
      (setq ss (ssget "_x"
                      '((-4 . "<OR")
                        (0 . "ARC")
                        (-4 . "<AND")
                        (0 . "LWPOLYLINE")
                        (-4 . "<>")
                        (42 . 0.0)
                        (-4 . "AND>")
                        (-4 . "OR>")
                       )
               )
      )
      (progn
        (initget "Circle Block")
        (setq ins (getkword "\n Choose one [Circle/Block] :"))
      )
    )
     (progn
       (if (not (tblsearch "LAYER" "arcmark"))
         (entmakex '((0 . "LAYER")
                     (100 . "AcDbSymbolTableRecord")
                     (100 . "AcDbLayerTableRecord")
                     (2 . "arcmark")
                     (70 . 0)
                     (62 . 3)
                     (6 . "Continuous")
                    )
         )
       )
       (if (eq ins "Block")
         (progn
           (setq bname (getstring t "\n Enter name of Block :"))
           (tblsearch "BLOCK" bname)
           (repeat (setq i (sslength ss))
             (setq sn (ssname ss (setq i (1- i))))
             (foreach p (list (vlax-curve-getstartpoint sn)
                              (vlax-curve-getendpoint sn)
                        )
               (entmakex (list '(0 . "INSERT")
                               (cons 2 bname)
                               (cons 10 p)
                               '(8 . "arcmark")
                               '(41 . 1.0)
                               '(42 . 1.0)
                               '(43 . 1.0)
                         )
               )
             )
           )
         )
         (progn
           (if (setq d (getdist "\n Specify Diameter of Circle :"))
             (repeat (setq i (sslength ss))
               (setq sn (ssname ss (setq i (1- i))))
               (foreach p (list (vlax-curve-getstartpoint sn)
                                (vlax-curve-getendpoint sn)
                          )
                 (entmakex (list '(0 . "CIRCLE")
                                 '(8 . "arcmark")
                                 (cons 10 p)
                                 (cons 40 d)
                           )
                 )
               )
             )
           )
         )
       )
     )
     (princ)
  )
  (princ)
)

[motee-z]

thank you tharwat for your effort

[Tharwat]

thank you tharwat for your effort

You're welcome anytime ..

[irneb]

Lee I like these constructs:

(setq f (lambda ( p ) (entmake (list '(0 . "CIRCLE") (cons 10 p) (cons 40 r)))))

Though, what would be the difference if you simply used a normal defun statement instead of setq+lambda?

[Lee Mac]

Lee I like these constructs:

(setq f (lambda ( p ) (entmake (list '(0 . "CIRCLE") (cons 10 p) (cons 40 r)))))

Thank you Irné

Though, what would be the difference if you simply used a normal defun statement instead of setq+lambda?

To my knowledge, a negligible difference in performance, though, since the function 'f' is different for each option and is created during runtime I felt it more suitable to use an anonymous lambda function rather than using a defun expression. I tend to reserve defun expressions for cases in which the function is static and isolated from the main function (i.e. does not share local variables with the main function).