custom erase command

I am looking for help with a special erase command. I would like to select objects one by one and have then delete as I select them.

Can someone advise how to write this command?

Thx

Welcome to CADTutor, and the world of LISP!

(defun c:Erase+ (/ eName layerName)
 (while
   (and
     (setq eName (car (entsel "\nSelect an entity to erase: ")))
     (setq layerName (cdr (assoc 8 (entget eName))))
     (/= 4 (cdr (assoc 70 (tblsearch "layer" layerName))))
   )
    (command "._erase" eName "")
 )
 (princ)
)

Another,

(defun c:e1 ( / e )
   (while (setq e (car (entsel))) (entdel e))
   (princ)
)

Or, to allow for missed picks:

(defun c:e1 ( / e )
   (while
       (progn (setvar 'errno 0) (setq e (car (entsel)))
           (cond
               (   (= 7 (getvar 'errno))
                   (princ "\nMissed, try again.")
               )
               (   (= 'ename (type e))
                   (entdel e)
                   t
               )
           )
       )
   )
   (princ)
)

You do not need a lisp routine to accomplish the task. I've had this ability for many years simply by using this:

*^C^CErase;\;

Good catch, Lee... I always forget about the ENTDEL function; much more efficient than the command. LoL *kicks dirt*

You do not need a lisp routine to accomplish the task. I've had this ability for many years simply by using this:

 

*^C^CErase;\;

Nice and simple...Thanks

You do realize you have to edit the CUIx to use the macro right?