Making DIMCONTINUE command honor current DIMSTYLE text placement formatting

[Dadgad]

I really enjoy using the DIMCONTINUE command, as it is really fast.
The problem I have with it, is that it overrides the current dimstyle
defined, TEXT PLACEMENT setting, with 'ABOVE DIM LINE WITH LEADER'.
I would prefer that it honor the DIMSTYLE saved text placement.

As it works now, every time I finish using this for a string of continued dimensions I need to remember to select them all and reapply the current dimstyle from the right click shortcut menu.
If I don't, and there are any dimensions too short to accommodate the text and arrows, the leader is added, which I don't want.

[Lee Mac]

Below is a very simple automation of the DimContinue and DimStyle commands:

(defun c:dimc ( / en )
    (setq en (entlast))
    (command "_.dimcontinue")
    (while (= 1 (logand 1 (getvar 'cmdactive)))
        (command "\\")
    )
    (if (not (eq en (entlast)))
        (progn
            (command "_.-dimstyle" "_A")
            (while (setq en (entnext en))
                (command en)
            )
            (command "")
        )
    )
    (princ)
)

Hope this helps!

[Dadgad]

Hi Lee, thanks very much for doing this,
but it seems I am still having the same issue.
Which seems to be that the DIMTMOVE value needs to remain 0, or be reset to 0 for any of the newly completed
dimensions, and the default behavior seems to switch it to 1, whenever the available space for the text
on the dimension line crosses the minimum threshold, instead of moving the text horizontally outside the arrow.

If I check the properties of a very short newly created continued dimension (displaying with the unwanted leader), in Properties it still says
it is the current dimstyle, BUT in order to restore that DIMTMOVE variable to 0, I have to click
dimension style in my right click shortcut menu and select the current dimstyle there, and that will reset it to
the TEXT PLACEMENT being beside the dimension line.

[Lee Mac]

Hi Lee, thanks very much for doing this,
but it seems I am still having the same issue.

You're welcome, though that's odd since the code seems to work for me:

DimCont.gif

[Dadgad]

Yes Lee, that is a very compelling argument, I must agree.
Let me give that another try.

I see said the blindman!
I was using the ESC button to exit the command, instead of ENTER.
Wherever you go, there you are!
Working like a charm now, just needed to keep my eyes on the road, thanks very much Lee!

That's smokin'!

[Lee Mac]

No worries Dadgad

Try this:

(defun c:dimc ( / *error* en )
    (defun *error* ( m )
        (if (not (eq en (entlast)))
            (progn
                (command "_.-dimstyle" "_A")
                (while (setq en (entnext en))
                    (command en)
                )
                (command "")
            )
        )
        (princ)
    )
    (setq en (entlast))
    (command "_.dimcontinue")
    (while (= 1 (logand 1 (getvar 'cmdactive)))
        (command "\\")
    )
    (*error* nil)
    (princ)
)

Now you should be able to exit with either 'Enter' or 'Esc'.

[Dadgad]

Too cool for school Lee!
Big old smile on my face, don't even need to learn how to use it.
Now that is what great design is all about, thanks again!

[Lee Mac]

Thanks Dadgad, you're very welcome.

[Dadgad]

I'm now eager to apply this enhanced version of DIMCONTINUE to
the hover over GRIP MENU for dimensions, so that if I choose to dimcontinue from that
drop down menu it will use this, instead of the default version.
If I click on DIMCONTINUE in that dropdown, the commandline shows
** CONTINUE DIMENSION **.
I tried creating a new alias for that in the CUI, but it is not recognized?