How to view and open a Dwg Files in a Folder...???

[vasqrainier]

How to view and open a Dwg files in a Folder .. Folder Location is based on the DWGPREFIX... in Lisp programing..

[kpblc]

I think you can only open dwg files through lisp, but not to view them. Try somethink like this:

(defun c:autoload (/ z-files-in-directory)
  ;; Returns file list in "directory" folder by mask
  ;; Author: Zuenko Vitaly aka ZZZ
  (defun z-files-in-directory (directory pattern nested /)
    (if	(not (listp pattern))
      (setq pattern (list pattern))
      ) ;_ if
    (if	nested
      (apply
	'append
	(append
	  (mapcar '(lambda (_pattern)
		     (mapcar '(lambda (f) (strcat directory "\\" f))
			     (vl-directory-files directory _pattern 1)
			     ) ;_ list
		     ) ;_ lambda
		  pattern
		  ) ;_ mapcar
	  (mapcar
	    '(lambda (d)
	       (z-files-in-directory
		 (strcat directory "\\" d)
		 pattern
		 nested
		 ) ;_ z-files-in-directory
	       ) ;_ lambda
	    (vl-remove
	      "."
	      (vl-remove ".."
			 (vl-directory-files directory nil -1)
			 ) ;_ end of vl-remove
	      ) ;_ vl-remove
	    ) ;_ mapcar
	  ) ;_ append
	) ;_ append
      (apply
	'append
	(mapcar	'(lambda (_pattern)
		   (mapcar '(lambda (f) (strcat directory "\\" f))
			   (vl-directory-files directory _pattern 1)
			   ) ;_ list
		   ) ;_ lambda
		pattern
		) ;_ end of mapcar
	) ;_ end of apply
      ) ;_ end of if
    ) ;_ end of defun

  (foreach file	(z-files-in-directory
		  (vl-string-right-trim "\\" (getvar "dwgprefix"))
		  "*.dwg"
		  nil
		  ) ;_ end of z-files-in-directory
    ;; with subfolders
    (vla-open (vla-get-documents (vlax-get-acad-object)) file)
    ;;(command "_.-open" file)
    ) ;_ end of foreach
  ) ;_ end of defun

[Patrick_35]

Hi

(if (setq file (getfiled "Title" "" "dwg" 16))
  (progn
    (setq file (vla-open (vla-get-documents (vlax-get-acad-object)) file))
    (vla-activate file)
  )
)

@+

[kpblc]

In this case:
1. You're opening only 1 file
2. You're activating it right now. But! LISP execution could be terminated!

[Patrick_35]

1. You're opening only 1 file

Yes, it's only for one file
If you want all files in a directory and you have installed express tools, try

(if (setq files (acet-ui-pickdir))
  (mapcar '(lambda (x) (vla-open (vla-get-documents (vlax-get-acad-object)) (strcat files "\\" x))) (vl-directory-files files "*.dwg" 1))
)

You're activating it right now. But! LISP execution could be terminated!

Yes, because i have activated the drawing. If i don't use (vla-activate file), the lisp continued and you can work with the variable file

[kpblc]

Well, there is no guarantee to be Express Tools installed.

the lisp continued

I didn't knew it because I never open files for working with them through lisp.

[Patrick_35]

To know if the express tools are installed, it's enough to make (if (member "acetutil.arx" (arx)) ....)
I found how to have dialogue box of vba msgbox and inputbox (in vlisp) without passing by the express tools, but by still for the repertories. I'm certain that that must be some share, because if I look in express tools (acet-ui-pickdir [title [path [message]]]), with objectdcl (Odcl_BrowseFolder message [Path]) and doslib (dos_getdir title [path [message]]), I find that it's the same thing. If you knows how to make, I'm a prennor

@+

[kpblc]

Does it yours?
http://www.theswamp.org/index.php?topic=11480.0
And related:
http://www.theswamp.org/index.php?topic=9684.0
---
Edited:
I'm using my own ActiveX DLL for these messages, so it doesn't critical for me.

[Patrick_35]

Yes, and i have posted for InputBox, but i don't find for a dialog box directories in this forum and another

@+

[kpblc]

I don't remember where from i cutted this code:

(defun browsefolder (msg / shlobj folder fldobj outval)
  (vl-load-com)
  (setq
    shlobj (vla-getinterfaceobject
	     (vlax-get-acad-object)
	     "Shell.Application"
	     ) ;_ end of vla-getInterfaceObject
    folder (vlax-invoke-method
	     shlobj
	     'browseforfolder
	     0
	     (if msg
	       msg
	       ""
	       ) ;_ end of if
	     0
	     ) ;_ end of vlax-invoke-method
    ) ;_ end of setqs
  (vlax-release-object shlobj)
  (if folder
    (progn
      (setq
	fldobj (vlax-get-property folder 'self)
	outval (vlax-get-property fldobj 'path)
	) ;_ end of setq
      (vlax-release-object folder)
      (vlax-release-object fldobj)
      outval
      ) ;_ end of progn
    ) ;_ end of if
  ) ;_ end of defun