Select by color in selection

(defun c:SBC ( / c d e l )
   (if (setq e (car (entsel)))
       (progn
           (setq c
               (cond
                   (   (cdr (assoc 62 (entget e)))   )
                   (   (abs (cdr (assoc 62 (tblsearch "LAYER" (cdr (assoc 8 (entget e)))))))   )
               )
           )                     
           (while (setq d (tblnext "LAYER" (null d)))
               (if (= c (abs (cdr (assoc 62 d))))
                   (setq l (cons "," (cons (cdr (assoc 2 d)) l)))
               )
           )
           (sssetfirst nil
               (ssget "_X"
                   (if l
                       (list
                           (cons -4 "<OR")
                               (cons 62 c)
                               (cons -4 "<AND")
                                   (cons 62 256)
                                   (cons 8 (apply 'strcat (cdr l)))
                               (cons -4 "AND>")
                           (cons -4 "OR>")
                       )
                       (list (cons 62 c))
                   )
               )
           )
       )
   )
   (princ)
)
(prompt "\nDigite: SBC")

I would appreciate your help to change this excellent routine: I do not feel able to do so.

I intend to do the same job, but not globally in the drawing, but only a specific selection. The routine must first allow obtain the desired color, and then filter the selection.

That looks familiar

Remove the "_X" from the ssget expression.

That looks familiar

 

Remove the "_X" from the ssget expression.

Lee,

nice.

Tanks again!

No worries

This filtered selection routine I posted might be of interest: http://www.theswamp.org/index.php?topic=35028.msg402471#msg402471

Nevermind, I see you also step through the layer list for matches, not just on the object level.

This filtered selection routine I posted might be of interest: http://www.theswamp.org/index.php?topic=35028.msg402471#msg402471

alanjt,

tanks for the atention!