Whats the matter with my multiline text?

[nod684]

if the issue is that you want the Mtext Boundaries flushed with your Mtext width you can use this lisp

i don't remember where i got it from but i've been using it for a long time now

; Lisp routine for resizing mtext boundaries - where each mtext selected will have its grips flush with the text.
;
(defun c:FX (/ sset en el ymt nmt mtwidth mtcont)
 (setq sset (ai_aselect))
 (if (null sset) 
  (progn
  (princ "\nNo objects selected.")
  (exit)
  )
 )
 (setq COUNT 0)
 (setq ymt 0)
 (setq nmt 0)
 (if (/= sset nil)(setq EN (ssname sset COUNT))(setq EN nil))
 (WHILE (/= EN nil)
  (setq mtcont nil)
  (setq nel nil)
  (setq EL (entget EN))
  (if (= (cdr (assoc 0 EL)) "MTEXT")
;-------------------------------remove extra spaces-----------------------------
   (progn
    (setq mtwidth (* (cdr (assoc 42 el))1.015))
    (setq mtheight (cdr (assoc 43 el)))
    (setq EL (subst (cons 41 mtwidth) (assoc 41 EL) EL))
    (setq EL (subst (cons 46 mtheight) (assoc 46 EL) EL))
    (if (= (cdr (assoc 90 EL)) 2)
     (setq el (vl-remove (assoc 90 EL) EL))
    )
    (entmod EL)
    (entupd en)
    (setq el (entget en '("ACAD")))
    (if (/= (assoc -3 el) nil)
     (progn
      (setq oheight (assoc 1040 (cdadr (assoc -3 el))))
      (setq nheight (cons 1040 (cdr (assoc 43 el))))
      (setq n-3 (list (cons -3 (list (subst nheight oheight (cadr (assoc -3 el)))))))
      (setq el (vl-remove (assoc -3 el) el))
      (setq el (append el n-3))
     )
    )
    (entdel (cdr (assoc -1 el)))
    (entmake el)
;--------------------------------------------------------------------------------
    (setq COUNT (1+ COUNT))
    (setq EN (SSNAME sset COUNT))
    (setq ymt (1+ ymt))
   )
   (progn
    (setq COUNT (1+ COUNT))
    (setq EN (SSNAME sset COUNT))
    (setq nmt (1+ nmt))
   )
  )
 )
 (prompt (strcat "\n" (itoa ymt) " Mtext object(s) were resized, and " (itoa nmt) " object(s) were not Mtext."))
 (princ)
)

[rkent]

You are zoomed out too far so the program is enlarging the editing window so you can still read it. Zoom in much closer and try again.