Set entity color

Hello everybody,

The following works with circle, line but not with lwpolyline, spline:

(defun C:RT ( / ent data )
(if (setq ent (car (entsel "\nSelect object to change its color")))
	(progn	
		(if (not (assoc 62 (setq data (entget ent))))
			(setq data (append (list (cons 62 1)) data))
			(setq data (subst (cons 62 1) (assoc 62 data) data))
		)
		(entupd (cdr (assoc -1 (entmod data))))
	)
)
(princ)
)

Is there an easy fix for this?

Try this :-

(defun c:test ( / a b i)
 (if (setq a (ssget '((0 . "*line,circle,ellipse,point"))))
   (repeat (setq i (sslength a))
     (setq b (vlax-ename->vla-object (ssname a (setq i (1- i)))))
     (vla-put-color b 1)
   )
 )
 (princ)
)

Another:

(defun c:rt ( / e )
   (if (setq e (car (entsel)))
       (entmod (append (entget e) '((62 . 1))))
   )
   (princ)
)

One more!

(defun C:RT ( / EOBJ )
(setq EOBJ (entsel "\nSelect object to change its color"))
(if EOBJ (vl-catch-all-apply 'vla-put-Color (list (vlax-ename->vla-object (car EOBJ)) 1)))
(princ)
)

Thanks guys, now I see the problem in my code:

(setq data (append (list (cons 62 1)) data))

must be:

(setq data (append data (list (cons 62 1))))

One more!

(defun C:RT ( / EOBJ )
(if (setq EOBJ (vlax-ename->vla-object  (car (entsel "\nSelect object to change its color"))))
	(vl-catch-all-apply 'vla-put-Color (list EOBJ 1))
)
(princ)
)

Careful - vlax-ename->vla-object will error for a null argument

Careful - vlax-ename->vla-object will error for a null argument

Fixed code above.

Thanks,

Thanks, now I know how its done with visual lisp.