make invisible attribute visible

any way to view invisible block attribute?

I created a block and the attributes really don't need to be seen in autocad just there for dataextraction and keeping it all in one location i want to go back through and make sure i have information filled in in all the right invisible attributes without having to open each block and check the attributes, but i don't want them permanently visible (i know i can freeze them or put them on a non plot layer but it clutters up the space when there is 20+ attributes to a block)

Try View > Display > Attribute Display then choose On. Does that work?

Give this a try:

;;; Attribute Visibility Toggle
;;; Required Subroutines: AT:Entsel AT:GetAttributes
;;; Alan J. Thompson, 11.17.09
(defun c:AVT (/ #Obj)
 (and
   (setq #OBj (AT:Entsel nil
                         "\nAttribute Visibility Toggle\nSelect Attributed Block: "
                         '("LV" (0 . "INSERT") (66 . 1))
                         nil
              ) ;_ AT:Entsel
   ) ;_ setq
   (foreach x (AT:GetAttributes #Obj)
     (vla-put-visible
       x
       (if (eq (vla-get-visible x) :vlax-true)
         :vlax-false
         :vlax-true
       ) ;_ if
     ) ;_ vla-put-visible
   ) ;_ foreach
 ) ;_ and
 (princ)
) ;_ defun

You'll need a couple subroutines from my subroutine thread:

http://www.cadtutor.net/forum/showpost.php?p=271359&postcount=5

http://www.cadtutor.net/forum/showpost.php?p=271389&postcount=26

Or at the command line type ATTDISP, or change the system variable ATTMODE

See at this:

http://www.cadtutor.net/forum/showthread.php?t=41414

Or at the command line type ATTDISP, or change the system variable ATTMODE

HaHa, oh well. LoL

(defun c:AM () (setvar 'attmode (abs (1- (getvar 'attmode)))) (princ))

Or ATTOUT them to a CSV and view them in Notepad/Excel.

Glen

Hey Alan,

Can you please update the subroutine locations that are linked?

The links aint workin' (at least when I click on them)...

Thanks

~Greg

Hey Alan,

 

Can you please update the subroutine locations that are linked?

 

The links aint workin' (at least when I click on them)...

 

Thanks

~Greg

(defun c:AVT (/ ss i)
 (if (setq ss (ssget "_:L" '((0 . "INSERT") (66 . 1))))
   (repeat (setq i (sslength ss))
     (foreach a (vlax-invoke (vlax-ename->vla-object (ssname ss (setq i (1- i)))) 'GetAttributes)
       (vlax-put a 'Visible (~ (vlax-get a 'Visible)))
     )
   )
 )
 (princ)
)

Works great on my end.

Thanks dude

~Greg

Works great on my end.

Thanks dude

 

~Greg

You're welcome.