Converting entity to string.

Hello,

I am currently trying to store any dimensional text to a string value

I have started to use entsel to select single dimension to store the entity

How should i approach to store the dimensional text from the entity information as a string value?

This is an example what I want to store the string as: "%%C "

Any help will be appreciated.

Thank you

Welcome to CADTutor.

Consider the TextOverride Property; quick example:

(vl-load-com)

(defun c:FOO (/ ss oDim s)
 (if (setq ss (ssget ":S:E" '((0 . "DIM*"))))
   (progn
     (setq oDim (vlax-ename->vla-object (ssname ss 0)))
     (prompt
       (strcat "\nTextOverride: "
               (if
                 (and
                   (vlax-property-available-p oDim 'textoverride)
                   (/= "" (setq s (vla-get-textoverride oDim)))
                 )
                  s
                  "<Empty String> "
               )
       )
     )
   )
 )
 (princ)
)

Thank you for your help Blackbox, the textoverride property works perfect!

Removed answer posted to wrong post

As an alternative to ActiveX(COM) and for compatibility on a Mac, you could also use DXF group 1, e.g.:

(defun c:test ( / e i s )
   (if (setq s (ssget "_:L" '((0 . "*DIMENSION") (1 . "~%%C <>"))))
       (repeat (setq i (sslength s))
           (setq e (entget (ssname s (setq i (1- i)))))
           (entmod (subst '(1 . "%%C <>") (assoc 1 e) e))
       )
   )
   (princ)
)

Thank you for your help Blackbox, the textoverride property works perfect!

You're very welcome, tama010; I'm happy to help.

Cheers