MText command in LISP

[Arepo]

I am trying to write a routine to "simulate" MText command in lisp using predefined Text Height (2.0mm in this case for 1:1 scale) and text Style. I started with this code:

(defun C:test (/ Height Style)
	(setvar "cmdecho" 1)
	(setq Height (* (getvar "DIMSCALE") 2.0 ))
	(setq Style "My_Style")
	(command "._MTEXT" pause "H" Height "S" Style pause)
 	(princ)
)

The text style seems to work but the Text Height doesn't change.
Could anyone help please?

[rickh]

Is (getvar "textsize") what you need instead of dimscale? You also have to ensure the text style used does not have a predefined height.
From F1 help for textsize:
Sets the default height for new text objects drawn with the current text style.
TEXTSIZE has no effect if the current text style has a fixed height.

-edit- if you just want the height to be 2.0, enter "2.0" instead of Height in your (command... ) line. Right now it is setting the value of Height to 2 times the current dimscale.

[Tharwat]

(defun c:Test (/ str p)
  (if (and (not (eq (setq str (getstring t "\n Type text string :")) ""))
       (setq p (getpoint "\n Specify Text location :"))
      )
    (entmake (list '(0 . "MTEXT") '(100 . "AcDbEntity") '(100 . "AcDbMText")
           (cons 10 p)
           (cons 40 (* (getvar "DIMSCALE") 2.0))
           (cons 7 (if (tblsearch "STYLE" "My_Style")  "My_Style"   "Standard" ))
           (cons 1 str)
         )
    )
  )
  (princ)
)

[Arepo]

What I am trying is to write a set of commands for different text styles and sizes. The text styles to be used are already loaded in the drawing template. Of course, text size should depend on DIMSCALE. I want the command to look as close to AutoCAD Mtext command as possible (have the Text Formatting box and the ability to write text on multiple lines). Something simple like MTEXT (MT) command I tried above, only having text style and text size predefined so I won't have to change them for different texts I'm using.
Rickh: The text styles I'm using don't have a predefined text height and I need text height depending on DIMSCALE so I have the right text size in Paper Space.
Tharwat: thank you for your code, works well but gives me the option to write text on one line only. Could you tell me why the code I tried doesn't work properly?

[Tharwat]

Tharwat: thank you for your code, works well but gives me the option to write text on one line only.

Try this ....

(defun c:Test (/ lst st p)
  (while (not (eq (setq st (getstring t "\n Type text string :")) "")
         )
    (setq lst (cons (strcat st "\\P") lst))
  )
  (if (setq p (getpoint "\n Specify Text location :"))
    (entmake (list '(0 . "MTEXT")
                   '(100 . "AcDbEntity")
                   '(100 . "AcDbMText")
                   (cons 10 p)
                   (cons 40 (* (getvar "DIMSCALE") 2.0))
                   (cons 7
                         (if (tblsearch "STYLE" "My_Style")
                           "My_Style"
                           "Standard"
                         )
                   )
                   (cons 1 (apply 'strcat (reverse lst)))
             )
    )
  )
  (princ)
)

[Lee Mac]

An alternative method:

(defun c:mtx ( / e h p s )

    (setq s "My_Style"
          h (* 2 (getvar 'dimscale))
    )    
    (if (setq p (getpoint "\nPoint for MText: "))
        (progn
            (setq e
                (entmakex
                    (list
                       '(0 . "MTEXT")
                       '(100 . "AcDbEntity")
                       '(100 . "AcDbMText")
                       '(1 . "")
                        (cons 10 (trans p 1 0))
                        (cons 40 h)
                        (cons 07 (if (tblsearch "STYLE" s) s "Standard"))
                    )
                )
            )
            (command "_.mtedit" e)
        )
    )
    (princ)
)

[Arepo]

[QUOTE=Lee Mac;484697]An alternative method:

That's exactly what I was looking for. I like having the Text Formatting window. It turned out to be more complicated code than I thought
Thank you very much!

[Lee Mac]

You're very welcome Arepo

[Arepo]

Thank you Tharwat, this works nicely.

[Tharwat]

Thank you Tharwat, this works nicely.

No problem ..