run lisp in lisp???

[manase]

Good morning,
Let's say i have a lisp that will erase all points in a drawing. This is a general question, maybe there is a general solution, i don't know... My lisp works ok, but in my drawing i have some blocks - and these blocks have points inside. How can i use a lisp inside of each block in a drawing? I mean, is it possible to have a lisp that will run another lisp (already made) inside of each block in a drawing?

[MSasu]

Welcome to the Forum, Manase.

Seems to me that you are referring to two different matters. (1) To run an existing AutoLISP routine from your code just do, if defined as function:

(MyALispFunction)

respectively if defined as command:

(C:MyALispCommand)

(2) To apply the editing inside blocks, you will need to parse the entities that compose that block’s definition. Seems that your routine will require some re-work.

[irneb]

You might try creating a command function which steps through all blocks using the tblnext function. Then check for stuff (from the data returned by tblnext) like is it an xref / unnamed (i.e. dynamic block placeholder), if not start the BEdit command run the existing (c:CommandName) use BSave/BClose and loop to the next block. This is probably going to run very slow though, perhaps MSasu's second point may make it a lot faster.

Could you perhaps post the code so we can see what it does? Otherwise we can't give you a definitive answer.

[manase]

As i said, this is a general question, and i want a general solution - i mean, to have a lisp that will use another lisp already made, using MSasu solution,

(C:MyALispCommand)

  (defun c:points ( / )
    (setq p (ssget "_x"(list '(0 . "POINT"))))
    (command "erase" p "" )
    )

This is a basic example - i want to erase all points in a drawing, including points that are inside of blocks (and nested blocks). For me, the best solution is a lisp that will use another lisp (already made) inside of Bedit
command (with tblnext function). If will run slow, is not a problem - only few blocks and nested blocks in my drawings.

[MSasu]

A workaround based on your proposed solution:

; Kill Points in Blocks routine (29-VIII-2012)
(defun c:KPB( / blockItem ssetPoints )
 (while (setq blockItem (tblnext "BLOCK" (not blockItem)))
  (command "_BEDIT" (cdr (assoc 2 blockItem)))
  (if (setq ssetPoints (ssget "_X" '((0 . "POINT"))))
   (command "_ERASE" ssetPoints ""
            "_BCLOSE" "_S")
   (command "_BCLOSE")
  )
 )
 (princ)
)

[irneb]

Something like this then

(defun c:points ( / p)
  (if (setq p (ssget "_x"(list '(0 . "POINT"))))
    (command "erase" p "" ))
  (princ))

(defun c:points2 (/ blk)
  (while (setq blk (tblnext "BLOCK" (not blk)))
    (if (= (logand (cdr (assoc 70 blk)) (+ 1 4 8 16 32 64)) 0) ;Check for not unnamed / xref
      (progn (command "._BEDIT" (cdr (assoc 2 blk)))
        (c:points) ;Call other lisp routine
        (command "._BSAVE" "._BCLOSE"))))
  (princ))

[manase]

In this case, your solution is ok, but is not a general solution. I want to use my lisp "points" defined above, not to make a new selection of points...etc... - you don't use a lisp defined already. - this answer is for MSasu

[MSasu]

To use the said POINTS user defined command will need to adjust it a little to return if there were points removed or not - since this will affect the way BCLOSE built-in command works.

[irneb]

In this case, your solution is ok, but is not a general solution. I want to use my lisp "points" defined above, not to make a new selection of points...etc... - you don't use a lisp defined already. - this answer is for MSasu

Note that this is rather specific - not actually a "generalized" thing. In this case you're fortunate since the points command can operate inside the BEdit environment and doesn't ask for any user input - else the code in my previous post wouldn't have worked fully.

To use the said POINTS user defined command will need to adjust it a little to return if there were points removed or not - since this will affect the way BCLOSE built-in command works.

That's why I'm using the BSave before the BClose. That way BClose works the same no matter if something's changed or not.

[MSasu]

Please try this then:

(defun c:points( / p )
 (if (setq p (ssget "_x" (list '(0 . "POINT"))))
  (command "erase" p "")
  T
 )
)
; Kill Points in Blocks routine (29-VIII-2012)
(defun c:KPB( / blockItem )
 (while (setq blockItem (tblnext "BLOCK" (not blockItem)))
  (command "_BEDIT" (cdr (assoc 2 blockItem)))
  (if (C:POINTS)
   (command "_BCLOSE")
   (command "_BCLOSE" "_S")
  )
 )
 (princ)
)