ZOOM EXTENTS INSIDE VIEWPORT AUTOMATICALLY

[pmadhwal7]

nearly 300 layouts to be prepare in my file, i just want to know is there any way to zoom and extents inside of all my viewports,

Edited July 1, 2020 by pmadhwal7

[rlx]

maybe one of these?

 

linky 1

 

linky 2

[BIGAL]

I think you have asked wrong question, if you just zoom e its the same as copying 1 layout 299 times. That's LAYOUT command.

 

Do you mean walk along the pline and zoom at a scale inside a viewport making 300 layouts ?

[pmadhwal7]

14 hours ago, rlx said:

maybe one of these?

 

linky 1

 

linky 2

both lsp are working perfect but only in one layout the same thing i want to do in all layouts.

[pmadhwal7]

5 hours ago, BIGAL said:

I think you have asked wrong question, if you just zoom e its the same as copying 1 layout 299 times. That's LAYOUT command.

 

Do you mean walk along the pline and zoom at a scale inside a viewport making 300 layouts ?

actually i have 300 sheets and which i copy from another dwg and they already have viewports, lsp that rlx provided are perfectly fitting but only in one layouts

[rlx]

in that case you need something like this

(setq old-ctab (getvar "CTAB"))
(foreach layout (layoutlist)
   (setvar "CTAB" layout)
   ;put call to mview zoom command here
)
(setvar "CTAB" old-ctab)

Edited July 2, 2020 by rlx

[pmadhwal7]

2 hours ago, rlx said:

in that case you need something like this

(setq old-ctab (getvar "CTAB"))
(foreach layout (layoutlist)
   (setvar "CTAB" layout)
   ;put call to mview zoom command here
)
(setvar "CTAB" old-ctab)

please tell me where to put those code?

[rlx]

;;; zoome.lsp - Zoom extents in all viewports - By Jimmy Bergmark - Copyright (C) 1997-2006 JTB World, All Rights Reserved
;;; Website: www.jtbworld.com - E-mail: info@jtbworld.com - 2000-08-29 - Tested on AutoCAD 2000

(defun c:zoome (/ oldcmdecho vplist curcvport nr vpss ms en x)
  (setq oldcmdecho (getvar "cmdecho"))(setvar "cmdecho" 0)(setq vplist (mapcar 'car (vports)))(setq curcvport (getvar "cvport"))
  (if (= (getvar "tilemode") 0)
    (progn
      (if (= (setq ms (getvar "cvport")) 1)(command "._mspace"))
      (setq nr 0 vpss (ssget "_x" (list
       '(-4 . "<AND") '(0 . "VIEWPORT")(cons 410 (getvar "ctab")) '(-4 . "<NOT") '(69 . 1) '(-4 . "NOT>") '(-4 . "AND>"))))
      (if vpss
        (repeat (sslength vpss)
          (setq en (entget (ssname vpss nr)))
          (if (and (= 0 (logand 1 (cdr (assoc 90 en))))(< 0 (cdr (assoc 68 en)))(/= 16384 (logand 16384 (cdr (assoc 90 en)))))
            (progn (setvar "cvport" (cdr (assoc 69 en)))(command "._zoom" "_e")))
          (setq nr (+ 1 nr))
        )
      )
      (if (= ms 1) (command "._pspace"))
    )
    (foreach x vplist (setvar "cvport" x) (command "._zoom" "_e"))
  )
  (setq vpss nil)(setvar "cvport" curcvport)(setvar "cmdecho" oldcmdecho)
  (princ)
)

; zoom extents all view ports rlx 2 jul 2020
(defun c:zeavp ( / c)(setq c (getvar "CTAB"))(foreach l (layoutlist) (setvar "CTAB" l)(c:zoome))(setvar "CTAB" c)(princ))

(princ "\nType zeavp or (c:zeavp) to run")
(princ)

[pmadhwal7]

1 hour ago, rlx said:

Great Sir it was working fine thanks a lot

;;; zoome.lsp - Zoom extents in all viewports - By Jimmy Bergmark - Copyright (C) 1997-2006 JTB World, All Rights Reserved
;;; Website: www.jtbworld.com - E-mail: info@jtbworld.com - 2000-08-29 - Tested on AutoCAD 2000

(defun c:zoome (/ oldcmdecho vplist curcvport nr vpss ms en x)
  (setq oldcmdecho (getvar "cmdecho"))(setvar "cmdecho" 0)(setq vplist (mapcar 'car (vports)))(setq curcvport (getvar "cvport"))
  (if (= (getvar "tilemode") 0)
    (progn
      (if (= (setq ms (getvar "cvport")) 1)(command "._mspace"))
      (setq nr 0 vpss (ssget "_x" (list
       '(-4 . "<AND") '(0 . "VIEWPORT")(cons 410 (getvar "ctab")) '(-4 . "<NOT") '(69 . 1) '(-4 . "NOT>") '(-4 . "AND>"))))
      (if vpss
        (repeat (sslength vpss)
          (setq en (entget (ssname vpss nr)))
          (if (and (= 0 (logand 1 (cdr (assoc 90 en))))(< 0 (cdr (assoc 68 en)))(/= 16384 (logand 16384 (cdr (assoc 90 en)))))
            (progn (setvar "cvport" (cdr (assoc 69 en)))(command "._zoom" "_e")))
          (setq nr (+ 1 nr))
        )
      )
      (if (= ms 1) (command "._pspace"))
    )
    (foreach x vplist (setvar "cvport" x) (command "._zoom" "_e"))
  )
  (setq vpss nil)(setvar "cvport" curcvport)(setvar "cmdecho" oldcmdecho)
  (princ)
)

; zoom extents all view ports rlx 2 jul 2020
(defun c:zeavp ( / c)(setq c (getvar "CTAB"))(foreach l (layoutlist) (setvar "CTAB" l)(c:zoome))(setvar "CTAB" c)(princ))

(princ "\nType zeavp or (c:zeavp) to run")
(princ)