Hello freinds

Hello friends

how we can get entity color even it is bylayer

i use this syntax

(setq e (car(entsel"\select entity>... ")))
(setq objcolor (vla-get-Color (vlax-ename->vla-object e)))

if the entity bylayer i got color value 256 whatever the color is

Quick example:

(defun entcolor ( enx )
   (cond
       ((cdr (assoc 62 enx)))
       ((abs (cdr (assoc 62 (tblsearch "layer" (cdr (assoc 8 enx)))))))
   )
)

Call with DXF data, e.g.:

(if (setq ent (car (entsel)))
   (entcolor (entget ent))
)

something going wrong Lee

i got a message when getting value entcolor

#

what i want is to pick polyline or line then get its color store the color in a variable to use it later

How are you calling the function?

How are you using the value returned by the function?

(defun c:gcolr (/)
(defun objco ( enx )
   (cond
       ((cdr (assoc 62 enx)))
       ((abs (cdr (assoc 62 (tblsearch "layer" (cdr (assoc 8 enx)))))))
   )
)
(if (setq e (car (entsel"\n pick polyline,line")))
   (objco (entget e))
)
 )

where is the color value stored

(defun c:gcolr (/)
(defun objco ( enx )
   (cond
       ((cdr (assoc 62 enx)))
       ((abs (cdr (assoc 62 (tblsearch "layer" (cdr (assoc 8 enx)))))))
   )
)
(if (setq e (car (entsel"\n pick polyline,line")))
   (objco (entget e))
)
 )

where is the color value stored

With your current code the colour value is not stored, as you are not using the value returned by the 'objco' function.

Consider the following:

(defun c:gcolr ( / c e )
   (if (setq e (car (entsel)))
       (setq c (objco (entget e)))
   )
   (if c
       (princ (strcat "\nThe colour of the selected object is: " (itoa c)))
       (princ "\nThe user did not select an object.")
   )
   (princ)
)
(defun objco ( enx )
   (cond
       ((cdr (assoc 62 enx)))
       ((abs (cdr (assoc 62 (tblsearch "layer" (cdr (assoc 8 enx)))))))
   )
)

thank Lee that,s okay

You're welcome.