m2s lisp routine

[neilma]

Does anyone have the lisp to convert mesh to solids available to share?

Thanks in Advance
Neil

[fuccaro]

Did you search in this Forum for older posts? I am sure I posted the link before...
Well, not big deal: here is the link: http://www.accustudio.com/marketplace/freeware.htm

[neilma]

Hi Fuccaro,
Thank you for the link, I did do an extensive search through the forum and saw that you had posted this link previously. Unfortunatley the link no longer works (for me anyway) the page returns "The page cannot be found
The page you are looking for might have been removed, had its name changed, or is temporarily unavailable."

I also did a Google search of "m2s.lsp" and found an Italian version of the lisp, but cannot read the command line prompts!

Still looking!, Neil

[robfowler]

Just tried Fuccaro's link and it worked fine for me.

Try again.

Rob.

[neilma]

Hi robfowler,
fuccaro's link "http://www.accustudio.com/marketplace/freeware.htm" does work :lol: , the link to the actual lisp file does not :cry: . Try the following;
http://www.accustudio.com/marketplace/free/m2s.zip

Am I wrong :? ?

Neil

[Flores]

Here is the code:

;; M2S (Mesh-to-Solid)
;; Creates an ACIS solid from an open 3d polygon mesh.
;;
;; Take 2 - Updated 7/7/1998
;; - Works with REVSURF'd meshes that touch or cross axis of revolution.
;; - Works even if solid being constructed is not fully visible on screen.
;; - Works with all open meshes created with REVSURF, RULESURF,
;; EDGESURF, TABSURF, AI_MESH, and 3DMESH. Most of the stock 3D
;; surfaces will work if you use DDMODIFY to open them in the M
;; and N directions.
;; - Does not work with polyface entities.
;;
;; (c) Copyright 1998 Bill Gilliss.
;; All rights reserved... such as they are.
;;
;; bill.gilliss@aya.yale.edu gilliss@iglou.com
;;
;; I wrote this to create sculptable ACIS terrain models
;; for architectural site renderings. It could also be used
;; to create thin shells from meshes, by subtracting a moved
;; copy of the solid from the original solid. Let me know of
;; other uses you find for it, or problems you encounter.
;;
;; The solid is created by projecting each mesh facet "down"
;; the current z-axis to a plane a user-specified distance below
;; the lowest vertex. To assure that all parts of the mesh are
;; generated as solids, this distance can not be zero, but the
;; solid can be SLICEd later if need be.
;;
;; The solid will match the displayed mesh: if the mesh has
;; been smoothed and SPLFRAME is set to 0, the solid will be
;; smoothed. Otherwise, it will not be. The mesh itself is not
;; changed at all.
;;


