[MR MAN]

i have two lines intersecting at point is there any way to explode them to 4 parts at intersection point.

[msasu]

By hand or automatically?
For the first case use BREAK command with “First point” option and subsequently select intersection point twice – do the same for both lines. Done!

[MR MAN]

thanks msasu for your help,but if i need select some intersecting lines and do this automatically how can i do that?

[Tiger]

There are a few lisps floating around that expands the Break-command - this thread highlights one that might be of use to you:

http://www.cadtutor.net/forum/showth...ght=BREAK+LISP

For help on how to use Lisps, please see this instruction:

http://www.cadtutor.net/forum/showthread.php?t=1390

[msasu]

Will require an AutoLISP routine with the above structure
1. Select the lines to process (filter for errors).
2. List endpoints of those lines.
3. Get the intersection point – using INTERS statements; exit if lines don’t intersect or the point doesn’t lies on (both) lines.
4. Call programmatically the BREAK command to split entities.

[David Bethel]

This will work on LINEs, not PLINESs or ARCs

(defun c:bil (/ ss l1 l1d l2 l2d p10 p11 p20 p21 ip)
  (while (or (not ss)
             (/= (sslength ss) 2))
         (princ "\nSelect 2 LINEs that Intersect")
         (setq ss (ssget (list (cons 0 "LINE")
                               (if (getvar "CTAB")
                                   (cons 410 (getvar "CTAB"))
                                   (cons 67 (- 1 (getvar "TILEMODE"))))))))

  (setq l1 (ssname ss 0) l1d (entget l1)
        l2 (ssname ss 1) l2d (entget l2)
        p10 (cdr (assoc 10 l1d)) p11 (cdr (assoc 11 l1d))
        p20 (cdr (assoc 10 l2d)) p21 (cdr (assoc 11 l2d))
        ip (inters p10 p11 p20 p21))

  (cond ((not ip)
         (alert "Lines Do Not Intersect"))
        (T
         (command "_.BREAK" l1 ip ip
                  "_.BREAK" l2 ip ip)))
  (prin1))

-David

[Lee Mac]

Another,

(defun c:brk (/ ss i y Obj1 Obj2 Ent1 Ent2 iLst ip)
  (vl-load-com)

  (if (setq ss (ssget "_:L" '((0 . "~VIEWPORT"))))
    (progn
      
      (setq i (sslength ss))
      (while (not (minusp (setq y (1- i) i (1- i))))
        (setq Obj1 (vlax-ename->vla-object (setq Ent1 (ssname ss i))))

        (while (not (minusp (setq y (1- y))))
          (setq Obj2 (vlax-ename->vla-object (setq Ent2 (ssname ss y))))

          (if (setq iLst (vlax-invoke Obj1 'IntersectWith Obj2 acExtendNone))
            (command "_.break" Ent1 "_non" (setq ip (list (car iLst) (cadr iLst) (caddr iLst)))
                      ip "_.break" (list Ent2 ip) "_non" ip ip))))))

  (princ))