Text name filter

[RepCad]

Hello every one,

I wrote this code to ssget all text :

(setq ss1 (ssget '((0 . "text,mtext"))))

 

Is it possible to ssget all texts except a specific text string in above code?  for example get all text except "Screw"

 

Edited March 26, 2020 by amir0914

[Tharwat]

What do you mean by 'text name' ? is it text style or text string ?

[RepCad]

I mean is text string.

[Tharwat]

(setq ss1 (ssget '((0 . "text,mtext")
		   (-4 . "<NOT")
		   (1 . "Screw")
		   (-4 . "NOT>")
		  )
	  )
)

 

[RepCad]

4 minutes ago, Tharwat said:

(setq ss1 (ssget '((0 . "text,mtext")
		   (-4 . "<NOT")
		   (1 . "Screw")
		   (-4 . "NOT>")
		  )
	  )
)

 

Thank you Tharwat, is it possible to do this with multiple text string name or list of string name? for example:

list = ("Screw","Hole","pin")

I mean ssget all texts except items of list

[Lee Mac]

Hint: (-4 . "<OR") ... (-4 . "OR>")

[Tharwat]

11 hours ago, amir0914 said:

Thank you Tharwat, is it possible to do this with multiple text string name or list of string name? for example:

list = ("Screw","Hole","pin")

I mean ssget all texts except items of list

 

Example:

(setq lst '("Screw" "Hole" "pin"))

(setq ss1 (ssget
	    (append '((0 . "text,mtext") (-4 . "<NOT") (-4 . "<OR"))
		    (mapcar '(lambda (u) (cons 1 u)) lst)
		    '((-4 . "OR>") (-4 . "NOT>"))
	    )
	  )
)

 

[RepCad]

Many thanks for your consideration, I have another request, is it possible to select items of lst by ssget ?

 

[Tharwat]

2 hours ago, amir0914 said:

Many thanks for your consideration, I have another request, is it possible to select items of lst by ssget ?

 

You're welcome anytime.

(setq lst '("Screw" "Hole" "pin"))

(setq ss1
       (ssget
	 (append
	   '((0 . "text,mtext"))
	   (list (cons 1 (apply 'strcat (mapcar '(lambda (u) (strcat u ",")) lst))))
	 )
     )
)

 

[ronjonp]

8 hours ago, Tharwat said:

 

Example:

(setq lst '("Screw" "Hole" "pin"))

(setq ss1 (ssget
	    (append '((0 . "text,mtext") (-4 . "<NOT") (-4 . "<OR"))
		    (mapcar '(lambda (u) (cons 1 u)) lst)
		    '((-4 . "OR>") (-4 . "NOT>"))
	    )
	  )
)

 

Quick test and this works too  (case sensitive of course).

(setq ss1 (ssget (append '((0 . "text,mtext"))
			 (mapcar '(lambda (u) (cons 1 (strcat "~" u))) '("Screw" "Hole" "pin"))
		 )
	  )
)

 

[RepCad]

Many thanks to Tharwat and ronjonp.