AutoCAD Message

"Object doesn't support this property or method". How to fix this problem? Thanks in advance!

Krystyna

What were you attempting to do when this message appeared?

Were you working in 2D or 3D?

Working in 2D AutoCAD 2010 (Windows 7, 32 bits) and FMSpace 7.2. Wanted to use the "Check drawing" function on FMSpace.

Could the problem be due to FMSpace and not AutoCAD?

What command were you attempting to use at the time?

"Object doesn't support this property or method". How to fix this problem? Thanks in advance!

Krystyna

One cannot apply or invoke a particular property or method, if an object does not support said property or method.

To view which properties and methods are available to an object, try this:

(defun c:DUMP (/ eName)
 (vl-load-com)
 (if (setq eName (car (entsel "\n  >>  Select Object To Dump Contents: ")))
   (progn
     (terpri)
     (vlax-dump-object (vlax-ename->vla-object eName) T)
     (textpage)))
 (princ))

Edit: For example, you cannot use vla-get-isxref on a layer item. Consider using vlax-property-available-p or vlax-method-applicable-p to mitigate uncessary errors.

Hope this helps!

DXF and VLA info of selected primary or nested object...

(defun c:Info (/ opt obj)
 ;; VLA & DXF Info of selected Primary or Nested object
 ;; Alan J. Thompson
 (initget 0 "Nested Primary")
 (setq opt (cond ((getkword "\nSpecify selection mode [Nested/Primary] <Primary>: "))
                 ("Primary")
           )
 )
 (if (setq obj (car ((if (eq opt "Primary")
                       entsel
                       nentsel
                     )
                      (strcat "\nSelect " opt " object for VLA & DXF info: ")
                    )
               )
     )
   (progn
     (textscr)
     (princ "\nVLA Info:\n\n")
     (vlax-dump-object (vlax-ename->vla-object obj) T)
     (princ "\nDXF Info:\n")
     (mapcar 'print (entget obj))
   )
 )
 (princ)
)

thank you both! It worked!

Krystyna:)