Define a regen after closing DWGPROPS?

[Keywordkid]

Hi folks,

I have very limited lisp understanding and generally try to work with what i have already been shown. I want to set up a ribbon tool for users to enter drawing details in the document properties which will auto fill the custom fields I have set up in our template file layout tabs. Currently when the edit is comlete and the dialogue is closed the fields remain unchanged until a regen is performed. Below is my poor attempt at redefining the dwgprops command but it clearly doesn't work.

; Define Document properties to regen on close
(command ".undefine" "dwgprops")
(defun c:dwgprops ()
(setvar "cmdecho" 0)
(command "-dwgprops")
(command ".regen")
(command ".dwgprops)
(setvar "cmdecho" 1)
(princ)
)

If it is possible I'd welcome some pointers - thanks.

[BlackBox]

Couple of things....

First, you seem to be missing a close quote here:

; Define Document properties to regen on close
(command ".undefine" "dwgprops")
(defun c:dwgprops ()
(setvar "cmdecho" 0)
(command "-dwgprops")
(command ".regen")
(command ".dwgprops")
(setvar "cmdecho" 1)
(princ)
)

If it is possible I'd welcome some pointers - thanks.

Your logic is sound, in that you're wanting the changes made to DwgProps to be reflected when you're done making changes. Where you've overlooked one option for accomplishing this is by not having a bit more experience - Don't worry, you'll get there.

When you consider that you're wanting to consistently perform a supplementary action following a specific Command, Undefining, and Redefining is one way to go about it. Were I to do this (and I may now add this to my setup, so for that I thank you for asking the question), I would employ a simple Command Reactor.

By using a Visual LISP Command Reactor, we can preclude the need to undefine a Command (in this case DwgProps), and instead simply monitor for the CommandEnded event (in lieu of CommandWillStart, CommandCancelled, etc.), as only when the DwgProps Command has successfully ended do we want our supplementary action to take place (in this case a regen).

Another advantage of using Visual LISP in this case is that we can regen the viewports without using another Command, as this has been exposed to the ActiveX API.

What does all of this look like?

Simple; to test load this psuedo-code:

(vl-load-com)

(defun DwgPropsCommandReactor:Start ()
  (or *DwgPropsCommandReactor*
      (setq *DwgPropsCommandReactor*
             (vlr-command-reactor
               "DwgPropsCommandReactor"
               '(
                 (:vlr-commandended . DwgPropsCallback:CommandEnded)
                )
             )
      )
  )
  (prompt "\n  >>  DwgProps command reactor loaded ")
  (princ)
)

(defun DwgPropsCallback:CommandEnded (rea cmd)
  (if (wcmatch (strcase (car cmd)) "DWGPROPS")
    (vla-regen (vla-get-activedocument (vlax-get-acad-object))
               acAllViewports
    )
  )
)

(defun c:StopR ()
  (if *DwgPropsCommandReactor*
    (progn
      (vlr-remove *DwgPropsCommandReactor*)
      (setq *DwgPropsCommandReactor* nil)
      (prompt "\n** DwgProps command reactor stopped ** ")
    )
  )
  (princ)
)

(DwgPropsCommandReactor:Start)

** Note - Be sure to NOT have the DwgProps Command undefined.

** Edit to add - I've also included a "STOPR" command so that if you'd like to turn this reactor of, you may.

HTH

[Keywordkid]

Many Thanks RenderMan,

Glad my idea may prove useful I'll give your code a try and see if I don't make a mess of it

[Keywordkid]

Thanks RenderMan - This works a treat! I just need to update the company Ribbon tools to include DWGPROPS to make it simple to run.

[Keywordkid]

HI RM,

Related to my initial idea, do you know if there is a method for pre-selecting the 'custom' tab in the DWGPROPS dialogue? - I want to make it as easy as possible to edit the fields for the users without running through instructions and tutorials.

Thanks,

KWK

[BlackBox]

Thanks RenderMan - This works a treat! I just need to update the company Ribbon tools to include DWGPROPS to make it simple to run.

Sorry for the delayed response - You're welcome, I'm happy to help.

Related to my initial idea, do you know if there is a method for pre-selecting the 'custom' tab in the DWGPROPS dialogue? - I want to make it as easy as possible to edit the fields for the users without running through instructions and tutorials.

Unfortunately not that I am aware of; once within a Command's dialog, AutoLISP, and even Visual LISP for that matter, are of little use.

[Keywordkid]

I thought that might be the case when Googling gave me no useful results, I've resorted to some text instructions in Defpoints just off the side of the Layout and hope the users will actually read it!!

Thanks for your help.

[kruuger]

HI RM,

Related to my initial idea, do you know if there is a method for pre-selecting the 'custom' tab in the DWGPROPS dialogue?

Thanks,
KWK

yes, with own custom prop dcl window
pros:
- multiple delete
- reorder, up-down
cons:
- not re-sizable

kruuger

[Keywordkid]

This looks interesting, is it just the dcl file that I need to edit for my preferred fields?

[kruuger]

This looks interesting, is it just the dcl file that I need to edit for my preferred fields?

what do mean by fields ?

you can change width of DCL to make it wider.
more props looks like this:

kruuger