modify point style or library

Hi,

In advance, sorry for my poor english.

I would like to change the look of the point that I draw ni autocad.

When i draw a point (1 on the joined picture), I can choose different style (point, circle, square, ...) and increase or reduce the size (2 on the joined picture)

but the model stay allways thin, i would like to modify my point to look like the 3 ont the joined picture.

I know that 20 models are allready a lot of choice, but is there a possibility to modify the library of the point?

Thank in advance for your help

Are you looking to add lineweight to points marker? I’m not sure that this is possible.

I would like to change the look of the point that I draw ni autocad.

 

When i draw a point (1 on the joined picture), I can choose different style (point, circle, square, ...) and increase or reduce the size (2 on the joined picture)

[ATTACH=CONFIG]35853[/ATTACH]

 

but the model stay allways thin, i would like to modify my point to look like the 3 ont the joined picture.

 

I know that 20 models are allready a lot of choice, but is there a possibility to modify the library of the point?

 

I assume you are talking about these choices.

As far as I know, you cannot modify these or add to the choices. Do you have to use a POINT entity? Have you considered using a block instead?

Are you looking to add lineweight to points marker? I’m not sure that this is possible.

It would be great

I assume you are talking about these choices.

[ATTACH]35855[/ATTACH]

 

As far as I know, you cannot modify these or add to the choices. Do you have to use a POINT entity? Have you considered using a block instead?

I knew that somebody will talk about block instead of point marker, but it will be impossible to replace thousand of point (dwg given by our client) by block.

It's weird that we can't edit the point marker library, no ?

Are the points on their own layer?

I found a lisp code which help me :

http://www.cadtutor.net/forum/showthread.php?65093-Changing-Converting-Points-into-Blocks-Objects&highlight=replace+point+block

But we could organise a march to Autodesk office to protest against their bounded point marker library

Are the points on their own layer? Yes or No?

There are several layers with their own type of points

Wonderful. Then you could place a block (on a separate layer) at each one of those points, using a lisp routine, then freeze the points layer.

.....but it will be impossible to replace thousand of point (dwg given by our client) by block.

Not really. Is see ReMark has already steered you in the right direction.

It's weird that we can't edit the point marker library, no ?

It's been hardcoded since...well, forever. I guess that is why other programs use blocks to display objects (i.e. manholes, survey points, etc.) differently, in an unlimited amount of ways.

I worked onthis subject since this summer.

I have a routin which transform point to block (which is selected in the block allready present in the dwg)

BUT

My point contain Object Data. And when I use this routin, I obtain block whiwh don't recover Object Data.

On this joined picture :

Below the code of the routin i use.

Do you think there is a possibility to modify this routin to transfer the object data from point to block?

Thank you in advance.

uigol

(defun c:RPWB (/ *error* _blocks lst block ss space)

 (vl-load-com)

 (defun *error* (msg)
   (and *AcadDoc* (vla-endundomark *AcadDoc*))
   (if (and msg (not (wcmatch (strcase msg) "*BREAK*,*CANCEL*,*QUIT*,")))
     (princ (strcat "\nError: " msg))
   )
 )

 (defun _blocks (doc / l)
   (vlax-for x (vla-get-blocks doc)
     (if (not (wcmatch (vla-get-name x) "*|*,`**"))
       (setq l (cons (vla-get-name x) l))
     )
   )
   (vl-sort l '<)
 )

 (vla-startundomark
   (cond (*AcadDoc*)
         ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
   )
 )

 (cond ((not (setq lst (_blocks *AcadDoc*))) (alert "Zero blocks in active drawing!"))
       ((and (setq block (car (AT:ListSelect "Select block to insert:" "" 10 10 "false" lst)))
             (princ "\nSelect POINT objects to replace: ")
             (ssget "_:L" '((0 . "POINT")))
        )

        (setq space (vlax-get-property
                      *AcadDoc*
                      (if (eq (getvar 'CVPORT) 1)
                        'PaperSpace
                        'ModelSpace
                      )
                    )
        )

        (vlax-for x (setq ss (vla-get-activeselectionset *AcadDoc*))
          (if (vla-insertblock space (vla-get-coordinates x) block 1. 1. 1. 0.)
            (vla-delete x)
          )
        )

        (vla-delete ss)
       )
 )
 (*error* nil)
 (princ)
)




(defun AT:ListSelect (title label height width multi lst / fn fo d item f)
 ;; List Select Dialog (Temp DCL list box selection, based on provided list)
 ;; title - list box title
 ;; label - label for list box
 ;; height - height of box
 ;; width - width of box
 ;; multi - selection method ["true": multiple, "false": single]
 ;; lst - list of strings to place in list box
 ;; Alan J. Thompson, 09.23.08 / 05.17.10 (rewrite)
 (setq fo (open (setq fn (vl-filename-mktemp "" "" ".dcl")) "w"))
 (foreach x (list (strcat "list_select : dialog { label = \"" title "\"; spacer;")
                  (strcat ": list_box { label = \"" label "\";" "key = \"lst\";")
                  (strcat "allow_accept = true; height = " (vl-princ-to-string height) ";")
                  (strcat "width = " (vl-princ-to-string width) ";")
                  (strcat "multiple_select = " multi "; } spacer; ok_cancel; }")
            )
   (write-line x fo)
 )
 (close fo)
 (new_dialog "list_select" (setq d (load_dialog fn)))
 (start_list "lst")
 (mapcar (function add_list) lst)
 (end_list)
 (setq item (set_tile "lst" "0"))
 (action_tile "lst" "(setq item $value)")
 (setq f (start_dialog))
 (unload_dialog d)
 (vl-file-delete fn)
 (if (= f 1)
   ((lambda (s / i s l)
      (while (setq i (vl-string-search " " s))
        (setq l (cons (nth (atoi (substr s 1 i)) lst) l))
        (setq s (substr s (+ 2 i)))
      )
      (reverse (cons (nth (atoi s) lst) l))
    )
     item
   )
 )
)