Jump to content

Convert Mline To Pline


MR MAN

Recommended Posts

  • Replies 20
  • Created
  • Last Reply

Top Posters In This Topic

  • Lee Mac

    7

  • sCO

    6

  • alanjt

    2

  • MR MAN

    2

Top Posters In This Topic

I don't know how to do it directly, but you can always use EXPLODE. Then select a segment and use PEDIT. It asks if you want to convert to a pline. Say "yes" the use JOIN to get all the pieces back together.

Should work, but does anyone have a more direct way that could eliminate the need to select each segment individually?

--DM

Link to comment
Share on other sites

Perhaps :

 

(defun c:m2p (/ vlst ovar ent ss elast)
 (setq vlst '("CMDECHO" "PEDITACCEPT")
   ovar (mapcar 'getvar vlst))
 (if (and (setq ent (car (entsel "\nSelect Multi-Line...")))
      (eq "MLINE" (cdadr (entget ent))))
   (progn
     (mapcar 'setvar vlst '(0 1))
     (command "_explode" ent) (setq ss (ssadd))
     (mapcar '(lambda (x) (ssadd x ss)) (Ent_List_to_End ent))
     (setq elast (entlast))
     (command "_pedit" "_M" ent ss elast "" "_J" "" ""))
   (princ "\n<!> No Multi-Line Selected <!>"))
 (mapcar 'setvar vlst ovar)
 (princ))

(defun Ent_List_to_End(ent / a)
 (reverse
   (if(setq a(entnext ent))
      (cons ent(Ent_List_to_End a)))))

Link to comment
Share on other sites

Thanks Lee Mac For Your Help As I Expect From You ALWAYS

And Thank You Also Drainmasta Really I Want Lisp Routine To Do That And Lee Mac Make It

 

 

Thanks Again Guys For Your Help

Link to comment
Share on other sites

  • 9 months later...

This is probably better:

 

(defun c:m2p (/ *error* EntNext_to_End DOC ELST ENT I MSS OV SS UFLAG VL)
 ;; MLine to PLine  ~  Lee Mac  ~  04.01.10

 (defun *error* (msg)
   (and ov    (mapcar (function setvar) vl ov))
   (and uflag (vla-EndUndoMark doc))
   (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
       (princ (strcat "\n** Error: " msg " **")))
   (princ))

 (defun EntNext_to_End (ent / a)
   (if (setq ent (entnext ent))
     (cons ent (EntNext_to_End ent)))) 

 (setq vl '("CMDECHO" "PEDITACCEPT" "QAFLAGS")
       ov  (mapcar (function getvar) vl) ss (ssadd))

 (mapcar (function setvar) vl '(0 1 0))

 (if (setq i -1 mss (ssget "_:L" '((0 . "MLINE"))))
   (progn
     (setq uFlag (not (vla-StartUndoMark
                        (setq doc (vla-get-ActiveDocument
                                    (vlax-get-acad-object))))))

     (while (setq ent (ssname mss (setq i (1+ i))))
       (setq eLst (entlast) ss (ssadd))

       (vl-cmdf "_.explode" ent)

       (mapcar (function (lambda (x) (ssadd x ss)))
               (EntNext_to_End eLst))

       (vl-cmdf "_.pedit" "_M" ss "" "_J" "" "")
       (setq ss nil))

     (setq uFlag (vla-EndUndoMark doc))))

 (mapcar (function setvar) vl ov)
 (princ))

Link to comment
Share on other sites

  • 9 months later...

Hey Lee, I was wondering if you could help me out too. I'm looking for a similar lisp to the one you wrote but with a little extra. I tried to combine yours with another lisp I found and had some success but I still can't figure out how to finish it off. I'm trying to draw an Mline, have it explode and made into a polyline, and then put the polylines created on 2 or 3 specific layers. I'm up to the point where I have your lisp make the polylines and they end up on a single layer that was made current at some point in the lisp, but I can't figure out how to select certain lines to bring to a new current layer. or something like that.

Link to comment
Share on other sites

Here's your edited code I was working with:

 

(defun c:mlb ( / *error* vl ov LastEntity ent ss currlay)
 ;; © Lee Mac  ~  19.06.10
   

(setq currlay (getvar "clayer"))
(SETQ lr1 (TBLSEARCH "LAYER" "P-SD-CL-L"))	
(IF (= LR1 NIL)	
(COMMAND "LAYER" "MAKE" "P-SD-CL-L" "COLOR" "BYLAYER" "" ""))
(command "layer" "set" "P-SD-CL-L" "" "")

   ;;Sco'S COMMENTS - SETS LAYER FOR NEW OBJECTS, IF MISSING, CREATES IT.

 (defun *error* ( msg )
   (mapcar 'setvar vl ov)
   (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
       (princ (strcat "\n** Error: " msg " **")))
   (princ))

  

 (setq vl '("CMDECHO" "PEDITACCEPT" "QAFLAGS")
       ov (mapcar 'getvar vl))

 (setq LastEntity (entlast))

  

 (command "_.mline" "ST" "B")
 (while (= 1 (logand 1 (getvar 'CMDACTIVE)))
   (command pause))
   (prompt "pick")

   

 (if (not (equal LastEntity (setq ent (entlast))))
   (progn
     (mapcar 'setvar vl '(0 1 5))

  
     
     (vl-cmdf "_.explode" ent "")

  



     (setq ss (ssadd))
     (mapcar '(lambda ( e ) (ssadd e ss)) (LM:EntnexttoEnd ent))

     (vl-cmdf "_.pedit" "_M" ss "" "_J" "" "")))

    (mapcar 'setvar vl ov)
    (princ)

     


     

 

(I hope I didn't mess it up too bad)

 

So I'm using a 3 line Mline with one in the center and 2 offset .5 either side. I have all brought on to the P-SD-CL-L layer. At the end I was want to select the 2 outer lines and bring them onto a new layer (P-SD-L), but leave the center on P-SD-CL-L. I kept trying to change current layer again and then select 2 previous but I just couldn't figure it out.

 

Any help would be greatly appreciated.

Link to comment
Share on other sites

It would be very difficult to know which lines were which after exploding the MLine - my routine merely makes a list of all created entities following the explosion.

Link to comment
Share on other sites

It would be very difficult to know which lines were which after exploding the MLine - my routine merely makes a list of all created entities following the explosion.

Right, I think I might have found a work around with the double offset lisp you posted here

http://www.cadtutor.net/forum/showthread.php?52725-Lisp-that-draws-a-line-and-offsets-next-line-a-centerline-and-next-a-solid-2-quot-apart

It just seems that everything I'm looking for you have already done :D

I personally like this lisp better because it doesn't have to work with pesky mline profiles.

Link to comment
Share on other sites

 

That lisp is amazing as well! We operate with all objects on a layers specifically made with names for the objects. Everything stays colored ByLayer so all objects can be changed at the same time for pen screening if things are too heavy or too light somewhere. Anyways, (ex) we draw pipes with a cl on one layer and the pipe line on a different layer. I was just trying get a lisp that would get me that but I think i've got an addition to the link I posted above if Lee Mac is ok with an edited version of his code.

 

Thanks for the input!

Link to comment
Share on other sites

if Lee Mac is ok with an edited version of his code.

 

Sure, I don't mind people editing my code, with the proviso that all headers etc remain in tact, and all modifications are marked/initialed :)

Link to comment
Share on other sites

Ok, so I'm new to this but what I changed ended up working for me. I'm still getting an "Uknown command 'SD'"" message so I probably have something extra somewhere. But here it is:

 

		;;START sCo'S EDITION;;

;;------------=={ SD PIPE EDIT OF Double Offset }==-----------;;
;;  This is an edition of Lee McDonnell's Double Offset code  ;;
;;  to an semi-automated pipe generating lisp                 ;;
;;  Description                                               ;;
;;	Changes current layer to specified layer              ;;
;;	Prompts to draw polyline                              ;;
;;	Changes current layer to second specified layer       ;;
;;	Starts Lee McDonnell's Doff lisp                      ;;
;;	specifies Layer then Current then a distance          ;;
;;	User hits enter and selects initial polyline          ;;
;;		*Carefull, the current layer is now that of   ;;
;;		the new offset lines*			      ;;

	;;END sCo'S EDITION;;

;;--------------------=={ Double Offset }==-------------------;;
;;                                                            ;;
;;  Offsets each object in a selection to both sides by a     ;;
;;  specified distance. With additional controls for erasure  ;;
;;  of source object and offset layer.                        ;;
;;------------------------------------------------------------;;
;;  Author: Lee McDonnell, 2010                               ;;
;;                                                            ;;
;;  Copyright © 2010 by Lee McDonnell, All Rights Reserved.   ;;
;;  Contact: Lee Mac @ TheSwamp.org, CADTutor.net             ;;
;;------------------------------------------------------------;;
;;  Version: 1-1 20100912                                     ;;
;;------------------------------------------------------------;;

	;;START sCo'S EDITION TO CODE;;

(defun c:SD ( / *error* _StartUndo _EndUndo DoubleOffset
               DOC EXITFLAG LAYER MPOINT OBJ OBJECT OF POINT SEL SYMBOL VALUE currlay doff doubleoffset )
  (vl-load-com)

(setq currlay (getvar "clayer"))
(SETQ lr1 (TBLSEARCH "LAYER" "P-SD-CL"))  ;;EDIT FOR CL LAYER;;	
(IF (= LR1 NIL)	
(COMMAND "LAYER" "MAKE" "P-SD-CL" "COLOR" "BYLAYER" "" ""))  ;;EDIT FOR CL LAYER;;  
(command "layer" "set" "P-SD-CL" "" "")  ;;EDIT FOR CL LAYER;;


	;;SETS LAYER FOR NEW OBJECTS, IF MISSING, CREATES IT. 

(command "_.pline")
(while (= 1 (logand 1 (getvar 'CMDACTIVE)))
   (command pause))
   (prompt "pick")

	;;STARTS PLINE;;

(setq currlay (getvar "clayer"))
(SETQ lr1 (TBLSEARCH "LAYER" "P-SD-L"))  ;;EDIT FOR OUTER PIPE LAYER;;	
(IF (= LR1 NIL)	
(COMMAND "LAYER" "MAKE" "P-SD-L" "COLOR" "BYLAYER" "" ""))  ;;EDIT FOR OUTER PIPE LAYER;;
(command "layer" "set" "P-SD-L" "" "")  ;;EDIT FOR OUTER PIPE LAYER;;

	;;SETS LAYER FOR NEW OBJECTS, IF MISSING, CREATES IT.

	;;END sCo'S EDITION TO CODE;;


 (defun *error* ( msg )    
   (and doc (_EndUndo doc))
   (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
       (princ (strcat "\n** Error: " msg " **")))
   (princ)
 )

 (defun _StartUndo ( doc ) (vla-StartUndoMark doc))

 (defun _EndUndo ( doc ) (if (= 8 (logand 8 (getvar 'UNDOCTL))) (vla-EndUndomark doc)))
 
 (defun DoubleOffset ( object offset layer )
   (mapcar
     (function
       (lambda ( o )
         (if
           (and
             (not
               (vl-catch-all-error-p
                 (setq o
                   (vl-catch-all-apply
                     (function vlax-invoke) (list object 'Offset o)
                   )
                 )
               )
             )
             layer
           )
           (mapcar
             (function
               (lambda ( o )
                 (vla-put-layer o (getvar 'CLAYER))
               )
             )
             o
           )
         )
       )
     )
     (list offset (- offset))
   )
 )

 (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))

 (mapcar
   '(lambda ( symbol value ) (or (boundp symbol) (set symbol value)))
   '(*dOff:Erase *dOff:Layer) '("No" "Source")
 )

 (if
   (progn
     (while
       (progn
         (princ
           (strcat
             "\nCurrent Settings: Erase source="
             *dOff:Erase
             "  Layer="
             *dOff:Layer
             "  OFFSETGAPTYPE="
             (itoa (getvar 'OFFSETGAPTYPE))
           )
         )
         (initget 6 "Through Erase Layer")
         (setq of
           (getdist
             (strcat "\nSpecify Offset Distance [Through/Erase/Layer] <"
               (if (minusp (getvar 'OFFSETDIST)) "Through"  (rtos (getvar 'OFFSETDIST))) "> : "
             )
           )
         )
         (cond
           (
             (null of) (not (setq of (getvar 'OFFSETDIST)))
           )
           (
             (eq "Through" of) (setq of (setvar 'OFFSETDIST -1)) nil
           )
           (
             (eq "Erase" of) (initget "Yes No")

             (setq *dOff:Erase
               (cond
                 (
                   (getkword
                     (strcat "\nErase source object after offsetting? [Yes/No] <" *doff:Erase "> : ")
                   )
                 )
                 ( *dOff:Erase )
               )
             )
           )
           (
             (eq "Layer" of) (initget "Current Source")

             (setq *dOff:Layer
               (cond
                 (
                   (getkword
                     (strcat "\nEnter layer option for offset objects [Current/Source] <" *dOff:Layer "> : ")
                   )
                 )
                 ( *dOff:Layer )
               )
             )
           )
           ( of (setvar 'OFFSETDIST of) nil )
         )
       )
     )
     of
   )
   (while
     (progn
       (or ExitFlag
         (progn (initget "Exit")
           (setq sel (entsel "\nSelect object to offset or [Exit] <Exit> : "))
         )
       )
       
       (cond
         (
           (or ExitFlag (null sel) (eq sel "Exit")) nil
         )
         ( (vl-consp sel)

           (_EndUndo doc) (_StartUndo doc)

           (if (and (wcmatch (cdr (assoc 0 (entget (car sel)))) "ARC,CIRCLE,ELLIPSE,SPLINE,LWPOLYLINE,XLINE,LINE")
                    (setq obj (vlax-ename->vla-object (car sel))))

             (if (minusp of)
               (if
                 (progn (initget "Exit Multiple")
                   (and
                     (setq point (getpoint "\nSpecify through point or [Exit/Multiple] <Exit> : "))
                     (not (eq "Exit" point))
                   )
                 )
                 (if (eq "Multiple" point)
                   (while
                     (progn (initget "Exit")
                       (setq mpoint (getpoint "\nSpecify through point or [Exit] <next object> : "))

                       (cond
                         (
                           (eq "Exit" mpoint)

                           (if (eq "Yes" *dOff:Erase) (vla-delete obj))

                           (not (setq ExitFlag t))
                         )
                         (
                           (null mpoint)

                           (if (eq "Yes" *dOff:Erase) (vla-delete obj))

                           nil
                         )
                         (
                           (listp mpoint)
                          
                           (DoubleOffset obj
                             (distance (trans mpoint 1 0)
                               (vlax-curve-getClosestPointto (car sel) (trans mpoint 1 0) t)
                             )
                             (eq "Current" *dOff:Layer)
                           )
                          t
                         )
                       )
                     )
                   )
                   (progn
                     (DoubleOffset obj
                       (distance (trans point 1 0)
                         (vlax-curve-getClosestPointto (car sel) (trans point 1 0) t)
                       )
                       (eq "Current" *dOff:Layer)
                     )
                     (if (eq "Yes" *dOff:Erase) (vla-delete obj))
                    t
                   )
                 )
                 (setq ExitFlag t)
               )
               (progn
                 (DoubleOffset obj of (eq "Current" *dOff:Layer))

                 (if (eq "Yes" *dOff:Erase) (vla-delete obj))
               )
             )
             (princ "\n** Cannot Offset that Object **")
           )
          t
         )
       )
     )
   )
 )  
 (_EndUndo doc) 

	;;START sCo'S CODE;;

("L" "C" ".5")

	 

(princ)
)  
(princ)
(princ "\n:: DoubleOffset.lsp | Copyright © 2010 by Lee McDonnell | Version 1-1 | EDIT BY sCo TO SD PIPE::")
(princ "\n:: Type \"SD\" to invoke ::")
(princ)

	;;END sCo'S CODE;;

 

Hey Lee, I think all is still there. Correct me if I'm wrong.

 

Thanks!

Link to comment
Share on other sites

Just a suggestion that may be usefull when using multiple layers in a program

 

(SETQ lr1 (TBLSEARCH "LAYER" "P-SD-CL")) ;;EDIT FOR CL LAYER;; 
(IF (= LR1 NIL) 
(COMMAND "LAYER" "MAKE" "P-SD-CL" "COLOR" "BYLAYER" "" "")) ;;EDIT FOR CL LAYER;; 
(command "layer" "set" "P-SD-CL" "" "") ;;EDIT FOR CL LAYER;;

 

make the code a defun (checklayer) and put it in startup lisp

 

Then Just

(setq clay "P-SD-CL") (checklayer)

replacing layer name with clay the idea is that you can put these two lines anywhere in any code and simply check and change layers.

 

eg (setq clay "P-SD-CL") (checklay) draw line 1(setq clay "P-SD-CL2") (checklay) draw line 2 (setq clay "P-SD-CL2") (checklay) and so on this makes it easier when your doing multiple layer changes all the time.

 

I would probably change the last line to (setvar "clayer" clay)

 

A house wall 4 lines 4 layers.

Link to comment
Share on other sites

Perhaps something like this might suffice?

 

( Hope this is what you were aiming for )

 


       ;;START sCo'S EDITION;;

;;------------=={ SD PIPE EDIT OF Double Offset }==-----------;;
;;  This is an edition of Lee McDonnell's Double Offset code  ;;
;;  to an semi-automated pipe generating lisp                 ;;
;;  Description                                               ;;
;;    Changes current layer to specified layer              ;;
;;    Prompts to draw polyline                              ;;
;;    Changes current layer to second specified layer       ;;
;;    Starts Lee McDonnell's Doff lisp                      ;;
;;    specifies Layer then Current then a distance          ;;
;;    User hits enter and selects initial polyline          ;;
;;        *Carefull, the current layer is now that of   ;;
;;        the new offset lines*                  ;;

       ;;END sCo'S EDITION;;

;;--------------------=={ Double Offset }==-------------------;;
;;                                                            ;;
;;  Offsets each object in a selection to both sides by a     ;;
;;  specified distance. With additional controls for erasure  ;;
;;  of source object and offset layer.                        ;;
;;------------------------------------------------------------;;
;;  Author: Lee McDonnell, 2010                               ;;
;;                                                            ;;
;;  Copyright © 2010 by Lee McDonnell, All Rights Reserved.   ;;
;;  Contact: Lee Mac @ TheSwamp.org, CADTutor.net             ;;
;;------------------------------------------------------------;;
;;  Version: 1-1 20100912                                     ;;
;;------------------------------------------------------------;;

(defun c:SD ( / *error* _StartUndo _EndUndo DoubleOffset CLA
               DOC EXITFLAG LAYER MPOINT OBJ OBJECT OF POINT SEL SYMBOL VALUE currlay doff doubleoffset )
 (vl-load-com)

 (defun *error* ( msg )    
   (and doc (_EndUndo doc))
   (and cla (setvar 'CLAYER cla)) ;; sCo Mod
   (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
       (princ (strcat "\n** Error: " msg " **")))
   (princ)
 )

 (defun _StartUndo ( doc ) (vla-StartUndoMark doc))

 (defun _EndUndo ( doc ) (if (= 8 (logand 8 (getvar 'UNDOCTL))) (vla-EndUndomark doc)))
 
 (defun DoubleOffset ( object offset layer )
   (mapcar
     (function
       (lambda ( o )
         (if
           (and
             (not
               (vl-catch-all-error-p
                 (setq o
                   (vl-catch-all-apply
                     (function vlax-invoke) (list object 'Offset o)
                   )
                 )
               )
             )
             layer
           )
           (mapcar
             (function
               (lambda ( o )
                 (vla-put-layer o (getvar 'CLAYER))
               )
             )
             o
           )
         )
       )
     )
     (list offset (- offset))
   )
 )

 (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))

 ;; ------------ sCo Modification Start ------------

 (setq cla (getvar 'CLAYER))

 (mapcar '(lambda ( l ) (vla-Add (vla-get-layers doc) l)) '("P-SD-CL" "P-SD-L"))

 (setvar 'CLAYER "P-SD-CL")

 (command "_.pline")
 (while (= 1 (logand 1 (getvar 'CMDACTIVE)))
   (command pause)
 )

 (setvar 'CLAYER "P-SD-L")

  ;; ------------ sCo Modification End ------------

 (mapcar
   '(lambda ( symbol value ) (or (boundp symbol) (set symbol value)))
   '(*dOff:Erase *dOff:Layer) '("No" "Source")
 )

 (if
   (progn
     (while
       (progn
         (princ
           (strcat
             "\nCurrent Settings: Erase source="
             *dOff:Erase
             "  Layer="
             *dOff:Layer
             "  OFFSETGAPTYPE="
             (itoa (getvar 'OFFSETGAPTYPE))
           )
         )
         (initget 6 "Through Erase Layer")
         (setq of
           (getdist
             (strcat "\nSpecify Offset Distance [Through/Erase/Layer] <"
               (if (minusp (getvar 'OFFSETDIST)) "Through"  (rtos (getvar 'OFFSETDIST))) "> : "
             )
           )
         )
         (cond
           (
             (null of) (not (setq of (getvar 'OFFSETDIST)))
           )
           (
             (eq "Through" of) (setq of (setvar 'OFFSETDIST -1)) nil
           )
           (
             (eq "Erase" of) (initget "Yes No")

             (setq *dOff:Erase
               (cond
                 (
                   (getkword
                     (strcat "\nErase source object after offsetting? [Yes/No] <" *doff:Erase "> : ")
                   )
                 )
                 ( *dOff:Erase )
               )
             )
           )
           (
             (eq "Layer" of) (initget "Current Source")

             (setq *dOff:Layer
               (cond
                 (
                   (getkword
                     (strcat "\nEnter layer option for offset objects [Current/Source] <" *dOff:Layer "> : ")
                   )
                 )
                 ( *dOff:Layer )
               )
             )
           )
           ( of (setvar 'OFFSETDIST of) nil )
         )
       )
     )
     of
   )
   (while
     (progn
       (or ExitFlag
         (progn (initget "Exit")
           (setq sel (entsel "\nSelect object to offset or [Exit] <Exit> : "))
         )
       )
       
       (cond
         (
           (or ExitFlag (null sel) (eq sel "Exit")) nil
         )
         ( (vl-consp sel)

           (_EndUndo doc) (_StartUndo doc)

           (if (and (wcmatch (cdr (assoc 0 (entget (car sel)))) "ARC,CIRCLE,ELLIPSE,SPLINE,LWPOLYLINE,XLINE,LINE")
                    (setq obj (vlax-ename->vla-object (car sel))))

             (if (minusp of)
               (if
                 (progn (initget "Exit Multiple")
                   (and
                     (setq point (getpoint "\nSpecify through point or [Exit/Multiple] <Exit> : "))
                     (not (eq "Exit" point))
                   )
                 )
                 (if (eq "Multiple" point)
                   (while
                     (progn (initget "Exit")
                       (setq mpoint (getpoint "\nSpecify through point or [Exit] <next object> : "))

                       (cond
                         (
                           (eq "Exit" mpoint)

                           (if (eq "Yes" *dOff:Erase) (vla-delete obj))

                           (not (setq ExitFlag t))
                         )
                         (
                           (null mpoint)

                           (if (eq "Yes" *dOff:Erase) (vla-delete obj))

                           nil
                         )
                         (
                           (listp mpoint)
                          
                           (DoubleOffset obj
                             (distance (trans mpoint 1 0)
                               (vlax-curve-getClosestPointto (car sel) (trans mpoint 1 0) t)
                             )
                             (eq "Current" *dOff:Layer)
                           )
                          t
                         )
                       )
                     )
                   )
                   (progn
                     (DoubleOffset obj
                       (distance (trans point 1 0)
                         (vlax-curve-getClosestPointto (car sel) (trans point 1 0) t)
                       )
                       (eq "Current" *dOff:Layer)
                     )
                     (if (eq "Yes" *dOff:Erase) (vla-delete obj))
                    t
                   )
                 )
                 (setq ExitFlag t)
               )
               (progn
                 (DoubleOffset obj of (eq "Current" *dOff:Layer))

                 (if (eq "Yes" *dOff:Erase) (vla-delete obj))
               )
             )
             (princ "\n** Cannot Offset that Object **")
           )
          t
         )
       )
     )
   )
 )  
 (_EndUndo doc)

 (setvar 'CLAYER cla) ;; sCo Mod
 (princ)
)

(princ)
(princ "\n:: DoubleOffset.lsp | Copyright © 2010 by Lee McDonnell | Version 1-1 | EDIT BY sCo TO SD PIPE::")
(princ "\n:: Type \"SD\" to invoke ::")
(princ)

Link to comment
Share on other sites

Yes! This is great! Thanks, guys. There wouldn't be any way to sneak a PEdit in the end there would there? Like after all is done? It I couldn't seem to get it because the offset command lets you do multiple offsets before it ends. Just a thought. Just another step I was thinking of that could be time saved.

 

I was trying to add a

 

(command "_.pedit")

(while (= 1 (logand 1 (getvar 'CMDACTIVE)))

(command pause))

(prompt "pick")

 

with a fill in of

 

("w" "1")

 

But yeah. again I'm new to this so I'm just plugging clumps of code that I'm familiar with into a colossus that takes me forever to decipher. Ha Ha Ha. Trial and error.

 

Thanks for the cleanup guys! I really appreciate it!

Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.
Note: Your post will require moderator approval before it will be visible.

Guest
Unfortunately, your content contains terms that we do not allow. Please edit your content to remove the highlighted words below.
Reply to this topic...

×   Pasted as rich text.   Restore formatting

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.


×
×
  • Create New...