(defun c:m2s (/ ent ename entlst M N MN SN SM ST smooth oldecho vtx d1
low vtxcnt vtxmax bot bottom p1 p2 p3 p4 c1 c2 c3 c4
b1 b2 b3 b4 soldepth ssall ssrow)

(setq oldecho (getvar "cmdecho"))
(setq oldsnap (getvar "osmode"))
(setq oldblip (getvar "blipmode"))
(setvar "cmdecho" 0)
(setvar "osmode" 0)
(setvar "blipmode" 0)
(command "undo" "begin")

;;select the mesh
(setq ent (entsel "Select a polygon mesh to solidify: "))
(setq ename (car ent))
(setq entlst (entget ename))

(if (not (= (cdr (assoc 0 entlst)) "POLYLINE"))
(progn
(alert "That is not a polygon mesh.")
(exit)
(princ)
);progn
);endif

(if
(not
(or
(= (cdr (assoc 70 entlst)) 16) ;open 3d polygon mesh
(= (cdr (assoc 70 entlst)) 20) ;open mesh w/ spline-fit vertices
);or
);not
(progn
(alert "That is not an *open* polygon mesh.")
(exit)
(princ)
);progn
);endif

;; decide whether to use smoothed or unsmoothed vertices
(setq M (cdr (assoc 71 entlst))) ;M vertices
(setq N (cdr (assoc 72 entlst))) ;N vertices
(setq SM (cdr (assoc 73 entlst))) ;smoothed M vertices
(setq SN (cdr (assoc 74 entlst))) ;smoothed N vertices
(setq ST (cdr (assoc 75 entlst))) ;surface type
(if
(or
(= (getvar "splframe") 1) ;use MxN vertices when splframe = 1
(= ST 0) ;or mesh has not been smoothed
)
(setq smooth 0
MN (* M N))
(setq smooth 1 ;use SMxSN vertices when mesh is smoothed
MN (* SM SN) ;and SPLFRAME = 0
M SM
N SN)
);if

;; determine lowest vertex
(grtext -2 "Checking out the mesh...")
(setq vtx ename)
(setq vtx (entnext vtx))
(setq d1 (entget vtx))
(setq bottom (caddr (trans (cdr (assoc 10 d1)) 0 1)))

(repeat (1- MN) ;compare with each vertex's z coord
(setq vtx (entnext vtx))
(setq d1 (entget vtx))
(setq low (caddr (trans (cdr (assoc 10 d1)) 0 1)))
(setq bottom (min bottom low))
);repeat

;; get desired thickness of solid
(setq soldepth 0)
(while
(zerop soldepth)
(progn
(setq soldepth
&#40;getdist "\nEnter desired thickness of solid below lowest vertex <1>&#58; "&#41;&#41;
&#40;if &#40;not soldepth&#41; &#40;setq soldepth 1.0&#41;&#41;
&#40;if &#40;zerop soldepth&#41;
&#40;princ "\nThickness can be small, but not zero. &#40;Slice it later, if need be.&#41;"&#41;&#41;
&#41;;progn
&#41;;while
&#40;setq bot &#40;- bottom &#40;abs soldepth&#41;&#41;&#41;

&#40;setq p1 ename&#41;
&#40;if &#40;= smooth 1&#41;
&#40;setq p1 &#40;entnext p1&#41;&#41;&#41; ;skip 1st vtx of smoothed mesh - not true vtx
&#40;setq ssrow &#40;ssadd&#41;&#41; ;initialize set of extruded segments to be unioned as a row
&#40;setq ssall &#40;ssadd&#41;&#41; ;initialize set of rows to be unioned into the whole
&#40;grtext -2 "Creating row..."&#41;
&#40;setq vtxmax &#40;- MN N&#41;&#41;
&#40;setq vtxcnt 1&#41;

;;create row of solid segments
&#40;while &#40;< vtxcnt vtxmax&#41;

&#40;if &#40;= 0 &#40;rem vtxcnt N&#41;&#41; ;at end of each row...
&#40;progn
&#40;setq rowmsg &#40;strcat "Unioning row "
&#40;itoa &#40;/ vtxcnt N&#41;&#41; " of "
&#40;itoa &#40;1- M&#41;&#41; "... "&#41;&#41;
&#40;grtext -2 rowmsg&#41;
&#40;command "union" ssrow ""&#41;
&#40;setq row &#40;entlast&#41;&#41;
&#40;ssadd row ssall&#41;
&#40;setq ssrow &#40;ssadd&#41;&#41;
&#40;setq p1 &#40;entnext p1&#41; ;skip to the next vertex
vtxcnt &#40;1+ vtxcnt&#41;&#41;
&#41;;progn
&#41;;if

&#40;grtext -2 "Creating row..."&#41;
&#40;setq p1 &#40;entnext p1&#41; ;first vertex of mesh square
p2 &#40;entnext p1&#41; ;second vertex
p3 p2&#41;
&#40;repeat &#40;1- n&#41; &#40;setq p3 &#40;entnext p3&#41;&#41;&#41; ;walk along to 3rd &#40;p1 + N&#41; vertex
&#40;setq p4 &#40;entnext p3&#41;&#41; ;4th vertex of mesh square

&#40;setq c1 &#40;trans &#40;cdr &#40;assoc 10 &#40;entget p1&#41;&#41;&#41; 0 1&#41; ;top coordinates
c2 &#40;trans &#40;cdr &#40;assoc 10 &#40;entget p2&#41;&#41;&#41; 0 1&#41;
c3 &#40;trans &#40;cdr &#40;assoc 10 &#40;entget p3&#41;&#41;&#41; 0 1&#41;
c4 &#40;trans &#40;cdr &#40;assoc 10 &#40;entget p4&#41;&#41;&#41; 0 1&#41;
b1 &#40;list &#40;car c1&#41; &#40;cadr c1&#41; bot&#41; ;bottom coordinates
b2 &#40;list &#40;car c2&#41; &#40;cadr c2&#41; bot&#41;
b3 &#40;list &#40;car c3&#41; &#40;cadr c3&#41; bot&#41;
b4 &#40;list &#40;car c4&#41; &#40;cadr c4&#41; bot&#41;&#41;
&#40;LOFT c1 c2 c3 b1 b2 b3&#41;
&#40;LOFT c2 c3 c4 b2 b3 b4&#41;

&#40;setq vtxcnt &#40;1+ vtxcnt&#41;&#41;
&#41;;while

&#40;grtext -2 "Unioning last row..."&#41;
&#40;command "union" ssrow ""&#41;
&#40;setq row &#40;entlast&#41;&#41;
&#40;ssadd row ssall&#41;
&#40;if &#40;> M 2&#41; ;bypass final union for N x 1 meshes &#40;i.e., RULESURF&#41;
&#40;progn
&#40;grtext -2 "Unioning all rows..."&#41;
&#40;command "union" ssall ""&#41;
&#41;;progn
&#41;;if

;;cleanup
&#40;command "undo" "end"&#41;
&#40;setvar "cmdecho" oldecho&#41;
&#40;setvar "osmode" oldsnap&#41;
&#40;setvar "blipmode" oldblip&#41;
&#40;setq ssall nil ssrow nil&#41;
&#40;princ&#41;

&#41;;defun

;;============== SUBROUTINES ====================
;&#40;defun *error* &#40;msg&#41;
; &#40;command&#41;
; &#40;command "undo" "end"&#41;
; &#40;setvar "cmdecho" oldecho&#41;
; &#40;setvar "osmode" oldsnap&#41;
; &#40;setvar "blipmode" oldblip&#41;
; &#40;princ &#40;strcat "\nError&#58; " msg&#41;&#41;
; &#41;;defun

&#40;defun LOFT &#40;r1 r2 r3 s1 s2 s3 / e1 extr highest&#41;
&#40;command "area" s1 s2 s3 ""&#41;
&#40;if &#40;not &#40;equal &#40;getvar "area"&#41; 0.0 0.00000001&#41;&#41;
&#40;progn
&#40;command "pline" s1 s2 s3 "c"&#41;
&#40;setq highest &#40;max &#40;caddr r1&#41; &#40;caddr r2&#41; &#40;caddr r3&#41;&#41;&#41;
&#40;setq extr &#40;- highest bot&#41;&#41;
&#40;command "extrude" &#40;entlast&#41; "" extr 0.0&#41;
&#40;command "slice" &#40;entlast&#41; "" "3points" r1 r2 r3 s1&#41;
&#40;setq e1 &#40;entlast&#41;&#41;
&#40;ssadd e1 ssrow&#41;
&#41;;progn
&#41;;if
&#41;;defun

&#40;princ "M2S loaded."&#41;



Flores

[neilma]

Flores,

Thank You,

Neil

[hyposmurf]

Is there a way to do the revers?Say from solid to mesh?

[David Bethel]

You can do a 3DSOUT and then 3DSIN. Beware, 3DS stuff in ACAD makes a lot of faces. They 3 sided faces only, never 4 sided. -David

[hyposmurf]

I'll try it out later thanks.

[fuccaro]

How about EXPLODE the solid and delete the unwanted surfaces?

[Paladin69]

'That is not an *open* polygon mesh' :(

That is the error message I get. I really need this to work for me but it looks like this doesn't with "polyface entities", and that's exactly what it says I have when ddmodify is run, and I have a lot of objects like that too.

This is an old tool. (1998 it says)
Is there a newer LSP or a different LSP tool?, or does anyone know how I can convert my stuff to an "open" polygon mesh so I can use this?

I'm really stuck and need some help.

[sychern]

I would like to know how to use it?

I saw "M2S loaded" on command like but don't know what to do next.

[erona]

Type M2S then select your mesh.

[kellenhaskell]

I have autocad 2007 and 3DSOUT comes out as "Unknown Command"???

[lewysr]

Might be a stupid question, but how would i go about executing the M2S.lsp?

Thanks for any help

[ReMark]

First you have to load it. You can do this with the APPLOAD command.

Then all you do is type M2S and select your mesh.

[lewysr]

Thanks ReMark.
I have loaded it and when i type M2S it tells me unknow command.

To create the lisp, i copied the text on page one, opened lisp editor, pasted, save as M2S.lisp then loaded that.

Not having much luck though :(

[fuccaro]

From the latest forum software upgrade we have some character code problems. The Lisp routine posted by our old friend Flores is affected too, I will ask David to take care of the code.
lewysr, you don't have to use the lisp editor -unless if you try to modify the code. Paste in Notepad, save the file with LSP extension and drag the file icon in the drawing area to load it.

[girrrrrrr2]

;; M2S (Mesh-to-Solid)
;; Creates an ACIS solid from an open 3d polygon mesh.
;;
;; Take 2 - Updated 7/7/1998
;; - Works with REVSURF'd meshes that touch or cross axis of revolution.
;; - Works even if solid being constructed is not fully visible on screen.
;; - Works with all open meshes created with REVSURF, RULESURF,
;; EDGESURF, TABSURF, AI_MESH, and 3DMESH. Most of the stock 3D
;; surfaces will work if you use DDMODIFY to open them in the M
;; and N directions.
;; - Does not work with polyface entities.
;;
;; (c) Copyright 1998 Bill Gilliss.
;; All rights reserved... such as they are.
;;
;; bill.gilliss@aya.yale.edu gilliss@iglou.com
;;
;; I wrote this to create sculptable ACIS terrain models
;; for architectural site renderings. It could also be used
;; to create thin shells from meshes, by subtracting a moved
;; copy of the solid from the original solid. Let me know of
;; other uses you find for it, or problems you encounter.
;;
;; The solid is created by projecting each mesh facet "down"
;; the current z-axis to a plane a user-specified distance below
;; the lowest vertex. To assure that all parts of the mesh are
;; generated as solids, this distance can not be zero, but the
;; solid can be SLICEd later if need be.
;;
;; The solid will match the displayed mesh: if the mesh has
;; been smoothed and SPLFRAME is set to 0, the solid will be
;; smoothed. Otherwise, it will not be. The mesh itself is not
;; changed at all.
;;


(defun c:m2s (/ ent ename entlst M N MN SN SM ST smooth oldecho vtx d1
low vtxcnt vtxmax bot bottom p1 p2 p3 p4 c1 c2 c3 c4
b1 b2 b3 b4 soldepth ssall ssrow)

(setq oldecho (getvar "cmdecho"))
(setq oldsnap (getvar "osmode"))
(setq oldblip (getvar "blipmode"))
(setvar "cmdecho" 0)
(setvar "osmode" 0)
(setvar "blipmode" 0)
(command "undo" "begin")

;;select the mesh
(setq ent (entsel "Select a polygon mesh to solidify: "))
(setq ename (car ent))
(setq entlst (entget ename))

(if (not (= (cdr (assoc 0 entlst)) "POLYLINE"))
(progn
(alert "That is not a polygon mesh.")
(exit)
(princ)
);progn
);endif

(if
(not
(or
(= (cdr (assoc 70 entlst)) 16) ;open 3d polygon mesh
(= (cdr (assoc 70 entlst)) 20) ;open mesh w/ spline-fit vertices
);or
);not
(progn
(alert "That is not an *open* polygon mesh.")
(exit)
(princ)
);progn
);endif

;; decide whether to use smoothed or unsmoothed vertices
(setq M (cdr (assoc 71 entlst))) ;M vertices
(setq N (cdr (assoc 72 entlst))) ;N vertices
(setq SM (cdr (assoc 73 entlst))) ;smoothed M vertices
(setq SN (cdr (assoc 74 entlst))) ;smoothed N vertices
(setq ST (cdr (assoc 75 entlst))) ;surface type
(if
(or
(= (getvar "splframe") 1) ;use MxN vertices when splframe = 1
(= ST 0) ;or mesh has not been smoothed
)
(setq smooth 0
MN (* M N))
(setq smooth 1 ;use SMxSN vertices when mesh is smoothed
MN (* SM SN) ;and SPLFRAME = 0
M SM
N SN)
);if

;; determine lowest vertex
(grtext -2 "Checking out the mesh...")
(setq vtx ename)
(setq vtx (entnext vtx))
(setq d1 (entget vtx))
(setq bottom (caddr (trans (cdr (assoc 10 d1)) 0 1)))

(repeat (1- MN) ;compare with each vertex's z coord
(setq vtx (entnext vtx))
(setq d1 (entget vtx))
(setq low (caddr (trans (cdr (assoc 10 d1)) 0 1)))
(setq bottom (min bottom low))
);repeat

;; get desired thickness of solid
(setq soldepth 0)
(while
(zerop soldepth)
(progn
(setq soldepth
(getdist "\nEnter desired thickness of solid below lowest vertex <1>: "))
(if (not soldepth) (setq soldepth 1.0))
(if (zerop soldepth)
(princ "\nThickness can be small, but not zero. (Slice it later, if need be.)"))
);progn
);while
(setq bot (- bottom (abs soldepth)))

(setq p1 ename)
(if (= smooth 1)
(setq p1 (entnext p1))) ;skip 1st vtx of smoothed mesh - not true vtx
(setq ssrow (ssadd)) ;initialize set of extruded segments to be unioned as a row
(setq ssall (ssadd)) ;initialize set of rows to be unioned into the whole
(grtext -2 "Creating row...")
(setq vtxmax (- MN N))
(setq vtxcnt 1)

;;create row of solid segments
(while (< vtxcnt vtxmax)

(if (= 0 (rem vtxcnt N)) ;at end of each row...
(progn
(setq rowmsg (strcat "Unioning row "
(itoa (/ vtxcnt N)) " of "
(itoa (1- M)) "... "))
(grtext -2 rowmsg)
(command "union" ssrow "")
(setq row (entlast))
(ssadd row ssall)
(setq ssrow (ssadd))
(setq p1 (entnext p1) ;skip to the next vertex
vtxcnt (1+ vtxcnt))
);progn
);if

(grtext -2 "Creating row...")
(setq p1 (entnext p1) ;first vertex of mesh square
p2 (entnext p1) ;second vertex
p3 p2)
(repeat (1- n) (setq p3 (entnext p3))) ;walk along to 3rd (p1 + N) vertex
(setq p4 (entnext p3)) ;4th vertex of mesh square

(setq c1 (trans (cdr (assoc 10 (entget p1))) 0 1) ;top coordinates
c2 (trans (cdr (assoc 10 (entget p2))) 0 1)
c3 (trans (cdr (assoc 10 (entget p3))) 0 1)
c4 (trans (cdr (assoc 10 (entget p4))) 0 1)
b1 (list (car c1) (cadr c1) bot) ;bottom coordinates
b2 (list (car c2) (cadr c2) bot)
b3 (list (car c3) (cadr c3) bot)
b4 (list (car c4) (cadr c4) bot))
(LOFT c1 c2 c3 b1 b2 b3)
(LOFT c2 c3 c4 b2 b3 b4)

(setq vtxcnt (1+ vtxcnt))
);while

(grtext -2 "Unioning last row...")
(command "union" ssrow "")
(setq row (entlast))
(ssadd row ssall)
(if (> M 2) ;bypass final union for N x 1 meshes (i.e., RULESURF)
(progn
(grtext -2 "Unioning all rows...")
(command "union" ssall "")
);progn
);if

;;cleanup
(command "undo" "end")
(setvar "cmdecho" oldecho)
(setvar "osmode" oldsnap)
(setvar "blipmode" oldblip)
(setq ssall nil ssrow nil)
(princ)

);defun

;;============== SUBROUTINES ====================
;(defun *error* (msg)
; (command)
; (command "undo" "end")
; (setvar "cmdecho" oldecho)
; (setvar "osmode" oldsnap)
; (setvar "blipmode" oldblip)
; (princ (strcat "\nError: " msg))
; );defun

(defun LOFT (r1 r2 r3 s1 s2 s3 / e1 extr highest)
(command "area" s1 s2 s3 "")
(if (not (equal (getvar "area") 0.0 0.00000001))
(progn
(command "pline" s1 s2 s3 "c")
(setq highest (max (caddr r1) (caddr r2) (caddr r3)))
(setq extr (- highest bot))
(command "extrude" (entlast) "" extr 0.0)
(command "slice" (entlast) "" "3points" r1 r2 r3 s1)
(setq e1 (entlast))
(ssadd e1 ssrow)
);progn
);if
);defun

(princ "M2S loaded.")



I found that somewhere, but when I ran it on what should have been a polygon mesh it said it wasnt one... it may be broken in 2010...
But, in 2010 you can just use union.