Ssget divide object on window filter

I selected objects function ssget.

(setq s ssget)

I have a list of corner windows (white squares on drawing).

'((x y) (x y) (x y) (x y) (x y))

How to divide the objects on those that are inside the window.

I need a list entity of objects in each window.

'((<Entity name: 7ffff931b40> <Entity name: 7ffff931b40> ...)
(...) (...) (...) (...))

Is there a way to use the filters window on the system variable ssget (ssget "_W"

The example in the drawing.

Something like this? :

(defun c:test ( / SS i ent lst x SelN n Nlst Tlst )
(if 
	(and 
		(princ "\nSelect the closed(white) plines: ")
		(setq SS (ssget '((0 . "LWPOLYLINE") (-4 . "&=") (70 . 1))))
	);and
	(progn
		(repeat (setq i (sslength SS)) ; repeat for each closed polyline
			(setq ent (ssname SS (setq i (1- i))))
			(setq	lst (mapcar 'cdr (vl-remove-if-not '(lambda ( x ) (= 10 (car x))) (entget ent))))
			
			(if 
				(and 
					(setq SelN (ssget "_WP" lst))
					(or (not (ssmemb ent SelN)) (ssdel ent SelN))
					(< 0 (sslength SelN))
				)
				(progn
					(repeat (setq n (sslength SelN)) ; repeat for each entity inside the polyline
						(setq Nlst (cons (ssname SelN (setq n (1- n))) Nlst)) ; create list for the SS
					)
					(setq Tlst (cons (reverse Nlst) Tlst)) ; store the SS list into the global list
					(setq Nlst nil) ; reset the SS list
				)
			); if
		); repeat
		(princ "\n") (print Tlst) ; print the global list
	);progn
); if/while
(princ)
)

This is heavily modified code, the original is from Lee Mac (MatchCenInsPoly) - by my old request.

An alternative method maybe a bit more complex is to pick one window only but check the min/max Y value of the object so it becomes part of only 1 window group. Look also at bounding box methods. You can vary the window sizes then.

It must be simple and quick.

I used a solution in which first choose the coordinates the windows and then ssget (window).

(setq lst '(((x y) (x y)) ((x y) (x y))  ((x y) (x y)) ...))

(mapcar '(lambda (%) (ssget "_W" (car %) (cadr %))) lst)

Sorry for my English.

Be careful using odd characters in your lisp like % you may wonder why something does not work.

Thanks for the advice. I will pay attention to the odd characters in my code.