coordinate labeling

hi guys,

i have more than 500 points to get the coordinates.

i'm badly in need of a lisp that would make my work easier and faster.

example:

1. command ___

2. select basepoint

3. select basepoint to put the text of the coordinates.

:if ther can be an option to have a leader pointing at the basepoint also.

thanks

Would this be of any use to you?

http://cadtips.cadalyst.com/coordinates/label-xyz

One of my old ones:

(defun c:mpt ( / _MText normal pt )
 ;; © Lee Mac 2010

 (defun _MText ( point text normal )
   (entmakex
     (list
       (cons 0 "MTEXT")
       (cons 100 "AcDbEntity")
       (cons 100 "AcDbMText")
       (cons 10 point)
       (cons 11 (getvar 'UCSXDIR))
       (cons 1  text)
       (cons 210 normal)
     )
   )
 )

 (setq normal (trans '(0. 0. 1.) 1 0 t))
 (terpri)
 (while (setq pt (getpoint "\rSpecify Point: "))
   (setq pt (trans pt 1 0))
   (_MText pt
     (apply 'strcat
       (mapcar 'strcat '("X = " "\nY = " "\nZ = ") (mapcar 'rtos pt))
     )
     normal
   )
 )
 (princ)
)

thanks Lee Mac! work done in no time

thanks Lee Mac! work done in no time

Good stuff