Modify The Rectangle Comand??

I Use The Rectangle Command For Corner To Corner In A Room. Then I Have To Add 2 Lines Corner To Corner To Make An X To Find The Center Of The Rectangle. Is The A Lisp Or A Fast Way To Do This?

AutoCAD 2005? Is there a M2P or MTP command?

M2P (a command modifier).

"Locates the midpoint between two points."

Check your AutoCAD Help files.

That Doesn't Work.... Would Be Nice

Really the X is unnecessary, you could just draw a diagonal line and snap to its midpoint.

Probably not much help, but it will save you a few seconds every time because now you'll only have to draw/delete one line instead of two.

Pick from one of the routines included in this discussion.

http://discussion.autodesk.com/forums/thread.jspa?threadID=416112

I Know That I Just Need Something That Makes A Mid Point In The Center Of A Rectangle To Snap To. I Would Save Me Alot Of Time

Try this one too

(defun C:RECX (/ pts)
(command "._rectangle")
(while (/= 0 (logand 1 (getvar 'cmdactive)))
 (command pause))
(setq  pts (vl-remove-if 'not
    (mapcar (function (lambda(x)
 (if (= 10 (car x))(trans (cdr x) 0 1))))
     (entget(entlast)))))
(command "._line" "_non" (car pts)"_non" (caddr pts) "")
(command "._line" "_non" (cadr pts)"_non" (last pts) "")
 (princ)
 )

~'J'~

fixo is the $#!t !!!! you will save me hours a month now thank you so much!!!!

You're welcome

Cheers

~'J'~

I thought M2P was around in '05. When did it become available?

Here, try this as a replacement for M2P since it's not available for you.

(defun c:M2P (/ p1 p2)
 ;; Midpoint Between Two Points (for older CAD versions)
 ;; Alan J. Thompson, 04.28.10
 (vl-load-com)
 (if (zerop (getvar 'cmdactive))
   (princ "\nMust be called from within another command.")
   (and (setq p1 (getpoint "\nFirst point of mid: "))
        (setq p2 (getpoint p1 "\nSecond point of mid: "))
        ((lambda (p)
           (vla-sendcommand
             (cond (*AcadDoc*)
                   ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
             )
             (strcat "_non " (car p) "," (cadr p) "," (caddr p) " ")
           )
         )
          (mapcar (function (lambda (x) (rtos x 2 16)))
                  (mapcar (function (lambda (a b) (/ (+ a b) 2.))) p1 p2)
          )
        )
   )
 )
 (princ)
)

Call it transparently within a command.

eg.

Command: l LINE Specify first point: 'm2p

First point of mid:
Second point of mid: Specify first point: Specify first point: _non 
10343.53278729567,10349.24066037932,0
Specify next point or [undo]: *Cancel*

Ah hah! I just found where I had it written down. Before the days of M2P, you could put this in your toolbar:

_non;'cal (cur + cur)/2;

alanjt, I've been looking for something like that little button routine for longer than I care to state here. Thanks for posting it.

You folks are good to us old ones

alanjt, I've been looking for something like that little button routine for longer than I care to state here. Thanks for posting it.

 

You folks are good to us old ones

You're very welcome.

I was hoping someone would find it useful and now you have two options.

I'm especially happy now that I dug around for the text file I had that written down in.

Happy CAD'ing.