Multiple Attribute Export

hi all,

I am using LEE MAC's code for getting attribute value which is as follows :-

(defun LM:vl-GetAttributeValue ( block tag )
   (setq tag (strcase tag))
   (vl-some
       (function
           (lambda ( attrib )
               (if (eq tag (strcase (vla-get-Tagstring attrib)))
                   (vla-get-TextString attrib)
               )
           )
       )
       (vlax-invoke block 'GetAttributes)
   )
)

(defun c:test ( / ss )  
   (if (setq ss (ssget "_+.:E:S" '((0 . "INSERT") (66 . 1))))
       (princ
           (LM:vl-GetAttributeValue
               (vlax-ename->vla-object (ssname ss 0))
               (getstring "\nSpecify Tag String: ")
           )
       )
   )
   (princ)
)
(vl-load-com)

But my prob is, I want to select multiple blocks at the time, please provide any solution for this

Thank you

(defun c:test ( / ss tag i)  
   (if
     (and (setq tag (getstring "\nSpecify Tag String: "))
          (not (eq "" tag))
     	   (setq ss (ssget  '((0 . "INSERT") (66 . 1))))
     )
       (repeat (setq i (sslength ss))
           (print (LM:vl-GetAttributeValue
               (vlax-ename->vla-object (ssname ss (setq i (1- i)))) tag
               
           )
                  )
       ) 
   )
   (princ)
)

Thankxxx a lot pBE.....

Problem solved completely....