make the crosshair visible during getcorner

Hello

I need a tip on how to make cross hair visible during getcorner function.Crosshair disappears during the second pick point.

(setq zonearea (getcorner (setq origin (getpoint))  "corner" )) 

Merci

To my knowledge, the only way you could achieve this is by creating a function to emulate the behaviour of the getcorner function, by using the grread function to monitor the cursor location.

For example:

;; Get Corner  -  Lee Mac
;; A grread substitution for the getcorner function
;; pt  -  A point to be used as the base point.
;; msg -  A string to be displayed to prompt the user.
;; Returns: Selected UCS point, else nil

(defun LM:GetCorner ( pt msg / gr pl )
   (if msg (princ msg))
   (while (= 5 (car (setq gr (grread t 13 0))))
       (redraw)
       (setq gr (cadr gr)
             pl (list pt (list (car gr) (cadr pt))
                      gr (list (car pt) (cadr gr))
                )
       )
       (mapcar 'grdraw pl (cons (last pl) pl) '(-1 -1 -1 -1))
   )
   (redraw)
   (if (listp (cadr gr)) (cadr gr))
)

(if (setq p1 (getpoint "\nFirst Point: "))
   (LM:GetCorner p1 "\nNext Point: ")
)

Thanks for reply, its getting a bit to much I dont need to see crosshair that badly.Its strange first point crosshair there, but on the second point it dissapears.

Its strange first point crosshair there, but on the second point it dissapears.

This is standard AutoCAD behaviour - the same occurs for Window / Crossing selections.