HELP needed with Autocad lisp!!!

[ruso]

I am in a hurry with the project so I don't have time to write this lisp myself specially couse I don't have any experience in it, so if anyone can help that would be great. Anyway I have a lot of parcels drawn in autocad and what i need to do is trim all the polyline endings and intersections and insert a point in the middle. Manually I do it this way:

- first i make circles (radius has to be 0.5) on the endings and intersections of polylines
- then I trim all the lines inside the circles
- then I insert a point in the center of circles and at the end delete circles.

There is also a picture at the bottom showing the first and the last fase of the process.

If anyone knows about the lisp that does that or maybe have time to write one it would help me a lot.

Thanks in advance. :-)cadtutor1.jpg

[ReMark]

Would it be possible to get the same affect if you created a block of a point and used a mask to block the ends of the lines? This block could then be inserted at each intersection.

In the future, to avoid a panic, it is best to seek an answer to a problem before you are on the threshold of your deadline. Just some friendly advice. No offense meant.

[rkmcswain]

Create a block containing a wipeout and a point, insert it on all the corners and then turn off the wipeout frames.

Here is what it looks like

blockit.png

[ReMark]

What he ^ ^ ^ said works for me. Plus he said it much better than I did too. LoL

[ruso]

Thanks but how do I make such a block? And can I insert it automaticly on every intersection and ending of polyline?

[ReMark]

You make it like any other block??

Automatically insert the block at every intersection? Is that practical? How many intersections are there?

[ruso]

Sorry for a delay on answer. Didn't have internet. There are many intersections and I have to do the sam thing on all polyline endings so the number is big. That's why I asked is there a way to insert them automatically to save time. Anyways I know how to make a block but I don't understand how to make a block containing a whipeout?!

[StykFacE]

If you put in your thread title "Willing to Pay" you might get a better response.

Or be patient... people are definitely generous but hope you can get someone to do something for you in time.

[ruso]

Good idea but I think I'm gonna wait a little more! :-)

If you put in your thread title "Willing to Pay" you might get a better response.

Or be patient... people are definitely generous but hope you can get someone to do something for you in time.

[Lee Mac]

Here is some hastily written code, but should perform as required:

trimparcel.gif

(defun c:trimparcel ( / a c d e h i l p s v )
    (if (setq s (ssget "_:L" '((0 . "LWPOLYLINE"))))
        (repeat (setq i (sslength s))
            (setq e (ssname s (setq i (1- i)))
                  d (entget e)
                  h (list
                        (assoc 8 d)
                        (cond ((assoc 06 d)) ('(06 . "BYLAYER")))
                        (cond ((assoc 62 d)) ('(62 . 256)))
                    )
                  v nil
            )
            (while (setq a (assoc 10 d))
                (setq p (cdr a)
                      v (cons p v)
                      d (cdr (member a d))
                )
                (if (not (vl-some '(lambda ( x ) (equal p x 1e-8)) l))
                    (progn
                        (entmake (vl-list* '(0 . "POINT") (cons 10 p) h))
                        (setq l (cons p l))
                    )
                )
            )
            (if (= 1 (logand 1 (cdr (assoc 70 (entget e)))))
                (setq v (cons (last v) v))
            )
            (mapcar
                (function
                    (lambda ( a b / x )
                        (if
                            (not
                                (vl-some
                                    (function
                                        (lambda ( x )
                                            (or (and (equal a (car x) 1e-8) (equal b (cadr x) 1e-8))
                                                (and (equal b (car x) 1e-8) (equal a (cadr x) 1e-8))
                                            )
                                        )
                                    )
                                    c
                                )
                            )
                            (progn
                                (setq c (cons (list a b) c)
                                      x (angle a b)
                                )
                                (entmake
                                    (vl-list*
                                       '(0 . "LINE")
                                        (cons 10 (polar a x 0.5))
                                        (cons 11 (polar b (+ x pi) 0.5))
                                        h
                                    )
                                )
                            )
                        )
                    )
                )
                v (cdr v)
            )
            (entdel e)
        )
    )
    (princ)
)
(princ)

Following the theme of Styk's post, perhaps make a contribution to my site if the above saves you time.