Text to excel

Hi all,

I have a drawing with z-coordinates in it as text.

I would like to export all the text-objects with their x- and y-coordinates, and use the text content for the z-coordinate.

Find the example attatched.

I couldn't find anything with a websearch.

Text2excel.dwg

Please check the built-in DATAEXTRACTION command. Apply it only for text entities and retain the Position X, Position Y and Value properties.

Try this .

(defun c:Test (/ ss f o)
 ;;    Tharwat 05.11.2014             ;;
 ;;    Export Texts' values to Excel    ;;
 (princ "\n << Select Texts to export to Excel : >>")
 (if (and (setq ss (ssget '((0 . "TEXT")
                           )
                   )
          )
          (setq f (getfiled "Save as :" (getvar 'DWGPREFIX) "csv" 1))
     )
   (progn
     (setq o (open f "w"))
     (write-line
       "X-coordinate of text;Y-coordinate of text;Z-coordinate of text value"
       o
     )
     ((lambda (i / sn p e)
        (while (setq sn (ssname ss (setq i (1+ i))))
          (write-line
            (strcat
              (rtos
                (car (setq p (cdr (assoc 10 (setq e (entget sn))))))
                2
              )
              ";"
              (rtos (cadr p) 2)
              ";"
              (cdr (assoc 1 e))
            )
            o
          )
        )
      )
       -1
     )
     (close o)
   )
 )
 (princ)
)

Hi Tharwat,

Thanks for the tool!

I miss the x- and y-coordinates in the list.

Regards,

Wesley

I miss the x- and y-coordinates in the list.

Are you talking about the X and Y of the Text location ?

Show the outcome of the program as best as you looking for to allow me to write it for in one go .

Hi Tharwat,

The outcome should look like this.

Thnx

I updated the routine above , try it and let me know .

Thnks Tharwat!

Works great!

Regards,

Wesley

Thnks Tharwat!

 

Works great!

 

Regards,

Wesley

You're welcome .

Happy to help